Comparing columns in Excel is something that we all do once in a while. Microsoft Excel offers a number of options to compare and match data, but most of them focus on searching in one column. In this tutorial, we will explore several techniques to **compare two columns** in Excel and find matches and differences between them.

## How to compare 2 columns in Excel row-by-row

When you do data analysis in Excel, one of the most frequent tasks is comparing data in each individual row. This task can be done by using the IF function, as demonstrated in the following examples.

### Example 1. Compare two columns for matches or differences in the same row

To compare two columns in Excel row-by-row, write a usual IF formula that compares the **first two cells.** Enter the formula in some other column in the same row, and then copy it down to other cells by dragging the fill handle (a small square in the bottom-right corner of the selected cell). As you do this, the cursor changes to the plus sign:

#### Formula for matches

To find cells within the same row having the same content, A2 and B2 in this example, the formula is as follows:

`=IF(A2=B2,"Match","")`

#### Formula for differences

To find cells in the same row with different values, simply replace the equals sign with the non-equality sign (<>):

`=IF(A2<>B2,"No match","")`

#### Matches and differences

And of course, nothing prevents you from finding both matches and differences with a single formula:

`=IF(A2=B2,"Match","No match")`

Or

`=IF(A2<>B2,"No match","Match")`

The result may look similar to this:

As you see, the formula handles **numbers**, **dates**, **times** and **text strings** equally well.

Tip. You can also compare two columns row-by-row using Excel Advanced Filter. Here is an example showing how to filter matches and differences between 2 columns.

### Example 2. Compare two lists for case-sensitive matches in the same row

As you have probably noticed, the formulas from the previous example ignore case when comparing text values, as in row 10 in the screenshot above. If you want to find **case-sensitive matches** between 2 columns in each row, then use the EXACT function:

`=IF(EXACT(A2, B2), "Match", "")`

To find **case-sensitive differences** in the same row, enter the corresponding text ("Unique" in this example) in the 3^{rd} argument of the IF function, e.g.:

`=IF(EXACT(A2, B2), "Match", "Unique")`

## Compare multiple columns for matches in the same row

In your Excel worksheets, multiple columns can be compared based on the following criteria:

- Find rows with the same values in
**all columns**(Example 1) - Find rows with the same values in
**any 2 columns**(Example 2)

### Example 1. Find matches in all cells within the same row

If your table has three or more columns and you want to find rows that have the same values in all cells, an IF formula with an AND statement will work a treat:

`=IF(AND(A2=B2, A2=C2), "Full match", "")`

If your table has a lot of columns, a more elegant solution would be using the COUNTIF function:

`=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")`

Where 5 is the number of columns you are comparing.

### Example 2. Find matches in any two cells in the same row

If you are looking for a way to compare columns for **any two or more cells** with the same values within the same row, use an IF formula with an OR statement:

`=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")`

In case there are many columns to compare, your OR statement may grow too big in size. In this case, a better solution would be adding up several COUNTIF functions. The first COUNTIF counts how many columns have the same value as in the 1^{st} column, the second COUNTIF counts how many of the remaining columns are equal to the 2^{nd} column, and so on. If the count is 0, the formula returns "Unique", "Match" otherwise. For example:

`=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0,"Unique","Match")`

## How to compare two columns in Excel for matches and differences

Suppose you have 2 lists of data in Excel, and you want to find all values (numbers, dates or text strings) which are in column A but not in column B.

For this, you can embed the COUNTIF($B:$B, $A2)=0 function in IF's logical test and check if it returns zero (no match is found) or any other number (at least 1 match is found).

For instance, the following IF/COUNTIF formula searches across the entire column B for the value in cell A2. If no match is found, the formula returns "No match in B", an empty string otherwise:

`=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "")`

Tip. If your table has a fixed number of rows, you can specify a certain range (e.g. $B2:$B10) rather than the entire column ($B:$B) for the formula to work faster on large data sets.

