How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4763 comments

  1. How to I call to both numbers and have text in my if statement. I want to say something along the lines of "You are " + x + " dollars over budget". With the X being a called variable able to be changed.

    Thanks y'all for your help

  2. Values to appear
    - to 10
    11-20
    21-30
    Above 31

    How can we use this in IF Condition as a status.....

  3. My total due amount is in cell A1 and status in cell A2
    i want cell A2 to change itself as per my conditions
    For ex,
    If A1>=0 then A2 should be "PAID",
    If A1 is greater then 0 but less then 350 A2 should be "DUE",
    & If A1 is greater then 350 A2 should be "OVER DUE"

  4. I'm trying to write a formula for the cell to display "x" if the date is greater than TODAY and if the cell does not contain any text.
    Tried this and I can't get it to work:
    =IF(AND(N118>TODAY(),N118*txt*),"x","")
    Any suggestions?

  5. maya has 2 car no DD03F9581 AND DD03G9344. AND LALU HAS 1 CAR NO DD03F9702
    WHEN I TYPE ANY OF CAR NO IT SHAW OWNER NAME BY FORMULA.

  6. Hi, I am trying to write an if statement to return the value of 0 if the number in column c = 38 and if the number in column c is not 38 return the value in column O in the same row.

  7. Ihave 3 column "Amount" "Norm" "stab"

    Amount is => norm result is *Norm*
    Amount is => stab result is *stab*
    Amount is 0 result is *unpaid*
    Plz suggest

  8. I want a formula to calculate a value into column D
    The one I have will not return a dollar value. What am I doing wrong?
    A B C D
    10 10.00 #VALUE! S/B 11.11
    20 10.00 #VALUE! S/B 12.50
    30 10.00 #VALUE! S/B 14.28

    =IF(A2:A4=10,C2/0.9,IF(A2:A4=20,C2/0.8,IF(A2:A4=30,C2/0.7)))

  9. Hello,

    I'm trying to set up a sheet to keep track of cleared checks. I have a column that has the check amount (Col B). I have a check box to indicate it if was cleared (Col J). I want to have a column for the calculation (Col I). So if the check is Cleared (True) then this Column shows 0. If it is not cleared (False) then it shows the same amount as Col B.

    So far I have it to working with the True. I can't get it to equal the value of another cell for false though. I'd appreciate any help)

    I'm only trying it on a specific cell to make sure it works first.
    =IF ( J5 = TRUE, "0",(=B5))

  10. Hi all,

    I am trying to pull data from 3 different tabs onto one sheet. The data are US states in the columns and the other data is either "yes" "no" or is a blank cell. I've done vlookups to match the y/n/blank into 3 columns on one sheet. (I'm sure this isn't the best way to do this either..)

    But now I'd like to pull the data from those 3 columns (each pulling from a different tab) and do if statements to pull my answer into one column. So, for example, State = AL, B1 = yes, c2 = blank, c3 = yes. How do I write a formula to look at all 3 and pull which column isn't blank?

    Thanks in advance!

  11. how do write fourmela if cell 1 = cell 2 then add whats in cell 3

    i have 2 lists 1 of username and pc name and the other one is username and phone number so i put all to the same file i want to make if the name match the name then add the phone number so i can have pc name username phone number

    thanks in advance

  12. Hi,
    Would someone help me with this assignment, it is urgent!
    We want to find the average grade but if i have all A and only a F in the average grade the argument should be "fail" (maybe this is with "IF" function) and i don't know how to do this.
    Hope i was clear.

  13. How do you write an IF formula for a question and answer sheet?. Example of sheet would be Line 1 the Question and line 2, 3,4 & 5 would be the answer following a check box next to each answer. When checking the box it would show True or False at line 6.

  14. I need help with a task.
    I have three columns, One has a list of vendors and if that vendor was on our job that month I put a Y in the 2nd column next to his name. The 3rd column then will have another Y if that vendor has turned in his paperwork for the month. What I want is if the 3rd column is blank i want to highlight it. But if there is No Y in the 2nd column then I want nothing done for those cells. So in other words, if the vendor wasn't onsite then I don't care if his paperwork is in. But if he was and he hasn't turned it in I want his cells highlighted.

    Thank you for your help.
    Jennifer

  15. I need your urgent help please
    I have two column, i want the current date in second column if i put a text in first column,
    When there is no text in first column then no date should be in second column

    • Ahmed:
      From your post it's not clear what type of text should be in the first column, so I just used ISBLANK. Here's what I came up with for you.
      =IF(ISBLANK(A2),"",TODAY())
      The cell where this formula is entered displays today's date when A2 is not blank otherwise the cell displays nothing.

      • Doug,

        regarding the =IF(ISBLANK(A2),"",TODAY()) , Will the date automatically update each day or will the date be set to whatever day you saved the file? I am trying to use the same idea. I want the date to post when anything is typed in cell A2, but I dont want the date to automatically update each day. I have to create a single file for each day of the month and am hoping to not have to go into each file and type the date each time. Looking to create a template.

  16. Is there a formula for changing a cells color? Conditional Formatting will not work for what I want...

    I have a block of text, i.e. A2:F100, (the amount of rows changes every week) in which column A holds the different "Tape Numbers" (AA0053) that I'm verifying. I copy in a column of current available scratch tape numbers in the H column.

    What I want is for my formula to look at H2 (AA0008) and search column A. If it finds AA0008 then color fill H2 Green, IF NOT then color fill H2 Red. Then I'll copy that formula down to H3 and so on... I know the =IF statement will do the True/False check, but I'm not sure how to tell it to change the background color.

    A B C D E H
    AA0008 *EXP 11/19/2018 11/27/2018 11/27/2018 AA0008
    AA0058 *EXP 7/21/2013 7/29/2013 3/16/2015 AA0009
    AA0085 *EXP 7/10/2018 7/25/2018 7/28/2018 AA0010
    AA0086 *EXP 9/1/2018 11/30/2018 11/29/2018 AA0011
    AA0105 *EXP 12/14/2018 12/22/2018 12/22/2018 AA0012

    Conditional Formatting only find the "True" statement then formats the cell. I also need the false, so I want an "old school" formula. I'm not well versed with VBA, so I'm hoping to stay away from Macros.

  17. My qustion is that in a cell in my worksheet which contain only date (12/12/12 to ...) and n/a so I need comment of dateee no problem,or n/a it should be a problem...

  18. I am facing a problem in excel sheet I need your help.
    For example if we enter the value like this
    1517001255 (A6)
    To (A7)
    1517001260 (A8)
    Than how we can find the (1517001256,1257,1258,1259) in H6
    Waiting.

  19. Please if you can help me my IF format is

    =IF(C2 ISBLANK,"",+30DAYS

    So basically what I want is if there is a date in cell C, then for cell D to add 30 days but if it is blank then leave cell D blank, i have an error in the +30 days but i can not work out how to do it

    • Hello, Sam:
      I think what you're looking for is something like this:
      =IF(ISBLANK(C2),"",C2+30)
      Be sure C2 and the target cell are formatted as dates.

      • Thank you so much Doug :)

  20. MF:
    There are several ways to identify duplicates in Excel. One way is to use Excel's built-in duplicate identification tool. Check out this article in AbleBits for several methods to accomplish your task.
    https://www.ablebits.com/office-addins-blog/how-to-highlight-duplicates-excel/
    When you want to look across several sheets you can use something like this in the formula =COUNTIF(Sheet2!$A$1:$A$7,A1)>0
    Where this is in the Sheet1 conditional formula rule.

  21. I'm having all sorts of problems with this. Please help!

    First tab: Typical Business Marketing List of 1200 businesses
    Column 1: Company Name
    Column 2: Address
    Column 3: City
    etc.
    2nd tab: Narrowed list of 50 of those businesses for a targeted mailer.

    I'd like to add a column to the main tab that indicates which businesses on the 2nd Tab were sent the mailer, with an X or something, perhaps. To do this, I have to somehow match the two columns on the different tabs and then if there's a match, an X will appear.

    I've tried =IF, =MATCH, VLOOKUP with a hundred different options and I can't figure this out.
    Any help would be greatly appreciated!!
    Thank you!

  22. Hii, am having a challenge with using an IF function to filter data of the type: 12/4/2018 5:53:40 PM.
    I have got a date captured just like above together with the time and i would like to filter by the date.
    How can i go about this?

  23. I am trying to increase vacation hours by 3.5 hours each year after 10 years. So far I have it working for 3 yrs, 4 yrs and 5
    =IF(A2>=2016,105,IF(A2>=2015,140,IF(A2>=2012,175))) not sure how to continue to include and increase by 3.5 each year after 2009

  24. >= 95 % = 1
    >= 97 %= 2
    >= 99.6 %=4
    >= 101 %=5
    >=103%= 6

    Kindly suggest for above if formula

    • Hello, Dayanand,
      Please try the following formula:

      =IF(A1 >= 103%, 6, IF(A1 >= 101%, 5,IF(A1 >= 99.6%, 4, IF(A1 >= 97%, 2, IF(A1 >= 95%, 1, "")))))

      You can learn more about nested IF function in Excel in this article on our blog.
      Hope you’ll find this information helpful.

  25. hi , how can i write the fact that if two countries use the same Currency 'euro' for exemple , 1 otherwise 0 ?
    waiting for your response

    • Hi Sasou,

      If we understand your task correctly, the formula below should work for you:
      =IF(A1 = B1, 1, 0)

      Where A1 and B1 are the cells that contain currencies.

      Hope this is what you need.

  26. Please share me Excel Formula for following....

    I want difference in two different dates but if this difference is more than 1 day it should reflect other wise not

    • Hello, Shekhar,

      Assuming that your dates are in the first row, the following formula should work for you:

      =IF(B1 > A1, B1-A1, "")

      Hope this is what you need.

  27. Is this correct

    =IF(LEN(C3=10),RIGHT(C3,8),RIGHT(C3,7))

    • Hi Samith,

      I believe this is what you are looking for:
      =IF(LEN(C3)=10,RIGHT(C3,8),RIGHT(C3,7))

  28. Seeliya Unit Price Al-Khaira Unit Price Madinah Unit Price
    1472.6 420
    15.5 40
    7.75 2
    450 24
    6.2 2.5
    9.3 3
    10.85 12

    i need the solution for the above work.

    This is the purchasing process. For one material, there are three offers available in quotation. I need the name of the supplier in a column who bidding the price in less.

    Thanks in advance.

  29. Dear Sir/Mam,

    i am following your formula and suggestions, all is best to use in work,
    plzz can you help me????

    if there is 1 box included 144 pcs
    suppoz i have closing stock is 146 pcs it means 1 box n 2 pcs if there is 288 pcs it means 2 box or if there is 143 pcs it means 143 pcs
    which formula i use and how????
    plzz help me asap
    mail me as soon as possible.

    Thanku

  30. If(N2="YES",i should get a drop down list of (a b c d e ), if N2="NO", then i should get NA)
    how do i write this formula in excel

    • Hello, Hermant,

      Unfortunately, there is no way to solve your task using standard Excel functions. Most likely you need a special macro. I am really sorry we can’t help you with this.

      You may try to find the solution in VBA sections on mrexcel.com or excelforum.com.

      I wish I could assist you better.

  31. Hello all, I hope someone can shed some light on my issue.
    I am trying to calculate fuel consumption based on different MOVEMENTS of the ship from cell A1.
    Cell A1 will either be, LOAD, SEA, MANEUVER, DISCH. Each Movement will correspond to a different CELL with its corresponding fuel consumption rate. SEA corresponds to cell A20 (or 1.02). I tried the IF function, but could only manage to get one IF.
    ex A1 (SEA), B1=30 hours. FORMULA in C1, =IF(A1="SEA",(B1*A20)). This one works, but I cant seem to add multiple IF functions for LOAD, MANEUVER, DISCH, withouth it saying #value.
    Any help would be great! thank you

      • Mary,
        Thank you so much! That was it! Merry Christmas!
        ~P~

        • Pricilla,

          Thank you very much for your reply. I'm so glad to hear you found the solution in this article!

          Merry Christmas and Happy New Year! :)

  32. Ross:
    What's the IF formula you're using?

  33. I am creating a time sheet. For each day I have three columns, Time (15 min breakdown of the day), Activity, and Time worked.

    I each created an IF function to fill the third column with a value 0.25 if the Activity cell has content.
    (ie; no content = I have not done any work. 0.25 represents the quarter of an hour i have worked).

    I had hoped to use a Sum function at the bottom of the third row to add up all the 0.25s to total my hours worked that day. However, the SUM function does not recognize the 0.25, generated by the IF function, as a number (cells are in number format but the 0.25 aligns to the left like text).

    Would appreciate some help with this puzzle :)

  34. Requested Mam/Sir,

    Kindly send me the All If functions in a Excel sheet, so that i will practice it at home after the office

    Your's Hopefully,
    A.Ganesh

  35. I have a set reference number in Colum A1 (254511556)

    Column B1 has the product name (metal screw)
    Column B2 has the product delivery date (DOD 15 Nov 2018)

    Is there a way to move value B2 to C1, if so can someone please help with the formula.

    thank you

  36. Khan:
    If the only two options are "PCS" or "CTN" then enter this in an empty cell:
    =IF(A24="PCS",F24*H24,E24*H24)

  37. IF COLUMN A TEXT IS = "PCS" THEN COLUMN H MUTIPLY WITH COLUMN F
    IF COLUMN A TEXT IS = "CTN" THEN COLUMN H MUTIPLY WITH COLUMN E

    KINDLY HELP IF THIS FORMULA IS POSSIBLE THEN MAKE FORMULA PLEASE AND SHARE..

  38. Hello Everyone,

    Trying to figure out how to show the value from a cell when doing IF.OR function.

    Here is my function (not working):
    =IF($P$14="";"";IF(OR($P14="PALLET";"$H14";"$L14"))

    The function should show empty if empty, but show the value of cell "H14" if P14=Pallet, while if different, show the value of cell "L14".

    Thank to all for the help.

  39. I Need if date is less than 15 days then it will be the same month and if date is more than 15 days the it should be next month. Please help in find formula

  40. Hi
    What is the formula to allow an Yes/No response to the induction expiry.

    Induction expiry Permit to work
    16/03/2020 yes
    18/03/2018 no

    THanks

  41. I am stumped, I am trying to tie 3 columns together with column 1 having a drop down menu. I need to be able to use the first column to select a city and the following 2 columns auto-populate with amounts.

    (IF D4=Norfolk, then E4=94 and F4=55) is what I am trying to get to work. Is this even possible?

    • No Anthony that is not even a correct formula.

  42. Hi

    If you see my data table, variable INNO_PS has value (yes/no) only for 2011H1. I need the same value for 2010H2 in INNO_PS variable if ID is same. This is a large database, it is not possible to do manually. Please help to get Excel syntax for this purpose. Thanks

    ID WAVE INNO_PS
    5 2010H2
    6 2010H2
    6 2011H1 No
    11 2010H2
    13 2010H2
    17 2010H2
    17 2011H1 Yes
    23 2010H2
    23 2011H1 No
    25 2010H2
    25 2011H1 No
    26 2010H2
    27 2010H2
    27 2011H1 Yes
    28 2010H2
    29 2010H2
    32 2010H2
    32 2011H1 Yes
    40 2010H2
    40 2011H1 No

  43. 80% - 83% 1 mark
    84% - 87% 2 mark
    88% - 91% 3 mark
    92% - 95% 4 mark
    96% - 100% 4 mark
    help me to formula for this in excel

    • =IF(L29<80%,"0",IF(L29=80%,"1",IF(L29<=83%,"1",IF(L29=84%,"1",IF(L29<=87%,"2",IF(L29=88%,"3",IF(L29<=91%,"3",IF(L29=92%,"4",IF(L29<=100%,"4","0")))))))))

      Note: L29 is reference cell

      • =IF(L29<80%," ",
        IF(L29=80%,"1Mark",IF(L29<=83%,"1Mark",IF(L29=84%,"2Mark",IF(L29<=87%,"2Mark",IF(L29=88%,"3Mark",IF(L29<=91%,"3Mark",IF(L29=92%,"4Mark",IF(L29<=100%,"4Mark","0")))))))))

  44. ...if the 'REORDER LEVEL IS GREATER THAN THE STOCK QUANTITY'. what formula should i use?

    Thank you..

  45. Please help me.. I HAVE 2 CONCERNS
    1. I have a column of "Stock Quantity". i want the "Stock Quantity"automatically decreases when i insert a data in my delivery sheets. then,

    2. From my "Stock Quantity" let say i have 1000 stocks, the "REORDER LEVEL is 2,500. i want the row highlighted into color red if the 'REORDER LEVEL IS GREATER THAN THE STOCK QUANTITY'. what formula should i use?

    Thank you..

    • i like to share my view here, if its use full i feel hapy

      For 2) conditional formating, then Highlight cell rules, then greater than option not required formle for RED colour

      For 1) In same cell its not possible, need to add one more column for stock quantiry for ( opening or closing )then its possible

      =B5-Sheet2!B6,share your mail id i try to send excel sheet directly

  46. I have a table with 5 columns, which each column has there own percentage of evaluation for example 25%-25%-25%-10%-15%.
    I want to create a formula that to look on each cell for each column the number and if it does't find number to take the percentage of that column and spread it to the other columns.

    25% 25% 25% 10% 15%
    1.00 0.73 0.45

    In this case it has to take the 25% and the 10% and spread it to the other columns and do the calculations again from the start so I will get the correct number.
    If I was going to do it by hand I will do the 35%/3 which 11.67% and add it on each column with data and then take the original data and multiply them with the result of the summary -

    0% 36.67% 36.67% 0% 26.67%

    Who can give a help with this?

  47. Is there a way to automatically move a row to sheet 2 if a specific cell contained text?
    Cell that would contain a date or be blank is G2. If it contained text I'd want to move a2:h2 to sheet2. On sheet2 it would not need to be in any specific place.

  48. I have two worksheet. i.e,Worksheet A and worksheet B. A11 of Worksheet A contains FR189X and B6 of Worksheet B is FR189. Likewise I have multiple rows in Worksheet B. I want to compare A11 of Worksheet A with column B of Worksheet B, if its equal then copy the value present on column F of Worksheet B into Worksheet A.

    I am using below codes and its working when A11 is same with B6.

    =IF(LEFT(A11,5)=[Book1.xlsx]Sheet1!$B$6,VLOOKUP(LEFT(A11,5),[Book1.xlsx]Sheet1!$B:$S,18,0),"")

    But its not working when I want to replace A11 of Worksheet A with B7 of Worksheet B. Can you please help?

  49. Hi,

    I'm trying to write a formula to say that if cell F4 says 'yes', to then remove the fill colour from cell E4. I am having trouble doing this. Can anyone do this? Thanks in advance :)

    • You don't need a formula - look at Conditional Formatting>Highlight Cell Rules

  50. How would I write the formula for if a range contains a value greater than 2, then true?

    • Hi.. i like share my view..

      =IF(J17>2,"True", "False")

    • Hi... i like share my view ..

      =IF(J18>2,"True", " ")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)