by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
Hello, I have a spreadsheet with an "if" function to provide different values based on what is selected in a drop-down box. I am trying to then use the result of that box to create a sum with another box. The problem I think is that when I created the "if" statement now that cell is being viewed as text, not a number so it will not add it. Can someone help me? Below is the "if" formula that I am using.
=IF(H3="AS", "10",IF(H3="SNS","10",IF(H3="TNS","0",IF(H3="TSNS","6",))))
Try removing the quotation marks on the value_if_true as this makes the result as text.
=IF(H3="AS", 10,IF(H3="SNS",10,IF(H3="TNS",0,IF(H3="TSNS",6,))))
How would I write an If function that inserts the value 0.08 if the client is located in Washington and the value 0 if the client is located elsewhere.
=IF(H4="WASHINGTON",0.08,0)
Hi I need some assistance with the if function.
The question is female started the swim 30 seconds after the males. I column G insert formula , adding 1 point to the total points which is in column F is the competitor is Female and for Males add no points.
hello. how do i code a rule for this: "safe" if the distance is between 9 and 10 and "error" if the distance is less than 9 or greater than 10.
=IF(AND(F13>=9,F13<=10),"SAFE","ERROR")
Replace the cells with where your distance values are.
Use the IF function in cell E5 to calculate the annual total amount, which is the sum of the basic cost and locker fees for those who rent a locker.
For people who do not rent a locker, the annual cost is only the cost shown in column C. The Locker column displays Yes for clients who rent a locker and No for those who don’t.
Note: You must use the proper function. Do NOT write your own formula.
I can't find any (IF) Function examples to do this assignment.
I circumstance is easy enough. If client uses a locker "Yes" or does not use Locker "No" then if "Yes" add $75 to Client cost. If "NO" then the Cost in final cost does not change.
i'm trying to create a formula that will show todays date on the next cell. For example...IF H2 say Adj then I2 should have today real time date. But my issue is that i need the date to change for whatever cell i put adj. 123456---29-Oct---Watermelons---1--Quality--654321--Dole---Pending ( this will show pending until i switch it to Adj) and when i finally switch to Adj i want todays date to pop up on the ("I"cell). is it even possible? i was told that ALL my cells will show todays date and change everyday which i dont want to happen because if tomorrow i have more rejections i'll make adjustments that day and i would need the cell to have that date on it.
Hi...
I don't know if this thread is still open but i need some help.
i have never used excel before but i need to do something to present to my workplace.
the idea is this: 7 columns, 5 rows and 4 numbers. the numbers need to be placed across the board.
a few rules need to apply: at each row, the numbers must be in ascending order (from left to right) and the 4th number must be placed 2 times exactly, next to each other.
at each column, the 4th number must not exist more then 2 time or less then 1 time..
both columns and rows rule: numbers must be equally placed across the board as much as possible.
I columns as
Column-1 = Latest; Column-2 = Code-2 & Code-4 and delay in re-submission. So, i need formula is that Latest = L&S; if Code-2 & Code-4, greater than 0 should indicate-1. so, please can you send me the if formula.
Hi Svetlana,
Wondering if you can help me.
I am creating an order system and I want to increase stock ordering for products that are on offer.
In a cell I either have 0 (Cell G in image) or a date. (Cell G Highlighted Red)
I want to know if there is a formula that will return a % for any date lets say 130% (Cell H highlighted in black)
And return 0% for 0 in the cell(Cell H Highlighted in Blue)
Regards,
Robbie
Just realised I can not attach an image.
Hi,
I have one cell with A1 - "9000" and for A2 I want "9000-000", How I can tell to the excel to put the information of A1+"-000" on A2?
Thanks
can you help me!
=IF(Teamno=B3,MVisit=A5,MAX(SrNo),MAX(MDATE),0)
i want to create a sheet in which, if A1 has value which is divisible by 5 then it should be multiplied by 5 (i.e. 5,10,15,20) in B1 or if A1 has the value which is not divisible by 5 (i.e. 1,2,7,9,11) then it should be multiplied by 4 in B2.
Please share the formula.
=IF(MOD(A9,B$9)=0,A9*5,A9*4)
Hello.
I have been trying to write the following for the last 2 days/
Column A - 5.5
Column B - 6.5
Column C - (If The difference between A and B is bigger than 10% of A, I need >10% to input ESC and <10% to input CLEAR
Hope I’ve made this seem clear and thanks for any help
=IF(SUM(B2-A2)>A2*10%,"ESC","CLEAR")
I need a small clarification in excel, that is, i do have a month budget saying some allocation amount for the upcoming days.
ex.
A = 100 Rs
B = 200 Rs
c = 300 Rs
and in my day expenses sheet, ill be puting the expensed amount. so i would like to know how to draw a function like, if i put "A" the amount need to be deducted in the allocated sheet (displaying the balance) ????
I need a formula that’s had me stumped for weeks and I know it’s simple ?
I’m trying to find out if a name in column A2 matches or contains a name in the same row columns b2,c2,d2 if yes leave blank if no then x
I have it this far
=if(A2=B2,””,”x”) but I need to add c2 & d2
Help pleeeease
Hi!
Just nest the OR function in the logical test to evaluate multiple conditions:
=IF(OR(A2=B2, A2=C2, A2=D2), "", "x")
Please note that the above formula leaves the cell blank only if A2 exactly matches B2 or C2 or D2.
To test if A2 contains a name that is part of cell contents of B2 or C2 or D2 (e.g. A2 contains "John" and one of the other cells "John Doe"), use this formula:
=IF(OR(ISNUMBER(SEARCH(A2,B2)), ISNUMBER(SEARCH(A2,C2)), ISNUMBER(SEARCH(A2,D2))), "", "x")
Nope not as simple as I thought but it worked like a charm! Thanks
hi
i used your formula
=IF($C2"", "Completed", "") but facing a problem.
the specific text "Completed" appeared in the targeted cell where i put any text not only date. even if i put a space there, the text "Completed" shown too.
Actually i am trying for a formula where i will put either any date or a certain text in a cell then a specific text will shown in an another cell.
example-
if i know the date then i will put the date 13.10.2019 in a cell then "completed" will be shown in an another cell but if i don't know the date correctly then i will use certain texts like "Not confirmed" then "completed" will be shown.so here i want to merge two formula for a cell.
TIA
can you help me.
IF($C2="", "Completed", "")
Try this and check.
If the FIGURES IN the range A2:A6 is EQUAL FIGURES IN A8:A12 COPY A1 Otherwise, empty text ("") is returned
=IF([Workbook9]Sheet1!$D$3:$H$3=D2:H2,[Workbook9]Sheet1!$C$3,"")
if row range D3:H3 IN WORKSHEET9 IS THE SAME WITH ROW D2:H2 IN WORKSHEET8, THEN COPY INFORMATION FROM WORKSHEET9 ROW D1 ELSE RETURN EMPTY SPACE
Hi there,
can you please help me out that how can i found if a person is traveling in between 6hrs two times.
i've a data where i've to check the employee, who has traveled two times in 6hrs.
thanks in advance
I need something that would work with setting the next columns numbers to negative. If A1>=215 B1 = "-"
A1 B1
215 8 changing the 8 to a negative 8
I believe you need another column in there. If you want the negative values to be in column B, the original 8 should be in column C.
=IF(A20>C20,C20*-1,C20)
Hi all, I need some help because I am pretty dumb with computers :-)
I am trying to get a cell to show either "Long" or "Short" in it by comparing 2 other cells,
ie.....d9 should show long if j9 is greater than m9 or short if j9 is smaller than m9. here is what I have tried and it returns "False"
=IF(J9>=M9, "Long", IF(M9<=J9, "Short"))
Hoping you guys can help.
Change the formula to
=IF(J9>=M9, "Long", IF(J9=M9, "Long", "Short")
However, you may want to consider when they are equal. If so then use the formula below.
=IF(J9>M9, "Long", IF(J9<M9, "Short","Equal"))
Hope this helps
Change the formula to
=IF(J9>=M9, "Long", IF(J9=M9, "", "Short"))
However, you may want to consider when they are equal. If so then use the formula below.
=IF(J9>M9, "Long", IF(J9<M9, "Short","Equal"))
Hope this helps
I created a simple (so I thought) time sheet so in a single column there would be start and stop times (using decimels not times, 12.50 is twelve thirty). Below those entries are cells to calculate 1. the total amount of time, 2. a balance of $ from the previous day, 3. the amount $ for the current day, 4. amount $ of any materials purchased (no formula in cell), 5. total of $ adding the 3 cells above, 6. a cell to enter amount of pay given to worker, 7. a balance cell calculating any balance remaining after payment given to the worker. I use the logical =IF(E70,E70-E71,"") format for making the calculations in all the cells. If there are no start stop times I see the error message #VALUE! in only three of the cells with formulas in them. The #3, #5, #7. I see an empty cell in the first cell with a formula in it, #1 but despite the, "" indicator for the FALSE response, I see the error message #VALUE! How can I create a formula to accomplish the calculations I have, with out seeing error messages?
Thank you very much.
Gary Schimelfenig
Hi I am trying to highlight text in a cell based on cell value, for example, if cell contains win, want that text in Green, Waiting in range, Lost in red, I can only do one value of text not multiple, as I can do with number values
Help!
Shri
I am trying to get a cell to have it's background turn red if the result of it's formula is greater than 0 if I have a date in a cell, and nothing in a second cell. This is what I typed but I get an error and not sure why.
=if (and (isblank($C2),$E2="",$F2>0),0 ,1)
Also tried this "=if (AND (isblank($C2)=false, isblank($E2), $F2>0),1 ,0)" still doesn't work, Notsure what I'm doing wrong
Hi,
I want to add up the main totals of sheets 1, 2 and 3 in an excel document, to separate excel sheet.
How the document works: This BOQ is used to add up codes/qty/price/etc. When sheet 1 is full and sheet 2 and / or 3 is used the total of the previous sheet shows “see next sheet“ in the total block and the main total only reflects on the last sheet used.
If for example only sheet 1 is used the total only shows on that sheet it doesn’t show on the other sheets that are not used.
My question: How can I add all three sheet totals without the words “see next sheet” interfering and I also need to add it in a way that it doesn’t count a sheet total twice as it is already calculated on the last sheet used.
Maybe if the formula sees the word “see next page” it can count the total of the next sheet until it finds the sheet with an actual total amount.
Please could you help. Thank you in advance.
I am trying to do the following:
Row 1 options: No, Yes-2nd, Yes 3rd. (Drop down options)
Row two needs to equal:
No= $100
Yes, 2nd= $50
Yes, 3rd= $30.
I can figure it out to be No= $100, but then if I put Yes, 2nd or Yes, 3rd it equals $50.
Help please!!
Is it possible to change the options to Yes1 or Yes2? This might be an easier way of going about this.
i want month wise count the consignment(s) by formula
Eg...
The Month is April
Assign April = "04"
Now count Numbers until the month is not changed from 04 to 05
for example
1/4/19 = 1
5/4/19 = 2
10/4/19 = 3
11/4/19 = 4
but..
01/5/19 = 1
2/5/19 = 2
so, please give me the right formula for the same
To begin with, you need to make sure the data is sorted by date. This is important for the below steps to work.
Now let us assume you have the date values from A1 to A6. Column B will have the following values:
B1=1
B2=IF(MONTH(A2)MONTH(A1), 1, B1+1)
For the rest of the B columns, you can copy paste the B2(You can also drag). So the formula for B3 will be like =IF(MONTH(A3)MONTH(A2), 1, B2+1) and B4 will be =IF(MONTH(A4)MONTH(A3), 1, B3+1)
Hope this helps
Dear All Expert,
I have a number in table range as show below and how to make the tolerance formula.
Reference target tolerance is 5%
Reference target value is Last day will be Beginning for next week
Week 2 reference target is last day output at week 1, 190. Week 2 are trigger as 1 because week 2 contain the value below and above on 5% tolerance for 190. Minimum is 180, maximum is 199.
Reference target for week 3 is the last day of week 2, 200. Minimum 5% tolerance for 200 is 190 and maximum 5 % is 210. Week 3 not have any output below 190 or more than 210, so result will show 0.
Reference target for week 4 are the ending day at week 3, 199 output as a reference for week 4 tolerance. Meaning that minimum and maximum 5% of 199 is 189 and 209. So if week 4 reach the output below than 189 or more than 209 it will trigger as 1. Result for week 4 is 1 because 27 Aug reach the bottleneck of below the minimum output of 189.
Week Date Output Trigger
4 31 Aug 206 1
4 30 Aug 201
4 29 Aug 196
4 28 Aug 206
4 27 Aug 187
-----------------------------------------------------------------------
3 26 Aug 199 0
3 25 Aug 195
3 24 Aug 202
3 23 Aug 208
3 22 Aug 209
----------------------------------------------------------------
2 21 Aug 200
2 20 Aug 130
2 19 Aug 160
2 18 Aug 145
2 17 Aug 170
-------------------------------------------------------------
1 16 Aug 190
1 15 Aug 150
Appreciate for your kind helpful.
Dear Sir,
how to EQUAL name with number like a(mdg 0001 + mdg 0002 = mdg 0003)
Hello I'm using this function below but I keep getting a name response instead of what I am looking for. Is there something wrong with the syntax?
=IF(AND(C3=WHITE, D3=Y), [WhiteY], [FalseWhite])
Thanks
Use this instead
=IF(AND(C3="WHITE", D3="Y"), C3&D3, "Falsewhite")
Note: When you are comparing text, the double quotes sign is required.
I'm trying to put together a formula that will look at a cell and a date and then search two columns to see if those two entries exist and to return a True/False response.
=IF(AND(A2=D2,B2=E2),"TRUE","FALSE")
Hi
I have a 2013 Excel spreadsheet based on Wool Bales. I need to find out the Average cost per lot number (Most of these lots have multiple lines).
I also need to find out the total count of wool bales that have a physical bin (location) number. These are in two separate columns, and some of the locations are blank cells.
Can anyone help?
Hi all
I just want to ask,it is possible to use If function if there is a gap in the given range?
You can use countif function. The following line looks at blank values("") in the Range A1 to B10, and returns TRUE if there is a blank cell.
=COUNTIF(A1:B10,"")>0
Madam
With A column time to B column time if 1 hour late meens c column need to show as "Late" how formala. Pls
Assuming B1 is always greater than equal to A1, you can use the following command
=IF(TEXT(B1-A1,"h")"0","Late","")
Hi. Can you please help me. I already have the IF formula where i want to generate a specific value from a column if between date range.
Example:
Column A1 Start Date, Column B1 End Date, Column C1 Headcount
Data in 2nd row: Headcount of 6 from Jan. 1, 2014 up to Jan.31, 2015
FOrmula in Column D1
=IF(AND(D1>A2, D1<B2), C2, 0)
The formula is working fine but he problem is when here is blank or no date in End date column. I would like to make use of one formula only that will work whether the End date has data or not.
Your help is very much appreciated. Thanks
Hi,
How to handle situation:
I have I3 value 153022, and I need that if char 1 value is bigger than 2 (or I could use also equal to 7) then it gives to cell K3 value KO and otherwise leave empty. I used =IF(LEFT(I3;1)=7;"K0";" ") but it returns no value to anywhere.
Please advise - is this even possible to do that?
=IF(LEFT(I3,1)=7,"K0","")
Just change the semicolon ";" to a comma ",".
Upon further review, you may need to add quotations to the 7.
=IF(LEFT(I3,1)="7","K0","")
or
=IF(LEFT(I3,1)>1,"K0","")
I'm not sure why it works with > without quotations but, does not with =.
Sir,
I have 2 data 1 is feed back taken list another one is feedback to be taken list.
i want to fill the remark as "old customer" and "new customer" with 2 data
A B C D
Deductible Nil Discount KWD 1.500/- 0 1.5
Deductible Nil Discount Nil. 0 0 0
Deductible Nil Discount KWD 0.750/- 0 0.75
Deductible Nil Discount KWD 1.500/- 0 1.5
Deductible Nil Discount KWD 1.250/- 0 1.25
HI FRIENDS, ASSUME ABOVE MENTION IS TABLE AND I WANT TO KNOW C COLUMN NUMBERS ARE PLACED IN THE A COLUMN. IF THERE IS ANY EQUATION IS AVAILABLE
NOTE: A COLUMN CONTAIN TEXTS AND NUMBERS.
M8 me value chahiya
j8 me zero value he to M8 me E8 ka data aana chahi a
You can use a simple IF statement for this
=IF(J8="", E8, "")
or
=IF(J8=0, E8, "")
=IF(LEFT(A3,1)=6,Y,"") not working????????
=IF(LEFT(A3,1)="6","Y","")
Seems you have to use "" when using the = on the Left function.
Still a problem to paste the formula.
In other words, I wish to insert categories in a column refering to the precedent showing the number of habitants per municipality. To analyse thousands of lines, my categories are for a number of habitants between:
0 and 999: A
1000 and 2499: B
2500 and 4999: C
5000 and 9999: D
10 000 and 19 999: E
20 000 and 500 000: F
So sorry that the copy/paste is not working for the formula... Thank you for your help
=IF(C1147=1000,C1147=2500,C1147=5000,C1147=10000,C1147=20000,C1147<500000),"F",))))))
=IF(C1147=1000,C1147=2500,C1147=5000,C1147=10000,C1147=20000,C1147<500000),"F",))))))
Something is wrong with the original, it didn't post the whole formula.
Something is wrong with the these forums as it doesn't seem to let me post the actual formula.
=IF(C1147=1000,C1147=2500,C1147=5000,C1147=10000,C1147=20000,C1147<500000),"F",))))))
Hi Dalia,
I seem to have the same problem and for your formula, you have to use If(and(
Ex. if(and(C1147>=10000,C1147<19999),"E",[similar formula with updated range]
Me again!
I don't understand that each time that I paste my formula, part of it disappear... Hoping that the categories (letters from A to F) will show after each category this time. Another try :
=IF(AND(C1147>=0, C1147=1000, C1147=2500, C1147=5000, C1147=10000, C1147=20000, C1147<=500000),"F"
Sorry and thanks
Sorry, my formula should be read as :
=IF(AND(C1147>=0, C1147=1000, C1147=2500, C1147=5000, C1147=10000, C1147=20000, C1147<=500000),"F"
Thank you
Hello,
I am trying to put categories (A to F) into my excel sheets (thousands of lines!) to be able to analyse depending on the number of habitants (between a number & another) by municipality for a research, but my formula isn't working. Please, could I ask you to correct me? My formula is:
=IF(AND(C1147>=0, C1147=1000, C1147=2500, C1147=5000, C1147=10000, C1147=20000, C1147<=500000),"F"
Thank you for your attention and have a great day/evening
Hi,
This is the criteria :
If assets age is..., then charge over the cost:
=1 year = 75%
>=2 years = 65%
>=3 years = 55%
>=4 years = 45%
>=5 years = 35%
>=6 years = 25%
>=7 years = 20%
Lets say :
A (List of Asset) = Motor (A1); Car (A2); Truck (A3)
B (List of Cost) = RM10,000 (B1); RM50,000 (B2); RM80,000 (B3)
C (List of Purchase Date) = 1/1/2015 (C1); 1/1/2016 (C2); 1/1/2017 (C3)
D (Disposal Date) = 1/1/2019 (D1; D2; D3)
E (Results) = what is the formula for this?
Good day,
I need to write a formula to say that if 15:10:06 it greater than 15:00:00 the make it 15:00:00 and if the value is less then leave it as is,
eg. 15:10:06 to 15:00:00
eg. 14:45:51 leave as is
Hi, I am trying to read excel cells, and want to write an if statement which recognizes whether the cell contains a numerical value or text (#N/A,#DIV/0!) and return specific values in return -
1 - if the cell contains numeric value - 4500, if statement should return numeric value 4500
2 - only if the cell contains this specific text - "#N/A", if statement should return text "NoASP"
3 - only if the cell contains this specific text - "#DIV/0!", if statement should return text "MissingASP"
I tried various formulas, for example - =IF(EXACT(A3,"#N/A"), "NoASP", A3), but this works only if I add in the cell containing the values #N/A with apostrophe or single quote like this ('#N/A), Changing the cell format to text didn't work for me.
Can anyone please help.
I need a formula where I can take todays date in one cell and in another cell if it is not three days after todays date an error pops up says invalid entry.
Hi,
I am trying to use a IF command, ie., =IF(B4=1, "10:00", IF(B4=2, "8:00", IF(B4=3, "8:27","0:00"))). Though i am getting the the result correct, i am not able to do the calculation on the hours (10:00) which is showing as text. How can i get the above result converted in hours.
santhosh
I'm trying to take multiple text in different cells and want them to shows as 1 specific text.
I need to convert Time To Employee shift in excel
Ex. 06:00 To 07:00 A shift
14:00 to 22:00 B shift
22:00 to 06:00 C Shift
In this middle time suppose to some employee will come 06:015 and leave the company 14:15 so i need to count Ashift .
Any Body Help