The same result can be achieved by using an IF formula with the embedded ISERROR and MATCH functions:

`=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)),"No match in B","")`

Or, by using the following array formula (remember to press Ctrl + Shift + Enter to enter it correctly):

`=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")`

If you want a single formula to identify both matches (duplicates) and differences (unique values), put some text for matches in the empty double quotes ("") in any of the above formulas. For example:

`=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "Match in B")`

## How to compare two lists in Excel and pull matches

Sometimes you may need not only match two columns in two different tables, but also pull matching entries from the lookup table. Microsoft Excel provides a special function for this - the VLOOKUP function. As an alternative, you can use a more powerful and versatile INDEX MATCH formula. The users of Excel 2021 and Excel 365, can accomplish the task with the XLOOKUP function.

For example, the following formulas compare the product names in columns D against the names in column A and pull a corresponding sales figure from column B if a match is found, otherwise the #N/A error is returned.

`=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)`

`=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))`

`=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)`

For more information, please see How to compare two columns using VLOOKUP.

If you don't feel very comfortable with formulas, you can have the job done using a fast and intuitive solution - Merge Tables Wizard.

## Compare two lists and highlight matches and differences

When you compare columns in Excel, you may want to "visualize" the items that are present in one column but missing in the other. You can shade such cells in any color of your choosing by using the Excel Conditional Formatting feature and the following examples demonstrate the detailed steps.

### Example 1. Highlight matches and differences in each row

To compare two columns and Excel and highlight cells in column A that have **identical entries** in column B in the same row, do the following:

- Select the cells you want to highlight (you can select cells within one column or in several columns if you want to color entire rows).
- Click
*Conditional formatting > New Rule… > Use a formula to determine which cells to format*. - Create a rule with a simple formula like
`=$B2=$A2`

(assuming that row 2 is the first row with data, not including the column header). Please double check that you use a relative row reference (without the $ sign) like in the formula above.

To highlight **differences** between column A and B, create a rule with this formula:

`=$B2<>$A2`

If you are new to Excel conditional formatting, please see How to create a formula-based conditional formatting rule for step-by-step instructions.

### Example 2. Highlight unique entries in each list

Whenever you are comparing two lists in Excel, there are 3 item types that you can highlight:

- Items that are only in the 1
^{st}list (unique) - Items that are only in the 2
^{nd}list (unique) - Items that are in both lists (duplicates) - demonstrated in the next example.

This example demonstrates how to color the items that are only in one list.

Supposing your List 1 is in column A (A2:A6) and List 2 in column C (C2:C5). You create the conditional formatting rules with the following formulas:

Highlight unique values in List 1 (column A):

`=COUNTIF($C$2:$C$5, $A2)=0`

Highlight unique values in List 2 (column C):

`=COUNTIF($A$2:$A$6, $C2)=0`

And get the following result:

### Example 3. Highlight matches (duplicates) between 2 columns

If you closely followed the previous example, you won't have difficulties adjusting the COUNTIF formulas so that they find the matches rather than differences. All you have to do is to set the count greater than zero:

Highlight matches in List 1 (column A):

`=COUNTIF($C$2:$C$5, $A2)>0`

Highlight matches in List 2 (column C):

`=COUNTIF($A$2:$A$6, $C2)>0`

## Highlight row differences and matches in multiple columns

When comparing values in several columns row-by-row, the quickest way to highlight matches is creating a conditional formatting rule, and the fastest way to shade differences is embracing the *Go To Special* feature, as demonstrated in the following examples.

### Example 1. Compare multiple columns and highlight row matches

To highlight rows that have **identical values in all columns**, create a conditional formatting rule based on one of the following formulas:

`=AND($A2=$B2, $A2=$C2)`

or

`=COUNTIF($A2:$C2, $A2)=3`

Where A2, B2 and C2 are the top-most cells and 3 is the number of columns to compare.

