How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4763 comments

  1. I could really use some help since the formula I'm using doesn't seem to be working. I have a drop down box in column A and column B with numbers ranging from 1-5. I'm creating in column C the "quadrant" it would fall in depending on the numbers selected in column A and B.
    For example. If A1=1 and B1=1 then C1= Quad1

    This is the formula I have to input in C1 but nothing happens... help please! I have no idea what I'm doing wrong.

    =IF(AND(A1="1",B1="1"),"Quad1","")

    • Hello,

      If I understand your task correctly, please try the following formula:

      =IF(AND(A1=1,B1=1),"Quad1","")

      Hope this will work for you

  2. Hello i have a list of over 272 phone contacts in 272 cells and i would like to put all of then in one cell with ease. How do i go about it?

    • Hello,

      Please try to solve your task with the help of the Merge Cells tool which is a part of our Ultimate Suite for Excel. You can download its fully functional 14-day trial version using this direct link.
      After you install the product, you will find Merge Cells in the Merge section under the Ablebits Data tab.

      Hope this will help you with your task.

  3. Hi Team,

    Could you please help me to find a solution for the below,i am handling logistic.we have some courier partner.i want to get a formula for rate calculation like, Pickup location 122016 and Delivery Area Pin code(any one Pan India) weight 0.500gms.
    Courier Partner Charging List

    Courier Partner Gurgaon To Gurgaon (Zone A) Gurgaon to Haryana,NCR (Zone B) Metro City to Metro City (Zone C) Gurgaon to Other State (Zone D) Gurgaon to North east india (Zone E)
    Zone A Zone B Zone C Zone D Zone E COD Rate COD %
    Aramex 32 42 50 55 71 35 2%
    Delivery35 43 52 59 73 39 2%
    Ecom 38 42 56 74 80 35 2%
    FEDEX 35 40 64 69 90 57 2%
    Holisol 28 36 48 66 66 35 2%
    Xpress 35 41 47 52 66 45 2%

    Now i want to know if Holisol is not service able in zone A for any pin code then formula will pickup automatically select Aramex in excel sheet for cheapest value or if holisol not provide COD Service for any pin code then automatically pick another courier partner by formula.

    Regards,
    Dinesh

    • Hi Dinesh,

      I'm sorry but your task is not entirely clear. For us to be able to help you better, please describe it in more detail and send us a small sample workbook with your source data and the result you expect to get to support@ablebits.com.
      I kindly ask you to shorten each table to 10-20 rows / columns.

      We'll do our best to help you.

  4. Please help me for this formula error

    =IF(L4 0<11,"Red",IF(L4 1112.5,"Green")))

  5. help me with a formula to compute Pass/Fail in a table with eight mark column with conditions pass if leaner obtains three 40 one of which should be Home language and three other 30

    • Hello,
      For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
      Please also don't forget to include the link to this comment into your email.
      I'll look into your task and try to help.

  6. Good morning,

    I am not sure if it is possible, but I am trying to use the IF function to name a product according to the bar code scanner. The scanner automatically enters the 15 digit number to an Excel column, but it does not name the product. For example, what I want to do, is create a formula that will apply the proper name for a given bar code. I assumed a nested "IF" formula would work, but apparently this is not the case. I can find no formula online that would handle such a seemingly simply application. Here is an idea of what I am trying to do:

    Bar Code: 123456789123456
    Product: Pinot Noir Wine

    I tried =IF(cell reference containing bar code = typed in bar code, "Pinot Noir")

    =IF(E2=123456789123456,"Pinot Noir, IF(E2..etc..etc..

    Does such a formula exist for this?

    RJ Lane

    • Hello,
      For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
      Please also don't forget to include the link to this comment into your email.
      I'll look into your task and try to help.

  7. Hi,
    I am searching the excel assistance for calculation of actual revenue for next year.

    Let's say.I rented one apartment from 9/Sep/17(C2) to 8/Sep/18(D2) at $ 1000(F2).I would like to make a spread sheet of monthly revenue for 2018 so that I have revenue columns from Apr 2017(G1) to Mar 2018(R1).The revenue should be shown starting from Sep 17 to Apr 18 according to my revenue column. I tried to use IF formula(=IF(G1<C2<R1=IF($C$2<G$1<$D$2,F2,"-")) in this case and I doesn't work out to get the correct revenue in respective column.

    Thank you in advance.

  8. I am going to create a tracker for my files with the following status "New File", "Pending", "Done", and "File sent to Author". What I want to do is, the STATUS Column should be generated automatically with the above status when the file is inputted on the excel file. I have here 5 examples of data. I cannot attach a file, but please take time to add this into excel so that this will be cleared and understand the format of this tracker. Every column has a header and next are the data. There are cells are intended to be blank depending on the status of the file. The image of the tracker is horizontal.

    First Column

    From month of
    Dec
    Dec
    Dec
    Dec
    Dec

    Second Column

    Product Code
    ABC
    DEF
    DEF
    GHI
    GHI

    Third Column

    File
    RO123
    RO456
    RO456
    RO789
    RO789

    Fourth Column

    Check-out Date
    N/A
    7-Dec
    7-Dec
    7-Dec
    7-Dec

    Fifth Column

    Print Check-out Date
    N/A
    N/A
    N/A
    N/A
    N/A

    Sixth Column

    Copy Check-out Date
    N/A
    N/A
    N/A
    N/A
    N/A

    Seventh Column

    Print/Copy/ Check-out by:
    N/A
    Marie
    Marie
    Marie
    Marie

    Eigth Column

    Check-in Date
    7-Dec

    7-Dec

    7-Dec

    Ninth Column

    Check-in by:
    Marie

    Marie

    Marie

    Tenth Column

    Requested by:
    Omar
    Omar
    Omar
    Omar
    Omar

    Eleventh Column

    Status
    New File
    Pending
    Done
    File/s sent to Author
    Done

    Thank you,

    • Hello,

      I'm afraid there's no easy way to solve your task with a formula. Using a VBA macro would be the best option here.

      However, since we do not cover the programming area (VBA-related questions), I can advice you to try and look for the solution in VBA sections on mrexcel.com or excelforum.com.

      Sorry I can't assist you better.

  9. Hi,

    Need make a If statement where, if the cell is blank it should return 'X' cells value and if the cells alphanumeric character length is 12 it should return 'X' cells value.

    • Hello,

      If I understand your task correctly, please try the following formula:

      =IF(ISBLANK(A1),B1,IF(LEN(A1)=12,C1))

      Hope this will work for you

      • Thank You Gennady, yes the formula works.

  10. I need to make an IF statement where one column is the expiration date and one is the current date and If the expiration date is 10 days less than the current date, then the expiration date cell will turn red. Any help would be appreciated. Thank you.

    • Hello,

      Supposing that the expiration date is in column A, please try to do the following:

      1. Select cells with your data.
      3. Click Conditional Formatting -> New Rule.
      4. Select the "Use a formula to determine which cells to format".
      5. In the Formula field type the following formula:
      =TODAY()-A1<=10
      6. Click the Format button to set the format you need.
      7. Click OK.

      We have an article on our blog that describes how to use conditional formatting in Excel. Please have a look at it.

      Hope it will help you.

  11. I am doing a budget spreadsheet. I have column C as what I spent my money on with drop down menus (Alcohol, Food, Gas, etc.). Column D is how much I spent. I would like Column I to be the totals of each item in the drop down list. Example: If it says Alcohol in column C then add all the numbers in column D that coincide with Alcohol.
    Alcohol 20.00 Alcohol 40.00
    Gas 44.00 Gas 88.00
    Food 100.00 Food 400.00
    Alcohol 20.00
    Gas 44.00
    Food 100.00
    Food 100.00
    Food 100.00

    • Hello,

      For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
      Please also don't forget to include the link to this comment into your email.

      I'll look into your task and try to help.

  12. Can someone help me with a formula
    if a purchase is $500 or more they can make the first payment in 180 days otherwise if less than $500 they make the first payment in 30 days. the result needs to show the new payment date

    • Hello,

      Please try the following formula:

      =TEXT(IF(A1<500,B1+30,B1+180),"mm/dd/yyyyy")

      where cell B1 contains a date value, e. g. 1/30/2018

      Hope it will help you.

  13. Hi,

    I've a situation where I have 4 cells to enter data in which If I enter data in Cell A then either B, C or D should have some entries or any of them should have entries. Can you please help me with this logic.

    Thanks
    Ramakrishna

    • Hello,

      Please create a custom Data Validation rule for cell A1 using this formula:

      =OR(NOT(ISBLANK(B1)),NOT(ISBLANK(C1)),NOT(ISBLANK(D1)))

      Please check out this article of ours to learn how Data Validation works.

      Hope it will help you.

  14. Hello,

    Can you please help me with a formula for a situation below.

    I have a column A with list of info (e.g. a-z), I want the second column (Column B) be such that if the text in column A matches/or contains the same text as Column C, then one value; if the text in column A matches/contains same text as Column D, another value, if the text in column A matches/contains same text as Column E, another value, and so on.

    Thanks you!

  15. hello, i got some problem in use of excel formulas,

    1 form=13.33 rs
    2 form=26.66 rs
    3 form=39.99 rs
    4 form=53.32 rs
    5 form=66.65 rs
    6 form=79.98 rs
    7 form=93.31 rs
    8 form=106.64 rs
    9 form=119.97 rs
    10 form=133.3 rs

    i want such type of formula that gives mi the proper value which i mentioned, by the typing of only value of no. of forms

  16. Hi. Good day!

    What would be the formula I can use for the details below.

    if Column A is "Corporate A", then amount is 25,000;
    if Column B is "Corporate B", then amount is 55,000;
    if Column A is "Academe", then amount is 15,000;
    if Column A is "Individuval/Startup", then amount is 5,000;
    if Column A is "Support Sector", then amount is 60,000.

    Your help will be much appreciated. Thanks!

    • Hello,

      Please try the following formula:

      =IFS(A1="Corporate A",25000,B1="Corporate B",55000,A1="Academe",15000,A1="Individuval/Startup",5000,A1="Support Sector",60000)

      Hope it will help you.

  17. Hey! I am trying to write an IF FUNCTION that will take the value of a cell in a table in the cell before equals a specific word. (I hope this makes sense)

    Example: If C4 has the word "ESSENTIAL" within the cell, that I want D4 to be copied into another cell.

    The plan is to track spending, on specific items, based on how they are catagorized. Then put all the ones that are catagorized into a new table with a sum for that catagory.

    Hope this makes sense

  18. Hi want to ask if a have an array of data, each of my samples have a row of value (few column of descriptive value). and I want to use IFBLANK() to check the each of the row to give it a "complete"(if all are filled) or "incomplete" (if it got any empty cells in the row) data.

    How do i do it? IFBLANK(C2:X2) for example, it just gave "false" to the row but it still has an empty cell.

    • Hello,

      Please try the following formula:

      =IF(SUMPRODUCT(ISBLANK(C2:X2)*1)>0,"blank","non-blank")

      Hope it will help you.

  19. In excel, my cell contains either x or y text. If text is x, then I need to put multiplication of three cells and if y, then need to put multiplication of other three different cells. how to put formula in the cell?

  20. EX:1
    A
    -10
    0
    IF(A1=0," ",)

    help to us..

  21. I am having trouble finding a formula for defining the payment deadline for invoices.
    If the invoice is dated before the 15 of a month it should be paid by the 15th of the following month, otherwise it should be paid before the 30th of the following month.
    I've tried combining IF with DATE but it returns the formula as text...

    • Hello, Mara,

      Please try the following formula:

      =DATE(YEAR(EOMONTH(A1,1)), MONTH(EOMONTH(A1,1)), DAY(IF(DAY(A1)<15,15,EOMONTH(A1,1))))

      Hope it will help you.

  22. I have an excel document with three columns.

    Example; I have the Name of staff, Amount contributed (deposit), amount applied from loan. I want to insert another collumn to analyze how many have qualified to receive the loan. I the new collumn, I want to introduce clients who have paid the required deposit( qualification amount and bring in the new collunm the amount of loan applied. Eg If qualification amount is $500,and the clients has applied a loan of $100000, i want the $100000 to appear in the new collumn by use of the formullae.

    • Hello,

      For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
      Please also don't forget to include the link to this comment into your email.

      I'll look into your task and try to help.

  23. I need to have a formula for the following; exp, column D, if b1=1, then enter vc; if b1=2, then enter vce if b1=3, then enter pp, and so on up to #5
    thank you so very much for helping me

    • Hello, Wanda,

      Please try the following formula:

      =IFS(B1=1,"vc",B1=2,"vce",B1=3,"pp",B1=4,"value4",B1=5,"value5")

      Hope it will help you.

  24. Hi. I have a question on the IF logic: state the status in a column as COSTLY if total expense is above $20,000, or FAIR if total expense is less than $20,000 but greater than $10,000, or MAINTAIN if total expenses is below $10,000

    • our value in A1 cell

      =IF(A1="","",IF(A110000,A120000,"Costly"))))

  25. Hello, I am trying to get a cell AB3 to show "complete" and if not to show "pending" when Cells on the spreadsheet H3,N3,T3, and Z3 are all showing "complete". I do not have the slightest idea how to write the "IF" formula.

    Any suggestions are appreciated greatly!

    • If(and(H3="COMPLETE",N3="COMPLETE=,T3="COMPLETE",Z3="COMPLETE"),"complete","pending")

      I done by mobile but its correct check

  26. In cell A cell B
    apple 1x
    grape 1x
    strawberry 1x
    grape 2x
    melon 1x
    grape 3x
    what function do i need to complete my cell B automatically
    tq....

    • Hello,

      I'm afraid there's no easy way to solve your task with a formula. Using a VBA macro would be the best option here.

      However, since we do not cover the programming area (VBA-related questions), I can advice you to try and look for the solution in VBA sections on mrexcel.com or excelforum.com.

      Sorry I can't assist you better.

  27. In Cell A2:A20 I have numeric (200.00) data. some cells are blank.
    1)how to convert blank cells into 0.00 Format cells converts numbers into 0.00 format if number is present.otherwise it is blank
    2)How to use If Isblank() formula for this conversion of blanks to 0 or if number is present, retain the same number

  28. How do I get cells in Excel to equal set amounts? For example if I was holding a competition to see how many ribbons kids could find? The ribbons would be different colors, and depending on the color the ribbon would worth different points?

    Blue=100
    Red=75
    Yellow=25
    Green=15

    Thank you in advance!

  29. Dear friends,

    i need a help for applying if condition in excel, in a column few different different text is there and few cell having MRP, if it is mrp cells have to multiply with qtys (599*12)if it is text in a cell that cells consider 300 rs * qty hot to apply if condition, please find the below the details and help me

    MRP VARIANCE FORMULA VALUE DIFF
    799 1 =IF(I6="NA",J6*300,IF(I6="",J6*300,J6*I6)) 799
    -1 =IF(I7="NA",J7*300,IF(I7="",J7*300,J7*I7)) -300
    NA 4 =IF(I8="NA",J8*300,IF(I8="",J8*300,J8*I8)) 1200
    tata 3 =IF(I9="NA",J9*300,IF(I9="",J9*300,J9*I9)) #VALUE!
    immma 7 =IF(I10="NA",J10*300,IF(I10="",J10*300,J10*I10)) #VALUE!

  30. Help! I am working on an excel and I want to know the function that if the value of D column is yes then the true value lie between 2002/9/13 to 2005/12/29 and if its false then it shows "N/A" please tell me the function need help? :)

  31. What would be the equation for 1000 ≥ certain cell block ≥ 501 =30%? For instance if certain cell block equaled 5000 the answer would be 150.

    • But if certain cell block was 800 then the answer would be 90.

  32. Hello,
    I have a spreadsheet that tracks investigations at different facilities. I am trying to find a formula that can give me the most up to date status of the facility. Here is some background: Every time the site is inspected, a particular operating status is evaluated and "T" or "F" is entered in the cell. Since the status can change from time to time, I would like to capture the most up to date status. The spreadsheet is designed with one row per site so my range will have to be across the row. i.e. I am looking at the last time a T or F was entered in that row. I hope this makes sense.

    Thanks in advance for your help!

  33. is there a formula for multiple logical test
    example. I wanted to place a certain word into a certain cell if it contains an specific text. thank you

  34. I am inputting the follwoing formula into my spreadsheet:
    =+IF((BG2=1)*AND(BH2=1)*AND(BF2<40000),1,0)

    This is the data it is pulling:
    BF BG BH
    0.00 1 1

    My result is still showing as "0" when it should be showing "1". Can anyone explain what I am missing??

  35. hi , iam from egypt please i need to explain how to make comparison between old list numbers with new list ( ex. 1254as = 1254as
    5478ad # 5478ac
    4568ab = 4568ab )
    i know we can used if function but how by details ?
    thanks for your support

  36. =if ( 'Visual Assessment Summary'!Y7='Visual Assessment Summary'! 8, if ('Visual Assessment Summary'!Y7="M" ,6, if( 'Visual Assessment Summary'!Y7="L",5,0))

  37. I would like to show a value of yes or no depending if a vehicle reg is displayed in a colum of cells. i have tried =IF(N7="WA60 BHU","YES","NO") but this only works if wa60 appears in cell n7 i would like it to say yes if it appeared in cell n7 to n20 or no if it is not displayed.

    Thanks

  38. I want to have a formula in which if the issue date in G6 is the 1st 7 days of the month then the expiry date in H6 will be the end of that month, however if the issue date in G6 is 8th-end of month then the expiry date in H6 will be the end of the next month.

  39. I am attempting to devise a formula that will assist me to calculate the payroll for my employees. It needs to address number of hours worked & then various rates of pay for those hours.

    So far I have come up with the following:

    =IF(AJ6>=3,(AJ6-3)*AN6+(3*AK6))+IF(AJ6>=3,(AH6-AJ6)*AI6)+IF(AJ6=3 - in the first instance I need a 0 recorded if cell AJ6> cell AH6
    - should that not be the case then I need the following calculation to take place (cell AH6 - cellAJ6)*cell AI6 (where cells AH & AJ are hours worked & cell AI is a rate of pay.

    My many attempts have been close but do not seem to recognise the IF/OR component - I need this because if it calculates a negative number as it can in the first instance it decreases the pay of my employees.

    Can someone out there help me?

  40. Hi, please help in my formula. I only get the first part right. If cell AB=1/2/3/4, returns 'Closed', else 'Open'. And if cell AB=#value!, returns Open.
    This is the formula I am using right now.
    =IF(OR(AND(AB3=1),AND(AB3=2),AND(AB3=3),AND(AB3=4)),"Closed","Open")
    Thanks a lot for ur help.

  41. Hello
    I need help to output the following:
    if given a list of id numbers and the 5th number represents sex i.e 1=male 2=female
    which formula can I use to find the sex
    eg given the following IDS:
    001329876
    123415672

    • Hello, Gofa,

      the formula below should help:
      =IF(RIGHT(LEFT(A1,5),1)="1","male","female")

      Feel free to take a look at this article to learn what LEFT function does, how it works.
      Hope this helps!

  42. Hi, Please help me in this senario.

    If there is a data (String) in "A2" need to compare with a range of cells say F1:F20. How can we compare using IF condition, or pls suggest me other possibilities.

    Regards,
    Varun.

  43. Hi,

    here's my formula right now:
    =FLOOR(MAX(C19,G19), 0.125)+$K$8

    what I want to do is that, i want to add an IF that if C19 and G19 are the same value, the formula will automatically deducts 5 from G19.

    any help will be much appreciated.

    Thank you

    • Hi, Leo,

      if I understand your task correctly, the following formula should help:
      =FLOOR(MAX(C19,IF(C19=G19,G19-5,G19)),0.125)+$K$8

      Hope this is what you need!

  44. Hi Ablebits.com Team,

    I am looking for help what kind of formula to resolve this condition.

    When A1= coal and B1= coal, then assign as coal
    however, when A1= coal and B1= 0, then assign as 0

    • Hi, Daniel,

      you need to create a nested IF formula with AND logic in it:
      =IF(AND(A1="coal",B1="coal"),"coal",IF(AND(A1="coal",B1=0),0,""))

      Please note that if neither of these conditions are met, the cell with the formula will remain empty.

  45. Hi Ablebits.com Team

    I am looking FOR help with formula for the following condition:

    When A1 B1 AND C1=D1 AND A10 AND B10, then assign E1 value "5065"
    When A1 B1 AND C1=D1 AND A1=0 AND B10, then assign E1 value "5065"
    When A1 B1 AND C1=D1 AND A10 AND B1=0, then assign E1 value "5066"
    When ABS A1 = ABS B1 AND C1D1, then assign E1 value "5067"

    THANKS.

  46. Hello, hope you can help!

    I have a column(A) with a drop-down menu with 7 different options ('Meeting', 'Private Party. 'Weddings', etc)That run on a calendar year.

    I have another tab where I have each option in a column (B), and next to it (C), I would like to have the total numbers of 'meeting', 'Party', 'Weddings' (from column A) within that Year (So a total SUM)

    How can I use the Sun formulas for a Word variable?

    does this make sense?

  47. I need help with a formula.
    I have a list of individual names some duplicate names. The duplicate names have test scores which I need to see if the score increased or decreased by when they took the test which is by date.
    How can i make a formula to look for multiple last names then look by date and score to get a result of increased +20 or decreased-20
    Example:

    Smith 200 9/25/2017
    Smith 175 9/1/2017

    Jones 150 9/24/2017
    Jones 180 9/1/2017

    I would appreciate if anyone knows how I can do this.

  48. I was wondering if anyone could help me out with an if statement.

    I have a figure in cell B5 I want to run an IF/OR statement on it to do the following:

    If B5 <5 then use the value in X5, OR if B5 = 5 AND 10, then use the value in X7

    Any help would be appreciated.

    • Hi, use the below Formula i think it will work

      =IF(B5<5,X5,IF(OR(B5=5,B5=10),X7,""))

  49. Was hoping you could help me? Here is my current formula:
    =IF(ISNUMBER(E15),VLOOKUP(E15,ReferenceTables!$B$13:$C$26,2)-F15,"0")

    Now I'd like to add "IF H15, I15 or J15 show any text, reduce this number by one"

    Thanks!

    • Hello, Josh,

      for us to be able to assist you better, please describe in more detail the last part of your condition with the text in H15, I15 and J15.

      If you still need help with this formula, it would be better if you could send us a small sample workbook with the data and the result you expect to get to support@ablebits.com. I kindly ask you to shorten your table to 10-20 rows.
      Don't forget to include the link to this comment.

      Our tech specialist will take a look at your task and try to help.

  50. Dear All,

    scenario as below.
    Price
    A1 B1
    1 YES
    2
    3
    4
    5
    i want to use formula wherein B1 Column populate automatically as "YES" to which the lower price is.

    Please help

    • HI, IF(A1<=1,"YES","")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)