by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
how to create a subscript in an "if()" function? for example if(1<2,"FS","") the "S" should be in subscript. thank you!
I want to replace F2 with value in G2 if value in F2 is 0.
Rukia,
It is not possible to have a value and a formula in the same cell.
Hi There,
I use this formula but nothing is coming out:
=IF(B6>2),"3.86"
what i need is if b6 is > 2 i need excel to put 3.86 and 3.99 if b6 is <= 2
Thanks
Hi Teame,
Please try this one:
=IF(B6>2, 3.86, 3.99)
Mant Thanks Sve.
I need help figuring out 2 calculations
1.If cell is blank, then leave cell blank, but if cell has a value then add another cell.
2.Total cells and then divide by cells that only have value. Example if there are 10 cells, but only 5 have value, you would divide by 5.
Hi Toni ,
You can use formulas like these:
1. =IF(A1="", "", B1)
A1 is the cell you check for being blank/non-blank, and B1 is the cell you add if A1 is blank.
2. =SUM(A1:A100)/COUNTIF(A1:A100, "<>"&"")
Hi,
I am currently working with a schedule, and I am trying to make an IF function that if I have a table that will show me who is working each shift, it will look at the schedule and pull the person that is scheduled at a certain time.
An Example:
If I have person A scheduled at 11:15 AM and I want there name to be pulled into the table which shows all the employees that work at 11:15 AM how would I do so. Currently the function I am trying to use (=IF(B13="11:15 AM", A13) is not working. B13 is representing the starting time of the shift, while A13 is representing the Employee name. I would greatly appreciate any help you can give on this matter, thank you!
Hi Phillip,
When comparing dates or times in Excel, you have to use the DATEVALUE and TIMEVALUE functions, respectively, in order to convert a date or time unit in the text format to a serial number that Excel recognizes as a date / time. For example:
=IF(B13=TIMEVALUE("11:15 AM"), A13, "")
What is the formula when my conditions are;
If 0<= A < 10 the result is 3
If 10< A < 15 the result is 2
If 15 < A 20 the result is 0
Assuming that the variable A is the value on a certain cell.
Thanks
Forgot to mention;
if 15< A < 20 the result is 1
Hi Faith,
Here you go:
=IF(AND(A1>=0, A1<10), 3, IF(AND(A1>=10, A1<15), 2, IF(AND(A1>=15, A1<20), 1, "")))
Thank you for the article. I don't know if there is a function to do what I want, but here is basically what I am looking for.
I have a list of items that I have set to display on a different sheet. I would like a large number of those items (those that start with a 4) to be combined into one cell with a different name in the same list (The 400 Series). Is there a function that will keep my list intact, but combine all the names that start with 4 into my new cell? I don't need a count of them by the way, just the list to transpose itself over as it is now with those specific cells pushed down into one.
Thank you for the help.
As a follow up and to complicate my question, I am hoping to establish a function to do this dynamically every day when I import new information. If I were doing it only once, I think I could just remove the "4" items and put in a new block, but this would become a timely process if I were doing it every day, because I have the list being dynamically generated, which would bring back all my "4" blocks with the new import each day.
Can I assume my question is too complicated?
Hi Svetlana,
I need to create the following if statement.
IF the member type in B6 = "TC" then take the date from B3 and + 10 Days, If the member type in B6 = "T2C" then take the date from B3 and + 15 Days.
Hi Adam,
Here you go:
=IF(B6="TC", B3+6, IF(B6="T2C", B3+15, ""))
Please remember to change the format of the cell with the formula to the Date format so that is displays the date correctly.
Hi Svetlana
I would like to create in "IF" statement or an "ISBLANK" statement that says that if C2 is blank, populate from D2. If C2 has text, do nothing.
=IF(C2 is Blank, Populate from D2) or =IF(ISBLANK(C2)=TRUE,D2,0)
Thank you!
Hello Donni,
You can use either of the below formulas:
=IF(C2="", D2, "")
If cell C2 is "visually blank" (including an empty string returned by some other formula, if any), the formula returns a values from D2, otherwise returns an empty string.
=IF(ISBLANK(C2), D2, "")
The second formula returns a value from D2 if cell C2 is absolutely blank (no value, no empty string).
Please see the Excel IF examples for blank, non-blank cells section in this tutorial for full details.
Hi,
I have a formula that is returning "Recent" in cells that do not contain dates.
=IF(C6>DATEVALUE("4/21/2014"),"Recent","")
Cell C6 = "1 File(s)"
What can I do to exclude cells that do not have dates?
Never mind this, got it figured out.
Hi,can you help me with formula if for this condition, if F3=A,D3=1,the result for H3=C3 & if F3=A,D3>1 the result for H3=-1 in 1 formula if. Thank you :)
Hi Pichan,
Here is the formula for H3 as per your conditions. If nether condition is met, it will return a blank cell (empty string).
=IF(AND(F3="A", D3=1), C3, IF(AND(F3="A", D3>1), -1, ""))
Hi, im trying to place a formula that, according to a "word" I can get a number as true or false value.
ex.: A1= Casa .......... B1= If=(A1Casa,"2","5"), something like that.
Thanks in advanced. :)
Hi Roman,
I believe you meant =IF(A1="Casa", 2, 5)
Yes,sorry...... but I get a warning that I shoud put an apostrophe, but is possible to make work somehow?
Most likely this is because you have ";" set as a List separator (you can check this in the Regional settings). If this is the case, then try =IF(A1="Casa"; 2; 5)
Sweeeeet, perfect, thanks Svetlana :)
Sorry again, work at prefection, but something else that I want to know if possible, Is possible also to make a Image to show in a cell linked to a word in a formula?, if possible can you direct me to a link of how to do it?, thanks again :)
=(D3/B3)if(B3="0"),D3,E3 I get error please help
D3=hour B3=Sales E3=final number
Hi Daniel,
Sorry, I cannot follow you. Can you explain the condition (logical test), please?
Hi Clarence,
Here you go:
=IF(AND(E20<J21, E20<D21), MAX(F11:F15), "")
it's not working :'(
Hmm... strange, it works just fine on my test sheet.
The formula is in A1.
hi , can you help with my sheet ? I can't translate it to codes in excel .this is how i read it "if e20 is less than j21 and d21 , i should get the cell with the highest value in f11 to f15 cells . thanks .
HELP! :( Working on a sheet I have made a drop down in a cel and I would like the cel next to it to enter text if a certain word is selected in the drop down, is this possible?!?! I am not very good at explaining so I can try my best with whatever questions you have!
For example, if the drop down menu is selected Oranges I want cel G to now have Bananas in it, but if from the drop down Grapes is selected I want cel G to now say Grapes, and so on and so on, honestly have 27 so far in the drop down and need an IF in G if something is in the drop down menu, is this possible?!?!
Hi Ryan,
If you want a cell next to your drop down list to display the same value as currently selected in the drop-down, all you need is a simple formula like =$A$1 where A1 is the drop-down cell.
If you want to display different values, then you should use nested IF functions, like this:
=IF(A1="bananas", "bananas2", IF(A1="oranges", "oranges2", IF(A1="grapes", "grapes2")))
=IF(AH5>69, AG5*5, IF(AH5>59, AG5*4,IF(AH5>49, AG5*3,IF(AH5>44, AG5*2,IF(AH5>39, AG5*1,IF(AH569) and so on.
pls, can you help
Hi Fred,
The formula looks good. You just need to finish it properly, by closing all IF statements. I.e. the number of closing brackets should match the number of opening ones. Also, in the value_if_false argument of the last IF, enter the value to display when none of the conditions are met - it's an empty string ("") in the example below:
=IF(AH5>69, AG5*5, IF(AH5>59, AG5*4, IF(AH5>49, AG5*3, IF(AH5>44, AG5*2, IF(AH5>39, AG5*1, IF(AH5>29, AG5, ""))))))
Hi! I am trying to use an IF Formula to provide me a date result.
=IF(H2=S, [Approval]+(7*[Estimated weeks from Start to Approval]),IF(H2=P, [Start]+(7*[Estimated weeks from Start to Approval])))
I'm not sure what to enter at the end for the result to show a date.
Thanks!
Thank you Svetlana!!!
Hi Svetlana, It would be great if you could help, I think I'm nearly there but getting frustrated :)
=IF(AND((E4-AG4>=5),50,0),IF(AND(E4-AG4<=-5),50,0))
I'm building a sports sheet, whereby E4 is the actual spread and AG4 is the predicted spread. If the predicted spread is within +5 0r -5 then 50 points are awarded.
Appreciate your help
Kind regards
Barry
Hi Barry,
The correct syntax of your formula is as follows:
=IF(AND(E4-AG4<=5, E4-AG4>=-5), 50, 0)
And you can make it even more simpler by using the ABS function that returns an absolute value regardless of the sign:
=IF(ABS(E4-AG4)<=5, 50, 0)
Hi,
Thank you in advance for your time. I am trying to creat an IF formula with a logic test that recognizes the most current date in the row and if the date is within 6 days of the todays date another cell will indicate NOT AVAILABLE
So far I have IF(???>6;AVAILABLE;NOT AVAILABLE)
I dont know how to create the date formula for the row only for a specific cell.
Thank you
Hi Stephanie,
You should use the MAX function to determine the most recent date in a row and then compare it with TODAY(). For me to be able to suggest the right formula, please clarify the conditions. I assume "within 6 days of the todays date" means within the next 6 days, right? And what shall the formula display if the most current date in the row is a past date? And what if it is more than 6 days in the future?
Row A: Will show "Open" if the date entered in any cell in that row is more than 6 days from the current date or show "Closed" if ay date in the row is within 6 days of the current date (future or past).
So far I have =IF(??-TODAY()>6;"OPEN";"CLOSED")
Thank you
Hi Stephanie,
Try this one:
=IF(ABS(TODAY()-MAX(A2:N2))<6, "open","closed")
Where A is the first and N is the last column containing dates.
Hi,
How would I write the formula to get the following:
If A1 IS BETWEN 1 & 3 then "q1" however if between 4 & 6 then Q2, If between 7 & 9 then q3...
Thanks!
Mishaal
Hi Michelle,
You can use a nested IF formula similar to this, beginning with the largest values:
=IF(AND(A1>=7, A1<=9), "q3", IF(A1>=4, "q2", IF(A1>=1, "q1", "")))
If there is no upper-bound limit, it can be simplified it to:
=IF(A1>=7, "q3", IF(A1>=4, "q2", IF(A1>=1, "q1", "")))
Hi,
How would I write the formula to get the following:
If A1 3 but 6 BUT 9 But <=12 "Q4"
THANKS IN ADVANCE FOR YOU HELP!!
Michelle
Hi,
i shall appreciate if you could please guide me as to how I can use IF function formula while making general journal (Accounts) to auto post entries into respective ledgers(account heads/expense heads) ?
I look forward for a positive response.
Thank you,
Danish Abbasi
Hi Danish,
Please try to explain the task from another viewpoint. In what columns do you have data, and where do you want to auto post data and based on exactly what conditions?
Hi,
I have a drop down selection in Column M with the choices: "China - UK", "China - EU", "China - ME"
In column P I have a formula: =INDEX(Products!M:M,MATCH(C5,Products!$B:$B,0)) to automatically populate the duty rate for bringing into UK/EU - this is a variable percentage depending on the product.
If in the drop down "China - ME" is selected I want to override column P with conditional formatting to show 5% which is constant for all products
I tried to put the two formulas in priority order on conditional formatting
=IF(M5="China - ME", "5%", "0") - selected stop if true
=INDEX(Products!M:M,MATCH(C5,Products!$B:$B,0))
Can you please tell me where I am going wrong?
Kind regards,
Alex
Hi Svetlana,
Could you please help me with my question below?
I'm collecting in 1 sheet customers feedbacks from 7 different languages (sheets).
So in the same colomn A, I have the answers "Yes, Oui, Ja, Si, No, Non, Nein...." or "Non, No, Nain...".
The formula works fine for 1 language "=IF(A2="SI",1,0)" but do not know how to add the others..I would need number 1 to appear if it's an answers "Yes, Ja, Si, oui.. and a 0 if it's a "Non, No, Nain...".
Any idea how can I compile all of this in one formula please?
That would be much appreciated if you could help with this.
Thanks a lot,
Erin
Hi Erin,
You can add multiple OR conditions in your logical test, like this:
=IF(OR(A2="SI", A2="Yes", A2="Ja"), 1, 0)"
Hi, what if the cells are multi-word strings and I want to have anything that contains, (e.g.) 'blue', 'green' or 'purple' return 'cool' and everything else 'warm'.
For example:
light blue (cool)
burnt orange (warm)
forest green (cool)
etc.
thanks
Hi,
i need the if condition formula for the below i need to allocate some of the qty so if total qty is less 5000 need allow 25 Pcs like details are below
Qty Allow Qty
12500 400
I have values in cells E6,H6,K6,N6,Q6 & T6 that I want added together. The values in these cells are from vlookups from other sheets in the workbook. Any of those 6 values (E6,H6,K6,N6,Q6 &T6) could contain a blank or have returned nothing as a result of the vlookup. I need to total these numbers but if I put a simple addition formula in I get an error because of the possible blanks. I am thinking it needs to be a complex nested if sentence but can't figure out how to tell it that I need it to add all the numbers and discount those that are blanks or empty cells.
= IF(A10,A1, IF(A20,A2,IF(A30,A3,"BAD")))
BAD is mean all 3 cells are blank
Hi!
Sorry, I am not sure I can follow you. Can you explain the conditions (logical tests), please?
first of all ,thanks in advance for the people whom create these very nice tutorials.I wanted to do math operation on the results of nested IFs.how could it possible with one formula??? my formula is as this:
=IF(HOUR(D26)> 0; HOUR(D26)*45357; IF(MINUTE(D26)> 0; MINUTE(D26)*755.95; IF(SECOND(D26)> 0; SECOND(D26)*12.6; 0)))
---------I wana add a statement to above formula in order to sum the true values , it calculate the first but ignores others!!!! I wanna sum hour+minute+second
Hi Svetlana,
I tried your formula here below to replace a text into a number and it works fine.
But I do not actually know how to make it work for different datas on the same colomn.
Let me quickly explain.
I'm collecting in 1 sheet customers feedbacks from 7 different languages (sheets).
So in the same colomn A, I have "Yes, Oui, Ja, Si, No, Non, Nein...." answers.
The formula works fine for 1 language "=IF(A2="SI",1,0)" but do not know how to add the others..I would need number 1 to appear if it's an answers "Yes, Ja, Si, oui.. and a 0 if it's a "Non, No, Nain...".
Any idea how can I compile all of this in one formula please?
That would be much appreciated if you could help with this.
Thanks a lot,
Erin
if i5 is less then D5 value is zero and if D5 is greater then I5 value is D5 is show
=IF(I5<D5, 0, D5)
The formula will return 0 if I5<D5, and the value in D5 if I5>=D5. If you are looking for something different, please clarify.
I am doing an excel on monthly growth of values based on employees. Issue is some people start during the month and some quit. So I have some people with no value at the beginning of the month and other with no value at the end. I do not want those to show up as values.
A B C D
1 1/1/15 2/1/15 Growth Percentage
2 225,749 248,324 200,471 88.8%
3 420,284 420,284 0%
4 48,744 -48,744 0%
For D2, I did =IF(OR(A2="",B2=""),,(B2-A2)/ABS(A2)) which gives me the percentage of growth through the month and returns 0% if either is blank. Can I make column D actually be blank instead of showing 0%? Or, I want to show a total average growth at the bottom of column D without being penalized for all the 0%. If D5 was going to be the "average" cell, could I do =AVERAGE(D2:D4) but somehow tell it to not include the cells which have a value of 0%? Some people have a negative percentage and I need to include those.
Well that table got all messed up after submitting it. Column A is 1/1/15's value, column B is 2/1/15's value, column C is the growth from 1/1 to 2/1 and column D is the percentage that they grew (or dropped) over the month.
Hi Doug,
I would add "" to value_if_true to return an empty string if either A2 or B2 is blank.
=IF(OR(A2="",B2=""),"",(B2-A2)/ABS(A2))
I need help with a if statement formulae
The formula is:
=IF(H18='Booking Date Log'!$J$13:$J$1048576, "Not Available", "Available")
H18 contains a date e.g. 9/9/2015
$J13:$J$1048576 contains a range of dates e.g. 9/9/2015 9/10/2015 ....
True Value = "Not Available"
False Value = "Available"
what i need is that if H18 = any of these cells ($J13:$J$1048576) for it to come as "Not Available"
and if H18 doesnt = any of these cells ($J13:$J$1048576) for it to come as "Available"
Can this be done?
thanks
Fraz
I want to write a formula where if the value in a particular cell is less then 18 I want the cell to indicate the cost is $48 but if the value is greater than 18 then I want the value to be $48 plus the value greater than 18 (or the value +30)
if A10 < 18 then = $48.00 but if A10 < 18 then = (A10 + 30)
Can this be done?
Figured it out, thanks =IF(E225>19,E225+30,"$48.00")
I want to test the value of a portion of a cell. For example: The cell says Approved: 12345 where 12345 is a changing order number, the list has Declined and Refunded transactions as well. Is there a way to test only for the word Approved without consideration of the remaining data within the field?
Hello Krystalya,
You have to use ISNUMBER and SEARCH function for partial match, like this:
=IF(ISNUMBER(SEARCH("approved",A2)), "yes", "no")
Where A2 says "says Approved: 12345".
Please check out "Example 3. IF formula for text values with partial match" in this tutorial for full details.
Hello,
I have a workbook with multiple sheets. In column A, of sheet 1, is a list of names. I have been able to get those names to populate on sheet 2 and three using ;
=IF(INDIRECT("Sheet1!A" & ROWS($1:1))="","",INDIRECT("Sheet1!A" & ROWS($1:1)))
This works well to a point. What I would like to happen is when a name is deleted from column A, sheet 1, I would like the data in sheets 2 and three in the corresponding row to be deleted as well. i.e. if row 17 (A-L) on sheet 1 is deleted, then row 17 A-L) on sheets 2 and 3 will be deleted.
Thanks
There was a simple fix. Just group the sheets together. Adjust as nessasary. And then un group.
Hi Guys,
I am new to VBA. I need a VBA macro code that will convert HTML data into Text in my microsoft 2007 excel.
one column A contain n number of rows data with HTML data I want to run a macro so it can be convert to Text data in just near by column that is B.
Hi Svelana,
How are you today. I appreciate the time you're taking to help me with my problem. I'm sure all these individual questions can be burdensome. My question is:
I have the first 80 cells numbered 1-80 in sequence. I have this in every row as well, and then after that I have 20 columns each with a number 1-80. I wanna highlight one of the 1st 1-80 if one of the 20 cells has a number that matches it. Is this possible?
Thank you,
Hi Eddie,
Sorry, I am not sure I fully understand your data structure. If you could post your sample workbook on our forum, our support team will do their best to help.
Hi, I wanted to know how can I get numerical value for 18 and below and 46 and above
thanks
Hi,
If you are give amount that between 6 to 10 is equal to 0.5 however I have to formulate it in such a way that below 6 it is to be number divided by 24 and above 10 it must be number divided by 24.
If(A3>0=6=10,Number/24,"")))
please how do I go about.
I need a formula for:
If A1=1, then B1:B4=1, otherwise B1:B4=0. If A5=1, then B5:B8=1, otherwise B5:B8=0.
I can also do:
If A1=1, then A2:A4=1, otherwise A2:A4=0. If A5=1, then A6:A8=1, otherwise A6:A8=0.
When I try to copy this formula down to record 10,000 I am getting a loop error. Excel is returning:
A1
1
0
0
0
1
0
0
0
How can I fix this??
Hi Brianna,
Try entering the following formula in cells B1 through B4, and A2 through A4:
=IF($A$1=1, 1, 0)
And this one in cells B5 through B8, and A6 through A8:
=IF($A$5=1, 1, 0)
I've got two columns of numbers to compare and see if the difference is + or - 5. How would I make a formula to do that?
i want a formula in excel that will return a value with it superscript Eg 1st
Hi I want to use this formula with =If condition
=RIGHT(A2,LEN(A2)-FIND(" ",A2,12))
i tried many time but it not fits in.
=if(A2<len(9),"Write your full name,RIGHT(A2,LEN(A2)-FIND(" ",A2,12)))
why this is not working????
Please guide me
Hi Nadeem,
Sorry, I cannot understand what your RIGHT formula does. Can you explain in words?
Anyway, the IF function may look similar to this:
=IF(LEN(A2)<9,"Write your full name", RIGHT())
It returns "Write your full name" when A2 contains less than 9 characters. Otherwise, what is it supposed to return?
I am trying to run an IF formula this is what I was trying to do =IF(A1>0,[A1=B1],[A1=0])
Basically if cell A1 is greater than zero I want the cell to be replaced with the data from cell B1, however if cell A1 is not greater than zero I want the cell to equal zero.
Can someone please help?!!!
Hi Mel,
You don't want square brackets in IF formulas:
=IF(A1>0, B1, 0)
Hi, i am wondering if it can be done when i sale an item and lets say inventory is 20 so i sold one and inventory changes to 19 i want a column to go plus every minus i do in the inventory.
Hello Rupesh,
You need a nested IF formula like this:
=IF(A2>90, 4, IF(A2>=80, 3, IF(A2>=70,2,1)))
Hi. I’m trying to figure out how to do two different calculations in a cell. Using the IF function.
It involves 3 different cells
If cell C3 has a number greater than 0, I multiply C3 by C1 plus the total in cell B2 to get a running total in the second row . Easy enough. My problem comes when I want to put in a 0 in C3 and then the cell has to multiply the running total by .5 (cutting the total in half).
I’m not sure how to put both in one cell. I would appreciate any help.
Thank you.
P.S. this is to keep score in a dart game called Shanghai ?
( >90 then 4, 80-90 then 3, 70-80 then 2 and <70 then 1
i tried to put a formula on this but its not working.
can you please suggest
i need help, i have data which i need to analyse, in a cell i have entered data for males and females with the figures of household size, e.g male 2 and female 3, so i need a formula to find the total of males and females separately.
Hello Givious,
I believe you need a SUMIF formula. Please check out this tutorial:
https://www.ablebits.com/office-addins-blog/excel-sumif-function-formula-examples/