Of course, neither AND nor COUNTIF formula is limited to comparing only 3 columns, you can use similar formulas to highlight rows with the same values in 4, 5, 6 or more columns.

### Example 2. Compare multiple columns and highlight row differences

To quickly highlight cells with different values in each individual row, you can use Excel's **Go To Special** feature.

- Select the range of cells you want to compare. In this example, I've selected cells A2 to C8.
By default, the top-most cell of the selected range is the active cell, and the cells from the other selected columns in the same row will be compared to that cell. As you can see in the screenshot above, the active cell is white while all other cells of the selected range are highlighted. In this example, the active cell is A2, so the

**comparison column**is column A.To

**change the comparison column**, use either the Tab key to navigate through selected cells from left to right, or the Enter key to move from top to bottom.Tip. To select

**non-adjacent columns**, select the first column, press and hold Ctrl, and then select the other columns. The active cell will be in the last column (or in the last block of adjacent columns). To change the comparison column, use the Tab or Enter key as described above. - On the
*Home*tab, go to*Editing*group, and click*Find & Select*>*Go To Special…*Then select**Row differences**and click the*OK*button. - The cells whose values are different from the comparison cell in each row are colored. If you want to shade the highlighted cells in some color, simply click the
*Fill Color*icon on the ribbon and select the color of your choosing.

## How to compare two cells in Excel

In fact, comparing 2 cells is a particular case of comparing two columns in Excel row-by-row except that you don't have to copy the formulas down to other cells in the column.

For example, to compare cells A1 and C1, you can use the following formulas.

For matches:

`=IF(A1=C1, "Match", "")`

For differences:

`=IF(A1<>C1, "Difference", "")`

To learn a few other ways to compare cells in Excel, please see:

## Formula-free way to compare two columns / lists in Excel

Now that you know Excel's offerings for comparing and matching columns, let me show you our own solution for this task. This tool is named Compare Two Tables and it is included in our Ultimate Suite.

The add-in can compare two tables or lists by any number of columns and both identify matches/differences (as we did with formulas) and highlight them (as we did with conditional formatting).

For the purpose of this article, we'll be comparing the following 2 lists to find common values that are present in both.

To compare two lists, here are the steps you need to follow:

- Start with clicking the
**Compare Tables**button on the*Ablebits Data*tab. - Select the
**first column/list**and click*Next*. In terms of the add-in, this is your Table 1. - Select the second
**column/list**and click*Next*. In terms of the add-in, it is your Table 2, and it can reside in the same or different worksheet or even in another workbook. - Choose what kind of data to look for:
**Duplicate****values**(matches) - the items that exist in both lists.**Unique****values**(differences) - the items that are present in list 1, but not in list 2.

Since our aim is to find matches, we select the first option and click

*Next*. - This is the key step where you select the
**columns for comparison**. In our case, the choice is obvious as we are only comparing 2 columns:*2000 Winners*against*2021 Winners*. In bigger tables, you can select several column pairs to compare by. - In the final step, you choose how to deal with the found items and click
*Finish*.A few different options are available here. For our purposes, these two are most useful:

**Highlight with color**- shades matches or differences in the selected color (like Excel conditional formatting does).**Identify in the Status column**- inserts the*Status*column with the "Duplicate" or "Unique" labels (like IF formulas do).

For this example, I've decided to highlight duplicates in the following color:

And in a moment, got the following result:

With the *Status* column, the result would look as follows:

Tip. If the lists you are comparing are in different worksheets or workbooks, it might be helpful to view Excel sheets side by side.

This is how you compare columns in Excel for matches (duplicates) and differences (unique values). If you are interested to try this tool, you are welcome to download an evaluation version using the below link.

I thank you for reading and encourage you to check out other helpful tutorials that we have :)

## Available downloads

Compare Excel Lists - examples (.xlsx file)

Ultimate Suite - trial version (.exe file)

