How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4763 comments

  1. I request to you i make a time , using if statement =if(A110,"A-10")

    • I request to you i make a time sheet , using if statement =if((A110,"sum(A1-10))

  2. Hello I need to use a formula that will display YES if the amount is $100 or more and remain blank if it is under $100.

    So far this is what I have =IF(B2>=100,"Yes")

  3. Not sure if this can be done. Need to search a range in A1:A20 for a text string and then return the value in the same row but 2 columns right. So for example look in A1:A20 for "Find me" and if find me is in A4 return the value that's in C4. Any ideas if this can be done?

  4. I need a formula to automatically display the current accrued PTO in a specific cell every time the excel sheet is open.
    The accrued PTO is 6.15 hours every two weeks. I have created a table with the dates and the corresponding accrued hours for reference.
    I tried IF and VLOOKUP statements but can't get the formula to work.
    Can someone suggest a formula?
    Any help will be greatly appreciated!

    Thanks,
    Raphael

  5. Hi Svetlana,
    Thanks for the great post, it helped me a lot. My case is a bit different. I want to use IF function in this way:
    IF xxx has the word "thanks" inside it, then "welcome" or "ok".
    I hope there is a way.
    Thank you.

  6. Need a formula to calculate following: if city =x zip =y. I keep getting a value error.Note I have approximately 10 cities and zips to include.
    Also need a formula stating: state always =CA

    Thanks for the help.

  7. i need some help from you.

    =IF(M9="yes", C9," ") How can i put this command in sheet 1 for the result of sheet2

  8. i am working on aproject. I need help with
    f2 contains both words and numbers. How do i display the text and numbers in 2 separate cells?

    • got it

  9. Please help me check my error
    =if((Q339,"D"),(Q3>49,"C"),(Q3>59,"B"),(Q3>69,"A"))
    I am computing exam result

  10. Sir if my output value is 12100, 12200,12300, 12400 all value change auto 12500.
    And my out put is 12600, 12700, 12800, 12900. That value change 13000.

  11. hello sir,
    I want to know how to add a1 value.in a2, a3, a4.....
    If i change value a1,all a2, a3, a4 ...value change auto.

  12. =IF(I10-K10, IF(I10="",N10-K10, IF(ISBLANK(N10),"2")))
    the first one will be formula then the other if blank of i10 IS BLANK USE FOR N10 THEN IF N10 IS BLANK IT SHOULD BE EQUAL TO "2" THANKS
    hi how to comine this formula thanks

    • SORI ITS N10.. THANKS

  13. Is it possible to create an IF calculation that asks a "greater than this number, but less than this number" question? i.e., if E17 is greater than 1800 or less than 2400, than perform E17-540*60%, otherwise place a zero. I get errors when I try this example...

    =IF(E17>1800<=2400, (E17-540*60%), 0)

    Thanks

  14. Hello, I have a date in cell D4, let's say 1/2003 displaying as 2003 due to custom formatting to YYYY and a formula in E4(also set to YYYY) which is D4+4385 because I want E4 to display 12 years after the date in cell D4. This formula works great if I have data in cell D4. If I don't, it will display 1912 in E4. What formula can I add to E4 to make it blank if D4 is blank without deleting the formula =D4+4385? Losing hair as we speak :/

  15. Hello sir, I'm Trying to enter Data in Sheet in form of numbers
    for example:-

    Roll-No:- 801
    Maximum Marks
    20
    20
    20
    20
    20
    20
    20
    Sig. of Class Incharge

    Roll-No:- 815
    Maximum Marks
    20
    20
    20
    20
    20
    20
    20
    Sig. of Class Incharge

    but the problem is when i try to drag or paste the same cells in another line.......Rollno has changed 814 instead of 802. My all cells are refrence cells of sheet1.

    Now which formula is best during drag or paste the rows.If i paste the row after 14 Rows ..roll no show 815 instead of 802.
    please guide me what should i do?
    if u want i can send you the copy of Sheet.
    Thanks & Regard
    Gandhi

  16. Assume that even numbered respondents (identified by RespondentID) are business travelers and odd numbered respondents are leisure travelers who travel infrequently. In column F on the surveyData tab, create a formula that identifies each respondent as either a Business traveler or Leisure traveler. You will need to use Excel’s If() function (see your Excel handbook or Excel help). Title this column travelerType. Ensure that cells F2:F501 are filled with the formula. Please help me create a formula.

  17. Hi, I need some help with this formula. A1 = $25000 B1= if(A1>0,"Total (A1)","Total"). If A1 is greater than 0, I would like B1 to show [ Total ($25,000.00) ] and if A1 = 0, I would like it to show [ Total ]. Does anyone know if this is possible?

  18. Hi Svetlana ,

    I need help with this one. I have one column lets say A1 : A38 that have some values / text . Those values can repeat themselves through A1 : A38 many times . I would like to get in another row or even sheet only one of each of those values or records.
    For Example : A1 have TB231 ; A2 TB236 ; A3 TB555 ; A4 TB555 ; A5 TB231 etc , now in separate sheet or row i should get only one of those , it dosent matter how much it has same records i just need that i get value of all different in separate sheet or row.
    Results of example should be : D1 TB231 ; D2 TB236 ; D3 TB555 , i tried with IF function but for 38 or more rows would be huge so maybe there is other easier way.

    Thank you

  19. How to check if there are 10 characters in a cell or not

  20. Is there a way to create an IF statement based on whether a number is a date? For example, If the value in A1 is a date, return the value of the date, otherwise, do nothing.

  21. I want a cell showing - , when i use it for calculation it's value should be 1.
    Please tell me how to do it?

  22. Please some one help...

    I need can enter the data if the nearest cell having only as "OK" otherwise should not able to enter any data.

    EX:
    E10=OK---> E11= Possible to enter data
    E10=asfa-----> E11= Not possible to enter data

  23. if row xx column xx = (todays date) display row xx in column xx (for example)

  24. I need to display a cell from another tab row using today's date. How would I do this?

  25. example: if cell a1 = "true" go to sheet 2

  26. Hi. I'm trying to figure out how to make excel go to the next sheet if a particular cell value is equal to "true".

  27. Hello dear friends

    I need help I have

    (column A is time in) (column B is time out) A1: 7:30 PM B1: 11:00 AM, I'm using the following formula to calculate the hours worked, less than 30 minutes lunch

    =MOD(B1-A1,1)*24-"0.5"

    BUT I only need to take the 30 minutes lunch ONLY if the employee worked more than 6 hours.

    "IF EXPERTS "HELP!", (THANK YOU) "" :)

    (employees are nurses so they work overnight and all kind of crazy hours). Can you help me to figure out an "IF" that works for something like that?

  28. Column
    A B

    Company A
    Rpt1
    Rpt2
    Rpt3
    Company B
    Rpt1
    Rpt2
    Rpt3

    I want analyse the similar data above by puting the header name (company name) next to each sub item cells
    example I want to see like this.

    Column
    A B

    Campany A
    Rpt1 Company A
    Rpt2 Company A
    Rpt3 Company A
    Campany B
    Rpt1 Company B
    Rpt2 Company B
    Rpt3 Company B

    Please anyone to help on this formula?

  29. Hello!
    Thank you for this guide. It's very helpful. I do have one question though, I am trying to copy a date on a cell. Say, date is in A1 and a restriction is in B1. My formula goes like this - =IF(B1="0","",A1). C1 should have be a copy of the date in A1 right? Wrong. Mine shows 420417. It shows numbers T_T not the date. Please help. Thank you in advance.

    • Sorry about this one. After a few trial and error, I managed to get it :D. Here's how I did it...

      Make sure that the cell you are copying is in a proper format. Don't let it automate to DATE, CURRENCY and etc. Then, before you create a statement, say =IF(X=A,"","B"), make sure you CLEAR FORMAT that cell. Good luck to you guys :D Thanks again.

  30. Worker Type Emp # Days Worked Total hours Worked Over Time Over Time Charges Basic Pay Net Pay
    A 121 20 190
    B 122 19 200
    C 123 24 231
    A 124 21 210
    B 125 25 215
    B 126 28 180
    C 127 15 140
    1) Over time=Total hours worked-(days Worked*8)
    2) Using If Function calculates over time charges
    3) Over time charges=Overtime *(100 if worker type is “A”, 50 if worker type is “B” and 35 if worker type is “C”)
    4) Basic Pay =Days worked *(400 if worker type is “A”, 300 if worker type is “B” and 200 if worker type is “C”)
    5) Using SUM() function compute NetPay=Basic Pay+Overtime Charges

    please solve part 2 and 3 , i m just got mad

  31. 18,19,43 in a column with test date at next column. 18's validity is 1 year,19's 5 year and 43's 6 month how can we show the due date in excel at a glance.

  32. Hi,

    I am using the =if(isnumber(search) to look for partial value. However, in my list I have 180 and 18. the end result will only pick up 18 instead of 180.
    What other functions can I use to ensure that both 18 and 180 will be pick up?

  33. =SUMIF(January!A5:A200,January!U4,January!B5:B200)
    The January!B5:B200 has names in it but it is coming up 0. i am sure that i am using the incorrect function

  34. Cell A1 is a hand entered date. Cell B1 is a total dollar value. Cell C1 is # of months. Starting with Cell D1 and going right are 12 more columns for the months of the year. Need a formula in D1 that says this: If the date in A1 is between January 1st and 31st, then take B1 and divide it by C1. Once I can get that, I can nest it with ifs to cover all of the months. My problem is how to do the date portion. Can you help??

  35. 1. i have a table with 2 columns (A,B)
    2. column A has a list of control measures and
    column B has 2 options(yes or no)
    3. what i want is if the answer is "yes" to NOT extract the control measure in a new worksheet and if the answer is "no" to EXTRACT

    e.g A1 (warning signs in place?) B1 (no)
    A2 (workers are aware of local emergency procedures?) B2 (yes)

  36. Hi Svetlana Cheusheva and Alexander,
    could you please help in solving my problem
    my excel column contains -5:55 -2:26 -2:19 -1:38 1:06 1:16 1:17 2:20 like wise nearly more than 100
    my result column to have Neg Neg Neg Neg 1-2 HR 1-2 HR 1-2 HR 2-3 HR
    could you please provide me an IF formula
    am using 2007 excel
    Remaining-TAT(h:m) TAT
    -2:19 Neg
    -1:38 Neg
    1:06 1-2 HR
    1:16 1-2 HR
    1:17 1-2 HR
    1:20 1-2 HR
    2:02 2-3 HR
    2:05 2-3 HR

  37. I am trying to add 1.5 to values higher than 3. Values 1-3, I need to remain the same. How can I do this?

    Ex. person enters 4 in a cell it is automatically calculates to 1.5
    Person enters 2 in a cell it remains the sames.

  38. Hi,

    Building a transcation register. Currently using this formula =IF(D13>0,H12-D13,H12+F13).
    But, when I copy this to the rows below I'll get the last result shown in the rows below. I would like to check the cells for values, before using the above mentioned formula. So when there are no numbers in cell D14 and F14, it will return an empty cell in H14. If there are numbers in either D14 or F14 use above if formula.
    Thanks for your help!

  39. Hi,

    1) I need a formula in I16 that can check cell B12 for # of servings (if any).
    example: B12="Sangría Rojo (2 glasses per guest). 10 servings."
    2) If B12=x servings then x*h12
    3) If B12 does not contain x servings then h8*h12
    example no servings: B12="Sangría Rojo (2 glasses per guest)."

    Thank You

  40. Hi Svetlana,

    I want to create the formula that select the cell P if the life time less than 10 years ,I put this formula =IF(S5<10,P5,"")but I also need to have same result if life time "1-5", (between 1 to 5) and I put this =IF(AND(S8<10,S8= 1 - 5),P8,"") didn't work, could you please help me.

    Thank you,

  41. i need a formula for first date is less then 2nd date how to check

  42. Hello Svetlana,

    I need a formula that could generate email from from a given list of names.

    I need the formula to be in such a way that it could satisfy both the below condition's.

    For ex:

    if there is:

    Condition 1:

    ==>> First name + Middle name-1 + Middle name-2 + last name
    Ex : ( how ) + ( are ) + ( you ) + (today )

    to generate : how.are.you.today@gmail.com

    Condition 2 :

    ==>> First name + Middle name-1 + Middle name-2 + last name
    Ex : ( how ) + ( isblank ) + (isblank) + (today )

    to generate : how.today@gmail.com

    xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

    looking forward to hearing from you soon.

    Thanks in advance.

  43. Hi,
    I have to find difference between two dates (Ex. A1 & B1). B1'=(now)' . I want results to display either one of these-"Minutes Ago","Hours Ago", "Days Ago","Week's Ago","Months Ago". whichever is the least.

    EX:A1= 2/16/2014 7:05:05 PM, B1=2/18/2015 2:29:13 PM.
    My formula gives me this result =1 years 12 months 367 days

    DATEDIF formula {=DATEDIF(A1,B1,"y")&" years Ago "&DATEDIF(A1,B1,"m")&" months Ago"&DATEDIF(A1,B1,"d")&" days Ago".
    This does not give Hours and Minutes. Can you help?And also is there a way to use If formula to display only 1 result i.e, "Minutes Ago" if this is the closest? Please help !

  44. Hello Svetlana,
    Your site is very helpful!
    Could you kindly help me with below:
    I need a formula where if the cell in particular row contain values from a table, then return value "trade", otherwise "unknown". The list contains over 100 values, therefore the ISNUMBER(SEARCH) function cannot be used.

    "Table" example:
    11 trade
    12 trade
    13 trade
    14 trade
    15 trade
    186 trade
    ...

    List example:
    13 trade
    13,14 trade
    15,2222 trade
    2882,2213 unknown
    14,11,75,2882,2213 unknown

    • 14,11,75,2882,2213 trade

  45. Hello Svetlana.
    Great Work.
    I need to find a two pairs of value in a cell, A/B OR C/D.
    A = 5 [value in cell C31]
    B = 5 [value in cell C31]
    C = 8 [value in cell C32]
    D = 8 [value in cell C32]
    blank cell, give me nothing.

    How can i do to find A or B ( same with C or D)

    =IF(C33="A OR B";(C$31);IF(C33="C OR D";(C$32);""))

    also one question, how can i make a addiction of various IF conditions? Like:

    =IF(C33="A OR B";(C$31);IF(C33="C OR D";(C$32);"")) + =IF(D33="A OR B";(D$31);IF(D33="C OR D";(D$32);"")) + =IF(E33="A OR B";(E$31);IF(E33="C OR D";(E$32);""))

  46. Using IF function write a formula if " Date" is Blank pick the Value from "System number", else name it as Date In.

    data
    system date
    d322 16/2/2015
    f3532 17/3/2015

  47. Hi. I have a word in cell A62. I want to search the range A5:A45 to see if it contains my word. If it finds the word, then i want to highlight that row and then insert a formalua, =IF(B41="a","yes","no") in the Q coloum of that row.
    Is this possible?

  48. i want to check if the data in one cell is contained in any other or not. what is the code??

  49. HELLO,
    i need a formula to show that if my first cell is greater than the average then to show me 0 otherwise to show the difference between the first cell and the average(some cells are 0) ,so i was trying =IF(D3>D$291;TRUE=0;FALSE=D3-D291) but doesn't work .THANK YOU IN ADVANCE!!!

    • Hello Sofia,

      Just enter the following formula:
      =IF(D3>D$291; 0; D3-D$291)

  50. I have 2 cells that contains month and year. The first cell is date when qualification was received. Second cell is date when qualification expires. The 3rd cell below these 2 cells I want to say "Expired", "1 Month Left", "3 Months Left" based on these dates.

    Please help me.

    Thank you very very very much!!!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)