by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
I need to use IF function on below case;
If one item is available from a column, then Yes or else No. Please advise the fuction.
Hi Jay,
Here is an example:
=IF(A1="item you want", "yes", "no")
hi,
In my data all the values are in Indian currency in rupees. While I create pivot table summary, all the values comes with in rupees. But I needs those figure should come in Lacs.
Thanks in advance.
HI,
I WANT TO CREATE IN EXCEL 2007 Which shows that in a selected cell (specifically Column K in spreadsheet in each cell downwards)if I will type a Value on it(numbers. 1-9) it will correspond to a word. say for example 1 means okay, 2 means not yet and etc. some sort of shortcut techniques in typing for that word. what kind of Formula should I use? Please let me know.
Thanks Svetlana!
Hi JAS,
You can use nested IF functions, like this:
=IF(A1=1, "ok", IF(A1=2, "not yet", IF(A1=3, "smth else", "")))
Excel 2007 allows adding up to 64 nested IF in one formula.
Great, thanks a lot!
I created a quiz and used data validation. I want to get 1 mark for the answer of 42 otherwise 0. I used if(A4="42", 1,0).it give me 0. am I using wrong syntax
Hi Istkar,
You don't need to enclose numbers in double quotes unless you want them to be treated as text strings. Once you remove "", your formula will work great:
=IF(A4=42,1,0)
can you help with the below:
i am creating a sheet for associates in my company. 1 tab has all details of the associate that a company database should have. column 'F' has the designation of the associate and column "A" has names
what i want to do (in another tab in the same excel). wherever column "F" has designation as manager the cell in the new tab should show me the name of that associate.
eg: if cell value f4=manager then value in new cell (in new tab) should be name as in A4.
i want the same to be applied to every cell.
Hi Ankit,
Hopefully, this is what you are looking for:
=IF(F4="manager", A4, "")
How many times i can add IF in one formula.
In Excel 2013, Excel 2010 and Excel 2010, you can add up to 64 nested IF functions. In older versions of Excel, you can use a maximum of 7 IFs in one formula.
Hi, Svetlana!
I'm trying to make an Excel 2013 formula that will extract a person's last name from a cell that has their full name. Unfortunately, the fullname cell can contain any of these formats:
First Last
First M. Last
F. Middle Last
F. Middle Second_middle Last Jr.
The formula to extract the last name form a "First Last" cell is easy (where A5 is the fullname cell):
=RIGHT(A5,LEN(A5)-FIND(" ",A5))
...but I need to be able to find the last instance of a space character to lead off the RIGHT() function location. That would work for the first three examples, but not the last. Not sure what to do about that one, unless maybe an exclusion list of common suffix titles?
I'd be most interested in your help.
Cheers!
Ted
I have created a spreadsheet for working out the pay of our employees. The data starts in Row 14. Col A contains that week's pay date eg. 24/3/15 etc. Col B has the total hours the employee has worked that week. Column C then multiplies the hours from Col B by the employees pay rate to give me their gross pay for that week. Cols D-F contain various deductions relevant to that employee & Col G lists net pay. Following that there are 4 more rows containing the above info with the hours listed as 0 unless it is used for that week's pay, and the sixth row adds up the totals for that month & displays them as *??.??.
In cell b3 I want a formula that tells me how many hours the employee worked in the last 4 weeks e.g..it will look down column B, find the last hours entry (ie. the last number that is greater than 0 & does not have an *), then add to this number the previous 3 weeks hours (ie. the previous 3 numbers greater than 0 & without an *). If it makes it easier I am happy to enter in the cell reference that contains the last hours entry (rather than Excel working that out) as I am not going to need this information on a regular basis.
In cell b4 I want to do do the same thing as b3 except i want to know how many hours the employee worked in the last 52 weeks (or if they haven't actually worked 52 weeks yet, their total hours so far).
I'm sure that this is not actually a difficult formula to write but excel is not my forte! Please let me know if you need further clarification.
Thanks a lot Svetlana that worked as expected :)
Cheers
I've two columns A & B, out of this i want to check against A column name if B column is not blank then it should show complete else Partial, for more understanding see below example
C-A C-B Output
A ABC12 Complete
A 105 Complete
A 13 Complete
B 213 Partial
B ABC12 Partial
B Partial
Hi Rajendra,
I am afraid our blog engine has made a mess of your data :( I understand about B column being non-blank. But exactly what shall we check against A column?
If somebody can please help me.
Mentioned below is my problem
I have a time format and I am trying to put an If formula which should give me a yes or no if its greater than or equal to a specific time
FOR EXAMPLE:
If (04:07:47)is greater than or equal to (04:00:00)then YES else NO
Hi Raymond,
If both times are entered in some cells, then you can use a simple IF formula like this:
=IF(A2>=B2, "yes", "no")
Where B2 is 04:00:00.
If you want to specify one of the values directly in the formula, then you will need the TIMEVALUE function is addition to IF:
=IF(A2>=TIMEVALUE("4:00:00"), "yes", "no")
Thank you Svetlana! To take this one step further and I tried couldn't get it to work
=IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) then take answer of this and calculate the difference between the answer and D1 *100* E1
This is more in line with what I was thinking all wrapped up in one formula - =IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) --- This is the first operation
IF cell O25 is a positive number subtract U25 or IF cell O25 is a negative number add U25 --- This is the second operation
How would you write them separate and within on formula sequence?
Thank you again!
Hi Jason,
Please specify if these are AND or OR conditions?
For example, if A1="put" and O25 is a positive number, then what do we do?
If A1="put" and O25 is a negative number, then... ?
And the same for A1="call", please.
What I believe I'm trying to do is calculate the positive or negative variance (on a non absolute basis)
My apologies, so I have your formula =IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) ... in column "U"
And in column "V" I'm trying to calculate the actual difference between cell O25 and U25(i.e. Add if a number is negative, Subtract if a number is positive)say if U25 Is positive and O25 in positive then O25-U25 or if U31 is negative and O31 is positive then U31+O31
I was also would like to combine this formula with your =IF(A1="put",C1-B1,IF(A1="call",B1-C1,""))
Let me check if my understanding is correct. If values in both columns U and O are positive, then O25-U25. If a value in either column or in both columns are negative, then U325+O25. If so, I would suggest that you keep the formula in column U as is and put the following one in column V (it is actually for cell V25, but you can easily adjust the references:
=IF(AND(U25>0, O25>0), O25-U25, U25+O25)
Also, please note that the formula equates zero to negative numbers. If you want to treat 0 as a positive number, then change the logical test to AND(U25>=0, O25>=0)
If I misunderstand something, please correct me.
Nope you made my nonsense into sense;-) So in that last formula =IF(AND(U25>0, O25>0), O25-U25, U25+O25)... how would I make any negative result display 0 and any positive result show the full value of the calculation?
i need help putting this in the if function, if an employee has a taxable income of greater $739, then the federal income equals $110.85 plus the federal tax rate found in cell B19 multiply by the taxable income excess of $739. if an employee taxable income is $739 or less, the federal tax witheld equals the taxable income multiplied by the federal taxrate found in b18
HOW TO MULTIPLY ONE VALUE OF A CELL BY THE PERCENT OF ANOTHER CELL
Hi Thello,
For example like this:
=A1*(A1*10%)
If you are looking for something different, please provide a bit more details.
Hi Svetlana how would you write this all in the same cell ... (If Cell A1 says “PUT” then Subtract cell B1 from C1 OR If Cell A1 says “CALL” then Subtract C1 from B1)
Hi Jason,
You need a nested IF like this:
=IF(A1="put",C1-B1,IF(A1="call",B1-C1,""))
Hi,
I'm trying to get my formula to say if I5=Y or N/A then 0 value, if not then 1 value. I'm using this: If(I5="Y""N/A",0,1) but I'm getting the value 0 no matter what's in I5. I5 is either Y, N, or N/A, and I only want it to populate when there's an "N". I thought the problem was that "N" and "N/A" both contain "N", but I typed in "fill" to test and still 0 value. Please help. Thanks!
Hi Felicia,
Since you have 2 conditions, you should include the OR statement in your formula, like this:
=IF(OR(I5="Y", I5="N/A"), 0, 1)
I am trying to populate a cell with the description "Current", "30 Days" and so forth.
I know I can use this Formula
=IF(L2>0,, "Current")
=IF(L2>30,, "30 Days")
=IF(L2>60,, "60 Days")
=IF(L2>90,, "90 Days")
=IF(L2>120,, "120 Days")
How do I make a full sentence (Combining all) of this so i don't have to do this individually?
Hi,
How can I restrict the cell in excel, where user have to enter the date in "MM/DD/YYYY" format only.
How could we change the color of the Cell if the logical_test is true or false?
Thank you.
You cannot change the color with a formula. You have to use Excel conditional formatting for this, as demonstrated in this tutorial:
https://www.ablebits.com/office-addins-blog/excel-conditional-formatting-formulas/
Hi,
in column A user will be entering date. In column B the month will get updated automatically with =Month(A1) function.
Now I want if the cell of A column is blank, then in column B will be showing "-" & the moment user enter the date it will return the month.
What would be the formula in excel... pl surrgest
Hi!
I believe this is what you are looking for:
=IF(A1="", "-", MONTH(A1))
=if(A1=12," ","12"),if(A1=8,"16"),if(A1=16,"8")
can anyone fix it... it will a very helpfull for me...
thank you very much
Hi Aidil,
It looks like you have to either concatenate those 3 IFs or use nested IF as explained in this tutorial:
https://www.ablebits.com/office-addins-blog/excel-if-function-multiple-conditions/#excel-if-multiple-and-or
If you can explain exactly what result you are after, I think we will get the right formula.
Hi there I am wondering if you can help me
I have the following data across columns and the desired outcome would be merge the cells sideways into a new cell and delete the duplicates.
Column J Column K Column L etc
Row 2: Article sign up | City1 | City2 = Article sign up, city 1, city 2
Row 3: Article Sign up | Article sign up | City 1 | City 1 = Article sign up, city 1
Row 4: Article sign up | Article sign up | City 2 | City 2 = Article sign up, city 2
Can you help?
Hello everyone,
I'm looking for a formula that looks at date ranges - so if the date of the line item is between 'date 1' and 'date 2' then display the line item in on a separate sheet.
Similarly if the date of the line item is NOT within 'date 1' and 'date 2' then display the line item on another sheet.
Any assistance would be greatly appreciated!
Hi Lorna,
You need two different formulas like these:
1. If between 2 dates:
=IF(AND("line item date">date1, "line item date"<date2), "line item", "")
2. If outside the date range (not within 2 dates):
=IF(OR("line item date"<date1, "line item date">date2), "line item", "")
If you can provide more details about your date structure (in what columns are dates and where are line items), I think we will get the real formula.
Hi Everyone,
Nice Day !
All medical representative send their reports in 2 excel sheets,
1.sales Visit – with date,product,doctors list
2.Office Word
now i have to compare these 2 lists and make a new report that whether they have send report or not according to names and date.
if they send 01 mar, then i put yes
if they not send 02 mar, then i put no
can anyone tell me which formula can use to compare these 2 list and make it automatically “yes” and “no” according to medical rep names and dates.
Advanced Thanks for reply
it doesn´t paste all the formula.. sorry
=(IF(B2=21,B2=40,B2=71,B291,"VFEL"))
Hello,
I ave a situation, i whish you can help me with: i need to work on a formula with the if funtion. i have to mark a range of values, for example: all the values are in the cell "B2"
range: 1 - 100
markA: 1 - 20 ( "a" )
markB: 21 - 35 ( "b" )
markC: 36 - 50 ( "c" )
markD: 51 - 89 ( "d" )
markE: 90 - 100 ( "e" )
i have try the next formula:
=(IF(B2=21,B2=40,B2=71,B291,"VFEL"))
but it says the is a error, can you help out ?
thanks
Hi Ussiels,
I am not sure I exactly understand the task, but it looks very similar to this one that can be solved using nested IFs.
Is this what you are looking for?
Hello,
I have a due date column that is calculated at 30 days after a transfer date column. However, when I put the formula "=A1+30" in the due date column it returns a date of 01/05/1900 for rows that don't have a date entered in the transfer date column. How do I get this to stay blank unless there's a date entered in the transfer column?
Thank you,
Jordan
Hi,
I'm looking for a formula that will return the last value greater than 0 from a range if the cell initially referenced is equal to 0.
Seems like it should be easy but I'm stuck on it.
Thanks
Hi,
I want to have a formula whereby i am doing an itinerary costing. i have a start date and then dates with prices of accommodation...the dates with the price of accommodation i already have IF(B3=DATE(2015,1,1),"7500","0").....
Now I want to have a formula where by I when the start date of the itinerary changes, then all the dates in the in the itinerary change and this change in starting date will also lead to a change on the prices.
Thanks
HI Svetlana,
I'm trying to write a formula that returns me 'true' or 'false' depending on whether there's a £ sign in a cell with numbers, ie: £32 gives 'true', but
€32 gives 'false.
I've tried your:
=IF(ISNUMBER(FIND("£",G7)),"true","false") and
=IF(ISTEXT(FIND("£",G7)),"true","false") ,
and both of them with SEARCH instead of FIND
but they don't work, presumably because £ isn't text or number. I vainly tried various things like ISCHARACTER and ISSYMBOL as well....
Hope you can help.
Thank you.
Geoff
Hey guys - it seems as though I came to the right place...I am using excel 2007 and trying to work a formula to check cell A1 for a value of 1 and if the value of 1 is there, then insert the current date in cell A2. Please help.
IN YOU TUBE I AM FEELING EASY TO UNDERSTAND ANY CONCEPT REGARDING EXCEL BUT IN GOOGLE IT IS LITTLE BIT COMPLICATED FOR ME AS BECAUSE THERE IS NO VIDEO LIKE YOUTUBE AND ALSO I AM A PLAIN GRADUATE.PLEASE DON'T MEAN IT WHAT I HAVE WROTE.I AM HAVING VERY EAGER TO LEARN EXCEL BUT I AM 35 YEARS OLD.PLEASE SEND EASY SOLVED SOLUTION OF EXCEL VIDEO IN YOUTUBE AND IN GOOGLE.
THANKS & REGARDS
Hi,
I am trying to figure out a formula for m aging. If its a negative number then its current, if it is between 1-29 days it's "30 Days", if it is between 30-59 days "60 Days",if it is between 60-119 days "90 Days" and if it is between 120-365 days its 120 days.
Please Help!!!!
Hi Svetlana,
I would like the next cell to represent if it is higher, lower, or equal to the previous cell. Each cell represents a total of items for a month. Ideally, it would be an up or down arrow (in green or red) for the execs to immediately identify changes.
Hi,
I need some help, I'm new to the formulation.
I need to create a sub-production plan link to another sub-plan
but I don't know at all how to do it.
Example sub-production have 2 shift opening stock,need create auto plan minus current balance 2 shift with quantity issue
I need to create a sub-production plan link to another sub-plan.
With opening 2 shift stock, current shift auto plan which minus stock issue from opening 2 shift stock to get return of 2 shift stock and 2nd auto shift will continue, once reach to one date which no plan, so auto plan automatically stop generate plan.
Could it be done.
Your deliberation on helping me is much appreciate.
Hi - need some help in extracting xxxx from a column that has"router bgp xxxx". xxxx varies across cells. What function can i use to extract xxxx?
Appreciate the help in advance!!!
I have a spreadsheet that has maximum number of locations in column B and and minimum number of locations in column C that a client uses as a reference when choosing services. the client seeing these number enters their desired number of locations into column D which is where the formula would be entered. Want them to be able to put in their own number that will show on the spreadsheet BUT...I do not want it to let them enter a number that is lower than the minimum or higher than the maximum. I also do not want it to say false or OK I would like the number they have added to show.
Additionally if they try to go less than min or more than max, I would like a pop up box saying "You must enter a number that is less than the maximum and greater than the minimum number allowed"
I have two columns of numbers, side by side. New numbers are loaded into the left column each day (column 1). I want to save the historical high number in a cell beside it (in column 2). If the new number in column 1 is greater than the old historical number in column 2, I want the historical nigh number in column 2 to be changed to equal the new number that came into column 1.
How do I do that?
Hello, I am not sure if what I want done is possible. I am looking to say if "apple" is in cells a2:a36 and there is an amount in cells h2:h36 then I would like it to total those amounts. Is that possible?
Hi,
I am hoping to create a formula to use in conditional formatting that would allow me to perform the following:
I have a list of employees in column A, date in column B, and number of sales in column C.
I am wanting to conditionally format the sales cell (in column C) as new sales data is entered. I want to compare the new sales figure against the most recent number of sales for that particular employee. With a reduction in sales of >3 formatted red.
Your assistance is greatly appreciated.
I have 3 cells (L3,M3, N3) with either true or false as responses to earlier coding but need to highlight where I get answers that are True,False, True in that order . How do I achieve this?
Please Help me :
=if(a1=2366,2355,2353 then b1 will be 120, if(a1=2377,2357,2354 then b1 will be 130)) how can i put the formula..
i need to make a formula in excel to put bonus marks, for example if kevin got 25 marks he will got another 25 bonus, if he got 50 then another 25, each 25+ mark got bonus of 25... i will put only the mark on one cell and i need in the bonus mark to calculated by excel in another cell... please help
=IF(F2:F152="Yes", "G3"),(F2:F152="No", "G3") returned #VALUE! What is the issue?The logic I am trying to achieveshould be if F2 thru F152 = Yes then return the name G3 and if f2 thru f152 = No return the name in column G3. Can you give me the correct formula to achieve this?
Hello,
I want to write an If then statement that takes cell contents and adds the same word to different cells. For example. suppose CELLS A3:A36 are words related to education (i.e. test, assignment homework etc...) Now suppose I want to add the word "calendar" to the words in cells A3:A36. Which would return "test calendar", "assignment calendar", "homework calendar" etc..
How would I go about doing that?
hi,
i need help please,
how can i add number if my result is less than 0
example;
=(P9-DAY(TODAY())) and i got the result -1 i dont need to see - so i wanna add 30 how can i do that
thx
Please help, I need a formula like when you subtract A1-B1 if the answer is 0.something the answer will be 0.
Like this one: =IF (A1-B1<1,"0")
Thank you...
asskm..
saya ingin membuat satu rumus if :
jika A1 berisi desimal maka B1 adalah 1, jika A1 berisikan teks maka B1 adalah 0,
mohon bantuannya untuk bisa sy membuat rumus excelnya. terimakasih..
i was making employee salary sheet , i am using three rows,1st row is total hours, 2nd row is basic overs & 3rd second row is over time , our company basic hours is eight.
Example :-
total overs = A1=10 B1=12 C1=A .....Ext.
Baic overs = A2=8 B2=8 C2=A ....Ext.
Over time = A3=2 B3=4 C3=X...Ext
iam using basic overs A2 =IF(A1=8,"8",IF(A1="A","A"))))
A3=(=IF(A1=8,X,IF(A1=8.5,.50,IF(A1=9,"1",IF(A1=9.5,1.50,IF(A1=10,2,IF(A1="A","X"))))))
iam using this function ,but Sundays also working overtime . i need help you Sundays hours u need over time row which function use .......... please give him the reply