## 548 comments

I was looking for solution to compare two columns having cells containing sentences( with few matching words- since letters send by different clients) in two different worksheets and return value to update missing letter nos.

Hi! If the methods suggested in the article above do not work for you, provide an example of the source data for the desired result.

This will help understand what you want.

hi,

I have a situation using excel formulas.

i have 2 columns B2, B3 having downtime and uptime data ( downtime/uptime = date with time in same column ) i have to get difference time from uptime and downtime uptime - downtime = " ".

note: i want diff time in hh:mm:ss or hh:mm and after that, i want total mean/sum time of diff time.

Hi! We have a special tutorial on this. Please see: Calculate time in Excel: time difference, add, subtract and sum times. Don't forget to set the formula cell to the time format you want. For example, "hh:mm:ss".

Is there a way that I can compare 3 columns (id,from,to) in sheet1 with 3 columns (id,from,to) in sheet2 and if all 3 columns are the same, select a value from another column in sheet2?

Hi! To search for a value based on three conditions, you can use the INDEX MATCH function as described in this article: Excel INDEX MATCH with multiple criteria - formula examples. The formula might look like this:

=INDEX(Sheet2!D1:D10, MATCH(1,(Sheet2!A1:A10=Sheet1!A1) * (Sheet2!B1:B10=Sheet1!B1) * (Sheet2!C1:C10=Sheet1!C1),0))

You can also use the XLOOKUP function and these instructions: XLOOKUP function in Excel with formula examples.

=XLOOKUP(1,(Sheet2!A1:A10=Sheet1!A1) * (Sheet2!B1:B10=Sheet1!B1) * (Sheet2!C1:C10=Sheet1!C1),Sheet2!D1:D10)

You can also find useful information in this article: Advanced VLOOKUP in Excel: multiple, double, nested.

Is there any way of making excel show the difference between two cells/columns?

I have a situation where some of the lookups fail even though the corresponding value seems to be in the lookup area. If I press F2 and then enter to have Excel "reenter" the value, the lookup works fine.

I've tried changing format of the cells between default/text, but that doesn't help. I've tried copying the entire row and pasting "as values" but that doesn't work. The only thing that I've found to work is the F2 -> enter aproach. But as there are thousands and thousands of rows, I can't use that.

But since that "fixes" the data, I am left to believe that it is a matter of special characters in the field; which I could then filter in the comparison. But I don't know how to get Excel to show me the actual difference.

Hello! To remove a non-printing character from a cell, you can try using these instructions.

I recommend paying attention to the Remove characters tool. You can easily remove text or numbers, non-printing characters, punctuation, special symbols, and more. The tool is included in the Ultimate Suite for Excel and can be used in a free trial to see how it works.

Hi Alexander,

I tried your instruction, and it proved that my theory was wrong :) Seems to be some linguring formatting problem.

The situation is that I have a long list of Ids. Some are straight numbers, but some have letters or even hyphen (-). So everything is formatted as text.

These values I have to lookup in a seperate spreadsheet. That spreadsheet starts out without formatting (Default). So I have highlighted the columns with Ids and formatted as text, so now I expect to match text to text. But it cannot find the values.

Using the =CODE approach, it correctly returns 57 and 49 (for 9341), meaning that the 9 and 1 are correctly identified as the first characters from the left and right.

A comparison using

=IF(A1=LookupSheet!A53,TRUE,FALSE) returns FALSE

=EXACT(A1,LookupSheet!A53) returns TRUE

So =IF is seeing something that EXACT is ignoring. Any suggestion how I put that into a lookup formula? :)

Hi! EXACT function:

Compares two text values and returns TRUE if they are exactly the same, including case, spaces, and formatting.

Operator =:

Compares two values and returns TRUE if they are the same in value, but not necessarily in type.

If A1 has the number 9341 written as text and B1 has 9341 written as a number, A1=B1 will return FALSE and =EXACT(A1,B1) will return TRUE.

