by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
I am having trouble with a formula hope you can help, I am trying to create a formula to put text in a cell.
I have a cell that reference with a set target which is a percentage 85% and then and
I want it to say if Col L7 which is a percentage value say 75%, is greater then a desire target which is in col K7 (85%) put YES if it is 85% or over put put no in NO if it is not
IF L7 is >=(K7)85% "YES" but if is under <Less than 85% say (K7) "NO"
Hi
I made this below chart and I want a indicator in AVAILABLE Cell where I need red mark will show if Qty will be 5 Pcs or less than 5 Pcs. Please help me to get this problem solved. Here in AVAILABLE Cell I put the formula like this =IF([@AVAILABLE]="0","-1",[@STOCK]-[@[SALES QTY]])
STOCK SALES QTY AVAILABLE
20 Pcs 11 Pcs 09 Pcs ▲
10 Pcs 09 Pcs 01 Pcs ▲
05 Pcs 05 Pcs - ▼
15 Pcs 04 Pcs 11 Pcs ▲
09 Pcs 04 Pcs 05 Pcs ▲
10 Pcs 05 Pcs 05 Pcs ▲
I tried many ways changing the number inside the fomula but failed to correct this.
Thanks
Sazedul Munna
Hello!
Apply conditional formatting to the AVAILABLE column. I recommend that you read this guide.
Hello, I'm hoping you can help.
I'm trying to create a formula for the following
Have multiple Dept (example 3226.7191 33.24.71, etc in Column L) and I have cost associated to each line items in Column R.
I want to create a formula which summaries the charges for each Dept.
For example - the forumla would look down column L and if Dept=3226.7191 it would then look at column R and cross-reference all of the charges that appear in column R with all the time that Dept 3226.7191 appears and provides a summary of those charges
Hello!
You can get a list of values by condition using the FILTER function. Read this detailed guide.
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi
How can i use if condition with range ( have 3 columns and need to say if the number in range A2:c5 more than 10 so its good
Hi,
Please use the following formula
=IF(SUM(--(A2:C5>10))>0,"good","")
I'm trying to replace words.
Example:
=IF(A1="XXX",REPLACE(A1,"G2"))
If the wording in A1=XXX, I want to replace the words in A1 with the words on G2
This doesn't return anything, what am I missing?
Thank you, Swann
Hello!
If A1 contains a value, then you cannot change it using an Excel formula. You need to use VBA.
Hi
I need a formula in excel that ensures that cell can only be 9 characters long. And the following must show if the entry does not meet the requirements: a stop symbol and an error message that says: the text lenght must be 9 characters?
Hope you can help
Hello!
Please check out the following article on our blog, it’ll be sure to help you with your task: Data validation in Excel.
Use this formula:
=LEN(A1)=9
I hope I answered your question. If something is still unclear, please feel free to ask.
I have made a formula
=+DATEDIF($H$2,G4,"Y")&" years ,"&DATEDIF($H$2,G4,"md")& " Months and "&DATEDIF($H$2,G4,"yd")&" Days"
Now i want that whenever the years are 0 or months are 0 only days should appear
I can do that with IF statement that
IF(DATEDIF($H$2,G4,"Y")&" years ,"=0,DATEDIF($H$2,G4,"md")& " Months and "&DATEDIF($H$2,G4,"yd")&" Days",DATEDIF($H$2,G4,"Y")&" years ,"&DATEDIF($H$2,G4,"md")& " Months and "&DATEDIF($H$2,G4,"yd")&" Days")
as can be seen it is very lengthy
Is there a better way?
I have made a formula
=+DATEDIF($H$2,G4,"Y")&" years ,"&DATEDIF($H$2,G4,"md")& " Months and "&DATEDIF($H$2,G4,"yd")&" Days"
Now i want that whenever the result is =0,"Formula","")
Basically I want the result of the "Formula" when it is true in the value_if_true part else blank but don't want to retype the "Formula" again every time in the value_if_true part in the IF formula
Hello!
Try the following formula:
=IF($H$2<>G4,DATEDIF($H$2,G4,"Y")&" years ,"&DATEDIF($H$2,G4,"md")& " Months and "&DATEDIF($H$2,G4,"yd")&" Days","")
I hope it’ll be helpful.
Hi I need help,
"The idea is to use the logical test to determine whether the current ID is the same as the previous ID. If so, use the old summation plus the current value as the new summation. If not, use the current value as the new summation."
I have ID numbers from A2:A693 and need to sum B2:B693 but the ID numbers go up to 148
thank you
Hello!
I’m sorry but your task is not entirely clear to me.
Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you.
Hi All,
If I have 4 different ranges, and want to make a formula in excel. Can you please help on this?
1- Less or equal to 65% is Bad
2- Between 65% and 110% is Good
3- Between 111% and 200% is Awesome
4- More than 200% is Maverick
Thank you for your support
Hello,
I need a cell to show"try again" if the answer is incorrect. Can you show me the formula.
1+5=6 If answer incorrect to display "Try again"
T6+V6 ANSWER ON W6
Thank you
Hello!
I believe the following formula will help you solve your task:
IF((T6+V6)<>W6, "Try again", "OK")
+IFERROR(VLOOKUP($D$2:$D$495,JAN_TB!$A$2:$F$183,3,FALSE)," ",IF(VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$F$441,3,FALSE)=0,0,VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$I$203,3,FALSE))) there is an error of connecting IFERROR fomula Please help me
+IFERROR(VLOOKUP($D$2:$D$495,JAN_TB!$A$2:$F$183,3,FALSE)," ",IF(VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$F$441,3,FALSE)=0,0,VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$I$203,3,FALSE)))
=concatenate("Date",text(sheet no.2!$A$1,"mm/dd/yy") I use this formula and there is a date appear which is in sheet no. 2 are empty. I want is empty cell to be appear.. Please help me.. Thanks
Hello!
What do you want to calculate exactly? Your question is not entirely clear, please specify.
Hi Svetlana
I'm trying to build a spreadsheet to progressively record a players best scores on each of 18 golf holes, over four rounds of golf.
So on day one they will have a score on each of 18 holes. Their total for the 18 holes will be shown at the end.
On each successive day, if they have a better score on one or more of those holes, then the score for those holes will change, along with their total for 18 holes.
So as an example:
Day 1
HOLE 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18
SCORE 2 2 3 2 0 2 3 3 0 2 1 1 2 2 2 1 1 0 29
Day 2
HOLE 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18
SCORE 2 2 3 3 0 2 3 3 0 2 2 1 2 2 4 1 1 0 33
On day two, they had a better score on holes 4, 11 and 15, so their overall total increased by 4 to 33.
This would be repeated on days 3 and 4 and changes made depending on their scores for each individual hole.
The objective is to determine the players best scores on each of 18 holes, over 4 rounds.
I would appreciate any help you can give so that I can build my Excel spreadsheet.
kind regards
Dave
Hello!
Please check out the following article on our blog, it’ll be sure to help you with your task: Excel MAX function - formula examples to find highest value
I hope I answered your question. If something is still unclear, please feel free to ask.
Hello,
I've been trying to figure this out, in the worksheet given to me as an assignment, the question is to use the if statement to recruit workers that have applied but the must be SLIM AND FEMALE and I have no idea on how to come up with a formula for that considering the fact that there are 2 conditions(slim and female)
Going out on a limb & praying I get some help. It is more a 2 part issue and as a result I tried to break it apart. Thanks in advance if anyone does help out. If not, I completely understand.
Overview: We have to record the absences at my job. When the agents call in we obtain some basic information. It is a voicemail inbox though. So sometimes it is extremely hard to understand things. The managers continue to add things they want us to track. With larger numbers of staff it has just become a nightmare.
Issue 1:
When the agents call in we obtain some basic information and send it out to our managers/supervisors/QA team. What I was trying to determine is if there was some way to take the data I have on an alternate spreadsheet, and make it so that when I enter the agent's phone number it will populate the basic data for us? Essentially, we have a field for last name, first name, supervisor, their reason for missing, shift start time, department, and site.
What I have been working on for weeks was a table that actually contains the data I want to be pulled in when the phone number is entered. I've added some extra fields that would allow for alternate phone numbers and things like that. So if the agent ever uses a phone number not in the system we could just add it to their "profile" & increase the chances of the automatic entry. I was also going to build a list of generic reasons that contain no details. Just because that is yet another thing the managers & clients both want. Totals of each reason.
My big question is: is this even possible? Making it so that when 1 thing of text is entered into a cell - the other data populates automatically?
Issue 2: The main manager wanted a running total at the top of the page. I used =COUNTIF in order to make that operational. However, the client requests a more detailed breakdown. They basically want a total for each start time + what department they are. So for example, I'd have 20 for 7:45 - 2 are Claims / 1 is a Team Lead. 12 for 8:00 - 3 chat + 4 dual skilled etc. etc. etc.
I was trying to figure a way to where as the call outs were entered in - the formula would automatically be totaling everything.
Another thing that may be useful with this 2nd issue.... The last sentence basically explains why I felt that way:
Our manager wanted a total at the top of the spreadsheet. I would often forget to tally it up. So I used =COUNTIF and.... Yeah... I'm not an expert. So I just added an extra row and I put the "bitcoin B" symbol in that row. Thus it only counts that symbol. When a new day starts I just delete the "B" out of that row. I also have a row called "Filter". They want us to keep all of the past data but want the column headers in the email. The easiest way for me was to just put an X in this "Filter" column for todays call outs. When tomorrow rolls around I just delete the X out, filter to show only the "X" (removing blank fields). And repeat daily. So it keeps all the past call outs (We average 20k per year) out of way. ----
Reasoning mentioned above & possibly the only useful part of that ramble: I didn't know if having the unique symbol already active would help with the counting process since the range it is counting will be changing on a daily basis. I thought maybe the "B" symbol would help identify what needs to be counted.
Very likely all of this is impossible and that is why no one else has done it already and I am just an idiot?
Hello!
As you enter text in a cell, other data can be automatically filled in using the VLOOKUP or INDEX + MATCH function.
Unfortunately, without seeing your data it is impossible to give you advice.
I'm sorry, it is not very clear what result you want to get. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.
We'll look into your task and try to help.
Hi Svetlana,
I have a range of cells across a sheet (24 rows x 27 columns).
=> First Column is Cycle (rows 1 to 24 )
=>Last column(27th) is "Total Days" which is summation of columns "Days" having values ( 29 or 30 or 31 or 32 or 33 ) resulting to "Total Days" 364 or 365 or 366 for the year, which are derived as difference between two columns having dates. eg Col B2 = (17/03/2020) ; Col C2 = (16/04/2020) ; Col D2 = 30. Where D2 = C2-B2.
=>In the sheet ,after "Cycle", Next two columns are having "Months" and third is "Days", but the subsequent columns after this are "Months" and "Days". Month cells are custom formatted as mmm-yy like:
Cycle | Mar-20 | Apr-20 | Days | May-20 | Days | Jun-19 | Days | Jul-19 | Days | Aug-19 | Days | Sep-19 | Days | Oct-19 | Days | Nov-19 | Days | Dec-19 | Days | Jan-20 | Days | Feb-20 | Days | Mar-20 | Days | Total Days
=>Each Month cell below is a linked formula to next date of the column Month cell across the range such that for Months, the formula is to avoid dates from a range of public holidays and Sundays between cells C33 and C103 which are maintained in col C64 onwards.
eg.
I2 cell formula is
=IF(ISERROR(MATCH((G25+1),$C$33:$C$103,0)),(G25+1),IF(ISERROR(MATCH((G25+2),$C$33:$C$103,0)),(G25+2),(IF(ISERROR(MATCH((G25+3),$C$33:$C$103,0)),(G25+3),IF(ISERROR(MATCH((G25+4),$C$33:$C$103,0)),(G25+4),IF(ISERROR(MATCH((G25+5),$C$33:$C$103,0)),(G25+5),IF(ISERROR(MATCH((G25+6),$C$33:$C$103,0)),(G25+6),"More than 6 days")))))))
I3 Cell Formula is
=IF(ISERROR(MATCH((I2+1),$C$33:$C$103,0)),(I2+1),IF(ISERROR(MATCH((I2+2),$C$33:$C$103,0)),(I2+2),(IF(ISERROR(MATCH((I2+3),$C$33:$C$103,0)),(I2+3),IF(ISERROR(MATCH((I2+4),$C$33:$C$103,0)),(I2+4),IF(ISERROR(MATCH((I2+5),$C$33:$C$103,0)),(I2+5),IF(ISERROR(MATCH((I2+6),$C$33:$C$103,0)),(I2+6),"More than 6 days")))))))
=>The whole idea is to match the difference between dates across the sheet to fit in (364 or 365 or 366) total days and Col "Days" between (28 to 32) such that each cycle average number of days is maintained close to 30.
=>What formula can be set to fill dates in particular cell C33 onwards to achieve the above?
Thanks and regards,
Dev.
Can i do such a formula: If value in column A has the letters CC at the beginning, then delete the CC?
Hi,
Using a formula, you can display the value in another cell and remove extra characters:
=IF(LEFT(A1,2)="CC",REPLACE(A1,1,2,""),A1)
I hope my advice will help you solve your task.
Thank you so much Alex.
Now how do i add to this formula that the last 3 letters should be removed as well?
For example: if i have a list of the following
CCGDR3M-1#1.
CCG5M-05#2.
CCGD34GM-11#5.
and i want to remove the CC at the beginning and the #1. or the #2. or the #5. at the end (Note: i want to remove the . as well)
Hello!
Use the following formula:
=IF(LEFT(A1,2)="CC",REPLACE(LEFT(A1,LEN(A1)-3),1,2,""),A1)
Here is the article that may be helpful to you: Excel substring - how to extract text from cell
How do I change a colum with (NO) to read (0) while Colum with (YES) to read (1),Column with (NOT RANGED) to read (-)
Hi,
I'm stuck with the following problem.
I'm trying to work out loss and gain on a starting number so my formula is -
=IF(C2<D2, "GAIN", "LOSS") and so on...
However, It will always show "LOSS" in the cell when cell D2 is blank. I only want it to show LOSS if a number has been inputted in both cells. Would anyone know what I need to change for this?
Hello!
If I got you right, the formula below will help you with your task:
=IF(C2
would it be possible to have two formulas in one cell
how do i write a formula for
if a value on a cell is less than or equal 3.99sf on a particular column it should always show and calculate as 4sf on my h column
Reply
Alexander Trifuntov (Ablebits.com Team) says:
February 19, 2021 at 8:21 am
Hello!
If I got you right, the formula below will help you with your task:
=IF(A1<4,4,A1)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi
Thank you for your response, it does work but i have assigned different formula already on cell, how can i apply your formula on an entire column, i tried this method and it doesnt work, by the way im doing all this on google sheet.
Hello!
I wrote this formula based on the description you provided in your original comment. Explain what is not working. If you want to write 2 formulas in a cell, then this is not possible.
how do i write a formula for
if a value on a cell is less than or equal 3.99sf on a particular column it should always show and calculate as 4sf on my h column
Hello!
If I got you right, the formula below will help you with your task:
=IF(A1<4,4,A1)
I hope this will help, otherwise please do not hesitate to contact me anytime.
here is a digit X in B1. IFB1 80 it must be 80, otherwise x
what is the formula? pls help
Hi,
I need help trying to create a formula that determines if the cell contains a numeric value or an alphanumeric value. If it is an alphanumeric value, leave it as is, but if it is a numeric value and letters. For example if 123456, then change to INV123456, and if INV123456 leave it alone.
Hi,
Please check the formula below, it should work for you:
=IF(ISNUMBER(--(A1)),"INV123456",A1)
I hope I answered your question.
Hi there
I have what I believe a very simple comparison to make between two date columns:
I want to compare column A2 and column B2 and have the formula tell me if A2 is less than B2.
So far, what I'm using is giving me false results.
I have tried:
=A2<B2
and also
=IF (A2<B2,"Yes","No") but this also gave incorrect results.
Example data:
A2: 08/09/2020
B2: 14/07/2020
In this example the query about whether or not A2 is smaller than B2 should yield a "No" result but it is throwing out a "Yes" when it is clear that the A2 date is a greater date.
My date format is DD/MM/YYYY.
Can anybody help?
Hi all... please ignore my query! I've worked it out.
Simply had to run Date - Text to Columns on my Date columns (already formatted as Date Format) in order to get the formula to compare the dates properly.
Hope this helps someone else!
cheers
Kaz
Gah! Typo... that solution was:
Data - Text to Columns (NOT Date - Text to Columns).
Time to sign out!
-Kaz
Hi,
Check your dates. I think that cell B2 is written as text, not as a date. Maybe the date format of 14/07/2020 does not match your Windows date format. Maybe the correct format is 07/14/2020. Check the date and time settings in the Control Panel.
Hello Alexander,
If you are able to assist me with my request, it would be greatly appreciated. I am trying to have a cell be copied from sheet 1 to sheet 2 when an "if" value is met. For example:
if a cell in the d column on sheet 1 reads "T", then I want the matching cell in e column to be copied to sheet 2.
The context is, that when a task is Tabled (T), in my list of things done in that day (Sheet 1), then on the following sheet (Sheet 2), a list of future tasks will be created. As the task is completed, I would change the status on the original page, and the task would no longer be carried over to the corresponding cell on sheet 2 . This would assist me in organizing my weekly to-do list.
Thank you for considering my request.
M.Tucker
Hello!
Here is the article that may be helpful to you: Vlookup multiple matches and return results in a column.
and this article: Excel reference to another sheet or workbook (external reference).
Use an array formula
=IFERROR(INDEX($E$2:$E$13, SMALL(IF($H$1=$D$2:$D$13, ROW($E$2:$E$13)-1,""), ROW()-2)),"")
This is an array formula and it needs to be entered via Ctrl + Shift + Enter, not just Enter.
Change the links in the formula according to your data.
After that you can copy this formula down along the column.
I hope my advice will help you solve your task.
THANKS
USING YOUR IDEA I DONE MY FULL DAY WORK WITHIN 1 HOUR
THANKYOU VERY MUCH
Hi Alexander. I am blown away by the amount of answers you have addressed in this thread! Thank you for offering so much value out there...hoping that mine will be included ;-)
I am trying to use an IF(ISNUMBER(SEARCH formula to perform a calculation based on whether a partial text match exists. I am wanting to pull the text from a cell and use that cell address in the formula to test for a partial match in another field. Otherwise I will be required to manually input the text multiple times throughout the formula. I'm having issues getting the formula to pull my text from a cell....for example:
=IF(ISNUMBER(SEARCH("*b3*",B$15)), C$15, C$21) where the text I'm looking for is located in cell b3. Is there syntax that will accomplish this?
Hello!
If I got you right, the formula below will help you with your task:
=IF(ISNUMBER(SEARCH(B3,C$15,1)), C$15, C$21)
You can read more about the SEARCH function in this article.
Thanks Alexander! That is so obvious now that I see it that I am embarrassed. I've tried it and it works perfectly. Thank you again for your quick, straightforward help!
Struggling with an If statement.
=(IF(D4="S", ((H4-F4)/(F4-I4), (IF(D4="L",((F4-H4)/(I4-F4))))
what I tried entering. keeps rejecting the formula.
It's my trade journal and looking to determine risk rewad. So when I go Long it needs the L formula and Short the S.
Appreciate any help
Hello!
I can’t test your formula as it uses your data.
Try the following formula:
=IF(D4="S", (H4-F4)/(F4-I4), IF(D4="L",(F4-H4)/(I4-F4),""))
Hope this is what you need.
I saw that you really active in replying comments ^^.
I want some answers too for my problem.
Is it possible to put/show results to another cell? (i dont know what this method called/its name; or this cant be implemented in Excel)
Lets say:
A1 value is 0
A2 value is 0
A3 value is 0
A4 value is 0
When A1 value turn to 1
A2 = 200
A3 = 400
A4 = 600
Its something like this,
if A1 =1, A2 = 200*A1 | A3 = 400*A1 | A4 = 600*A1
A single cell that using fuction, and write the results into other cell
Is it possible?
THanks
Hello!
An Excel formula can only write the result to the cell in which it is located. If a value has already been written in a cell, then it can only be changed using a VBA macro
Thanks ya ~ i will look into VBA.
I am working on a daily deployment graph where the hours someone begins a shift is in column A and the time they leave is in column B. If cell A1 shown 1100 and Cell B1 shows 1300, I want cell P1, Q1, AND R1 to turn white filled. =if(a1=1100, P1:Q1*WHITE) or something like this if that makes sense?
Hello!
You can change the color of a cell based on the values of other cells using conditional formatting.
Here is the article that may be helpful to you: Excel conditional formatting formulas
How to formulate this into the function
if cell A1 is multiplied by a number then put value of 1 in cell A2
hello!
How do you want to know that cell A1 is being multiplied by a number? Please describe this condition in detail.
Hi.
I'm trying to lookup if text matches to return a text string and if it doesn't match, to lookup in another sheet, but it only is seeming to check the first lookup, not the second.
=IF(VLOOKUP(C2687,'Master Data'!A:A,1,FALSE)=C2687, "regular listed", IF(VLOOKUP(C2687,'Community Service - Master Data'!A:A,1,FALSE)=C2687, "community service", "No Master Data!"))
Hello!
If the text does not match, then the VLOOKUP function will return an error. Therefore, I recommend using IFERROR instead of IF.
Hello I'm looking to have the formula work: =ISTEXT(IF('Investment Center'!$B$6:B26=E46,'Investment Center'!$C$6:C26))
All fields are text and I want to have the following logic. If anywhere within Investment Center'!$B$6:B26 equals to E46 then return value of 'Investment Center'!$C$6:C26. All entires are text.
Hello!
If I understand you correctly, you want to return not one value, but an array. Then try this formula
=IF(SUM(--(B6:B26=$E$46))>0,C6:C26,"")
Hope this is what you need.
=IF(L444<3,"PASS","FAIL")=IF 0 =N/A
HELP Please
Hello.
I'm trying to us an IF function to a cell that has a small formula F7 has this formula(=F1-F2) but it wont work. It will work if I type the correct number in there but if it is coming from the small formula it is coming up up as "False" Can you help?
F7 has this formula (=F1-F2)
Example: If F7...
is greater than or equal to 0.5 then 2
is less than or equal to -0.5 then -2
is in the range of 0.4 to -0.4 then 1
All in one formula?
I hope that makes sense.
Hello!
If I understand your task correctly, the following formula should work for you:
=IF((F1-F2) >= 0.5,2,IF((F1-F2) <= -0.5,-2,IF(AND((F1-F2) >= -0.4,(F1-F2) <= 0.4),1,"")))
I hope it’ll be helpful.
Hi.
I am trying to do a product costing spreadsheet. working with 3 different rates of VAT. i'm hoping to indicate which one of the rates applies to the product with a check box? and then using the IF function to give me 'cost per item' based on what rate is selected because the others don't apply.
Hope this makes sense :)
Hello!
You can check 3 boxes for each VAT. With the IF function, you will check the value of 3 cells. You can also use the dropdown list and specify 3 VAT values in it. Then, in the formula, just use the value from the dropdown list.
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hello, I'm working with a large amount of text in excel and trying to create a formula where text in one column (name of country) and text in another column (name of a political party) produces a specific pre-set code to identify a specific party. Dataset includes dozens of countries and hundreds of parties.
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.
I have a question I am using IF function to a cell, if the cell is FALSE, it will appear as blank. But when a date is inputted i want it to add 2 more days. Is that possible? or how can i do that?
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(A1=FALSE,"",IF(CELL("format",A1)="D4",A1+2,""))
You can learn more about CELL function in Excel in this article on our blog.
I hope I answered your question. If something is still unclear, please feel free to ask.
I WANT A HELP
IF i= 5
in cell A1 it shall write A1
in cell A2 it shall write A2
in cell A3 it shall write A3
in cell A4 it shall write A4
in cell A5 it shall write A5
Hi,
I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
What does the condition i = 5 mean?
Hi
I have a problem to use IF statement to give me text value when a numeric value condition is met.
Example:
If cell "A" is more than "15" should give text "H" (High) in cell B, if value equals "5" but less than "15" should give "M" (Medium), and less than "5" should give "L" (Low).
I will appreciate your help.
Thanks
Hello!
Please check out this article to learn how to use multiple conditions in a IF function.
I hope my advice will help you solve your task.
I have an employee training log that goes back about three years. I need to know if and how I can write a formula in a different sheet to look at a list of required training, compare it to the training log and tell me on the new sheet what employee has not taken what training. Is this possible or are my hopes too high for excel?
Hello!
Unfortunately, without seeing your data it is difficult to give you any advice. Please provide me with an example of the source data and the expected result.
Good Morning!
Hello Ma'am/Sir,
I have some problems regarding date formula.
=IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY())
That is the formula that i created if the value in the cell is "DONE" & "WIP" today Date will be shown in the cell. And if the value is different the cell value would be "NA" but the issue if i am putting next argument the excel showing an error "You've entered too many arguments for this function" this is the formula i created where error is showing =IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY(),"NA") If you can help me with this it will be a big help.
Another thing Ma'am & Sir,
=IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY()) for this formula once if i put the text "DONE" & "WIP" the today date will shown but the issue is once it is in the next day the next day date will be updated in the cell i want it like when i put Done and WIP today date will be there but if it is possible it will not change on the next day or the other date. Like when they put DONE or WIP in today date it will not change the date by tomorrow it self because it is updated once the date change by the next day.
It will be a big help for me if you will answer it thanks and regards.
Hello!
Please check out the following article on our blog, it’ll be sure to help you with your task: How to convert the current date to text in Excel (Example 3)
I hope I answered your question. If something is still unclear, please feel free to ask.
Hi, I'm trying to use an if function to check if a string value matches it, it adds the corresponding numeric value to a cell but it doesn't work.
=If(C10:C43="Income",J10:J43+H7, H7+0)
So basically, I want the sheet to check that if Income is selected on the C range, the value from J is then added to the cell H7. This is for an expense tracker that I'm currently working on.
I'm new to this and I really appreciate any help.
Hello!
In a cell like K10, you can use a formula
=IF(C10="Income",$H$7+J10, $H$7)
Then copy this formula down the column.
I hope my advice will help you solve your task.
Hi Can any one tell me how can i fill the Colour in Excel file. For text like Green , Yellow, Red. Etc.
Just use conditional formatting
how to write this function properly.
=IF(J3 greater than 10,"1",IF(J3 is greater than 10 or less than 15,"2",IF(J3 greater than 15 or less than 20,"3",IF(J3 greater than 20 or less than 25,"4",IF(J3 greater than 25,"5")))))
Hi,
I need help in Excel cell. I want to fill the time only if if is not filled. To fill the time I am already using IF statement =IF(E2 "", NOW(), ""), so trying to solve with nested IF statements. But unfortunately it is not working.
With statement =IF(E2 "", NOW(), "") - it is filled the value in Coloumn B2 with now time, but it if I enter in new row, the time in previous row get updated. Can you please help.
Regards
If you want the formula to fill in the blanks then it should be =IF(E2="", NOW(),B2)
Now() function is dynamic so it will continuously update. If you want previous entries to stay static then you need to copy+paste as values.
Hi,
I need help in Excel cell. I want to fill the time only if if is not filled. To fill the time I am already using IF statement =IF(E2 "", NOW(), ""), so trying to solve with nested IF statements. But unfortunately it is not working.
With statement =IF(E2 "", NOW(), "") - it is filled the value in Coloumn B2 with now time, but it if I enter in new row, the time in previous row get updated. Can you please help.
Regards, Surinder
Hello,
I'm creating a Sales order form where I use the following formula -
=if(and(F18>0, D18>0, E18>0),C18*D18*E18*(1-F18),"")
So what I'm trying to do is to multiply cells C18 through E18 and if there is a discount amount in cell F18, then include it and get the final net price which includes the discount amount. This is fine and works.
What I can't make work is to multiply cells C18 through E18, but if there's no discount amount (cell E18 is left blank), I would still get the net price without the discount code.
I hope this makes sense! Any help would be greatly appreciated!
Thanks!