Indeed. But how would you go about doing a lookup between the two?

I've tried marking the entire column, and then formatted it as text. But that doesn't work (until I use F2 on each cell).

So I'm looking for some sort of lookup, where the values in the table get converted to text before it tries to find the value. TEXT doesn't work for this, but it would be =VLOOKUP(A1, TEXT(Sheet!Table), 3, FALSE) kind of thing

Hi! Learn how to use the TEXT function to convert a number to text: Excel TEXT function with formula examples.

For example:

=VLOOKUP(B1,TEXT(A1:A10,"@"),1,FALSE)

or

=INDEX(C1:C10,MATCH(B1,TEXT(A1:A10,"@"),0))

Perfect, thank you! :)

Good day Alexander,

Do you have idea how to compare two cells with text, and then highlight the text different between the two cells? Thanks

Example:

Cell A1 contain the text : IC1A, IC1B, IC1C, IC1E, IC1F

Cell B1 contain the text : IC1A, IC1B, IC1C, IC1D, IC1E, IC1F

Hi! You can use the TEXTSPLIT function to split text into cells and then identify duplicates. However, you cannot use an Excel formula to change the format of any part of the text in a cell.

Noted & thanks for the information

I have a sports draw with 16 teams in multiple rounds. Games are paired with rink numbers 1-8

Column A Teamnames, column B Rinknumber, column C calculates the opponent.

Example A4 ="blue" A15 = "red", B4 = 4, B15 = 4 so blue is playing red on rink 4 in round 1.

Calculated cell C4 needs to return opponents "red" and C15 needs to return "blue"

This sounds real easy but duplicates in lookup confound the issue.

Hi! If I understand your task correctly, this article may be helpful: Excel INDEX MATCH with multiple criteria - formula examples. Based on the information provided, the formula could look like this:

=INDEX($A$1:$A$16,MATCH(1,($A$1:$A$16<>A1)*($B$1:$B$16=B1),0))

Thanks heaps Alexander, so easy when you "see" it and it works perfectly. Using matching pairs to retrieve relative data seems such a basic task for Excel I'm surprised there isn't a function to do it without needing a complex formula.

A2 To O2 15 Cell Data Contain A Or B Or C Or D Or Nothing Student Attempt

Actually This Regarding 10 Question Attempt From 15 But Student Maybe Answer 0 To Max 15

I Have To Check With Maximum 10 First Attempted If More Than 10 Ignore Further

Need Only First Attempted 10 Count Right Or Not

A1 To Q1 Is Correct Ans Key Which Does Only From A Or B Or C Or D

Trying From More Than 5 Months To Figure This With Gpt

Reply Please

If Email Me That Would Much Better

Student Have To Solve Max Any Any 10 Q From 15 And There Is No Limit For Solving Minimum

First Attempted 10 Check Maximum If More Than 10 Attempted Whatever He Answers Ignore Further Counting

Correct Count Need From First Attempted 10

It would be good if you could explain in detail what you want to do. As it's currently written, it's hard to tell exactly what you're asking.

Could I Send You Example Excel Sheet

Could You Mail Me So I Reply

Hello, I'm trying to find a way to write a conditional formula that "strengthens" a cell highlight based on if the number of partial text matches from different columns occur. Column A has the name "John Smith" and then there are three subsequent columns, B-D, that each has an address. I am trying to get the highlight to be a light color if only one Column has the address in "Gotham, US", and then a darker color, if two columns list "Gotham, US", and then a darker color if all three columns have "Gotham, US". I don't know if this is within the capabilities of excel or macros to automate.

Hi! You can create three separate rules for each color. The order of these rules is important. For more information, read: Apply multiple conditional formatting rules to same cells.

Hi all, any help would be greatly appreciated. My data in column A is a specified number on a chart, row B is the actual value that the number in column A represents. How would I use the number in column A on a different sheet to equal the sum from columns C, D, E etc. using the numbers from column B on the first sheet? Example...

Column A row 1=10 Column B =324, so in essence A1=B1 but I need column F on the second sheet to sum total the numbers using the numbers from Column B when I put in the Column A equivalent. Thanks in advance!

Hi! Please clarify your specific problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.

I have a chart that I am trying to use. Column A will be the psi reading Column B will be the GPM equivalent. I have a second sheet that will be my test results. In one row I will have up to 5 different entries that are psi readings. I am trying to calculate the sum of the gpm equivalent to the psi measurement input on the row on my test results sheet. So for example again I have 10 psi in A1 the equivalent in B1 is 493 gpm, A2 11psi is equal to B2 at 517 gpm, my list carries on with equivalents up to 70 psi in Column A. How can I sum the total gpm by inputting the psi equivalent? If I have 1 row with multiple psi readings. Psi1 = 10, psi2 = 11, psi3=10 which would sum up to 1503 gpm. It's a conversion chart that need to be able to input psi and have excel calculate the results for gpm. Thanks!

Hi! To answer your question requires specialized knowledge regarding the physics of the processes you describe.

Hi i have aging report, I HAVE COLUMn A as tenanant code (which is repeating), Column b as Charges / receipt, Column C as amount of (charge or receipt), i want to filter only the charges which have no corresponding payment or receipt.

Hi! The following tutorial should help: Excel Filter: How to add, use and remove.

I have two columns of data, A and B. Each has 1000 rows. The goal is to compare each cell data on column A throughout column B and find exact matches of each cell in column A in column B. Then return the matching cell reference of Coulumn B

Hi! Determine the position of the matched cell using the MATCH function and get the address of that cell using the ADDRESS function.

Try this formula:

=IFERROR(ADDRESS(MATCH(A1,$B$1:$B$100,0),2),"")

If cell A2 has "Know me as well or not" and cell B2 has "but i know me as well" how to calculate percentage match between these two?

Really I got correct formula excatly what I expected. Thank you so much

Is there a way to compare data in one column to data in another column for mismatches and then have only the data that is different be highlighted or change the text color?

For example:

Col A Col B

State Farm State Frm In this example the "a" in Col A would be highlighted or a different color text

Hi! You can only compare the characters in two cells and highlight the color using a VBA macro.

Hello, would you mind sharing a VBA macro for this?

(only parts of the text in the cell that are different between 2 columns)

That'd very much helpful and appreciated!

Thank you so much!

Sorry, your request goes beyond the advice we provide on this blog.

Would you mind sharing the VBA macro for this? It will help a lot! Thank you so so much!

Hi, hoping you can answer an issue I am having. So eg. I have account numbers in column A, column B holds the users to that account number (there can be multiple users for one account) I need to pull the users of that one account into one cell…I then need to compare those results to column C (which holds the primary account user) and if it doesn’t match then return the value (user names). Is this achievable…?

Hi! Use the FILTER function to get an array of users with the account number that is written in D1. Then combine this into a delimited text string using the TEXTJOIN function.

Try this formula:

=TEXTJOIN(",",TRUE,FILTER(B2:B30,A2:A30=D1))

Selamat siang, saya memiliki 2 cell yang hampir mirip

Cell Sumber

A1 : Mei Jakarta 18

A2 : Mei Jakarta

Cell Hasil

A3 : 18

Apakah ada cara untuk memunculkan karakter yang tidak terduplikat di 2 atau lebih cell seperti contoh diatas?

terima kasih banyak

Hi! Combine the values into a text string with the TEXTJOIN function. Split this text string into separate words with the TEXTSPLIT function. Find unique words with the UNIQUE function.

=UNIQUE(TEXTSPLIT(TEXTJOIN(" ",TRUE,A1:A2),," "),FALSE,TRUE)

Hello,

If I have a large set of data and in each column is numbers for that specific value that makes it unique how can I compare that value to any other value like it and have them match up?

For example,

Peaches = 23, 44, 45, 67, 69, 50, 18, 16

Apples= 99, 44, 42, 67, 69, 40, 18, 16

and because they have 5 values in common I would want them to be highlighted or paired together some how.

Is this possible?

Thank you in advance

Correction** exact matches only.

Thank you

Hi! Maybe this article will be helpful: How to highlight duplicate cells and rows in Excel.

Hi,

I would like to compare and highlight same text string from 2 column.

Example:

D2 SALTED DUCK EGGS

F2 EGGS 360'S/CTN

I want compare these two column, search and highlight same text, EGGS

I have many rows need compare, D2 compare F2, D3 compare F3.

How to set formula, please advise, thanks~.

Hi! If you are looking for a specific word in the text, you can use these instructions: How to find substring in Excel.

If you are looking for any matching words, try Fuzzy Duplicate Finder. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.

I hope it’ll be helpful.

How I can compare only part of the text in two columns in the same row for this case:

Column A contains abc-123

Column B contains abc

I want column C to get FALSE if left part of the text in column A isn't the same.

Thank you!

Hi! We have a special tutorial on this. Please see: How to find substring in Excel

Try this formula:

=ISNUMBER(SEARCH(B1,A1))

Thank you so much!

I'd been looking for a formula forever, trying to figure out how to compare two columns of data (not just the corresponding rows) & have a separate column display whether one of the entries was unique to one list or not.

Many thanks :)

Hi

Could you please help me on below query.

In column a i have date and in column b i have date and other text.

How can I verify column a date and column b dates. If both are same

Hi!

If I understand correctly, you need to find a partial match of cell values. Use the TEXT function to convert the date to text in the correct format. Here is an example formula:

=ISNUMBER(SEARCH(TEXT(A1,"dd-mm-yy"),B1))

For more information, please read: How to find substring in Excel

how do we find true/false when cell "A" contain the name "a b c" and cell "B" contains the name "c a b"

Hi!

Your question is not very clear. To find a partial match of text strings, please read: How to find substring in Excel

Hi,

Is there a way to only highlight one set of duplicate in both columns?

If column A has the following numbers: 20, 21, 22, 23, 24 & 25

Then column B has the following numbers: 20, 20, 21, 22, 23, 20 & 25

Could only (1) of the 20s in column B be highlighted leaving the other 20 un-highlighted?

Hi!

If I understand the problem correctly, add another condition to the conditional formatting formula:

=AND(COUNTIF($C$2:$C$20, $A2)>0, COUNTIF($A$2:$A2, $A2)=1)

The second condition will allow only the first duplicate in the column to be highlighted with color.

Hello Alexander,

I believe you are close to figuring out my issue. If I use my example above, from A2-A7 I have entered 20, 21, 22, 23, 24 & 25 and from C2-C8 I have entered 20, 20, 21 22, 23, 20 & 25. After entering your formula, the first set of 20s are highlighted in cells A2 & C2 while the 20s in C3 & C7 are not highlighted - this is what I was looking for, thank you! However, the 21 in cell A3 is not highlighted while the 21 in cell C4 is highlighted. Additionally, the 24 in cell A6 is highlighted when there is not a duplicate 24 in column C.

I am looking to review a large set of numbers in (2) columns to see if the costs from one column are reflected in the 2nd. If the costs are only in (1) column then I will know something needs to happen in my budget to bring it back to normal. However, there will likely be the same number multiple times in both columns and I need a way to show which did not get reflected in the 2nd column. Please let me know if this situation makes sense or if there is a way to share my worksheet.

Thank you,

Gary

Hi!

I used your data and the conditional formatting formula suggested above for column A. Cells A2,A3,A4,A5 were highlighted. A6 - not highlighted.

I don't know what conditional formatting formula you used for column C.