by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
HI
How can i form this formula...
I want to compute the BMI of children with regards to their (Age, Gender, Weight, Height)? thanks
what function should i use?
B1=Gender C1=Age D1=Weight E1=Height F1=BMI G1=COMMENT (underweight,normal, overweight)
IF(B2=F/FEMALE, F2>14, "underweight", F224"Overweight"), IF(B2=M/MALE, F2>15, "underweight", F2<=25, "normal", F2<25, "overweight")
please how will i correct this?
thank you
A1 is 7300
B2 is 7850
in C2 row = if a1 is less than b2= 0 and if not than a1-b2
request suggest the formula on my email
Hello Deepak!
You can use the following formula:
=IF(A1<B2,0,A1-B2)
Hello,
You can use the following nested IF formula that lists all conditions:
=IF(F1>0,F1&G1,IF(E1>0,E1&G1,IF(D1>0,D1&G1,IF(C1>0,C1&G1,IF(B1>0,B1&G1,IF(A1>0,A1&G1,""))))))
Thank you so much for your help Andrei Bertosh! It worked!!!
Anderi,
It worked but it's showing the results in one columns. Can you tell me how to show the results in two separate columns?
Thank you!
Hello Sher Khan !
You can write a separate formula for each column.
Anyone willing to accept this challenge and help me?
I have data in 7 columns, 5000 plus rows. First 6 columns have numbers they refer to the value in column 7th which is text. Example
10 0 0 0 0 0 H
10 101 0 0 0 0 S
10 101 10105 0 0 0 T
10 101 10105 10 0 0 W
10 101 10105 20 0 0 F
I want to see the result in the new sheet like this.
10 H
101 S
10105 T
10 W
20 F
Column 5th and 6th value is "0" so the result should be "no value"
Thank you for your help in advance.
Can someone please help with,If A1>=10; Efficient, If A1=5; Average, If A1=3; Poor, If A1<3 ;"" (blank).
Thank you.
Hello,
You can use the following nested IF formula that lists all conditions:
=IF(A1>=10,"Efficient",IF(A1=5,"Average",IF(A1=3, "Poor","")))
I hope this helps.
Thanks! For me work grate.
Hello, Can anyone help me with the following. I have data in 7 columns, 5000 plus rows. First 6 columns have numbers they refer to the value in column 7th which is text. Example
10 0 0 0 0 0 H
10 101 0 0 0 0 S
10 101 10105 0 0 0 T
10 101 10105 10 0 0 W
10 101 10105 20 0 0 F
I want to see the result in the new sheet like this.
10 H
101 S
10105 T
10 W
20 F
Column 5th and 6th value is "0" so the result should be "no value"
Thank you for your help in advance.
Hello, I would greatly appreciate some help. I would like to create a command which will do the following: when I insert a specific text on a cell this will equal to a specific number. For example , when I insert "TT" this will equal to 0.2. Or when I write HD this will equal to 0.1. This will then be summed up on another cell. I would like to see only the letters but not the numbers. Is that possible?
Thanks in advance for any help offered.
Hello Christos,
If you can have just either of the values, you can use the following formula:
=IF(A2="TT",0.2,0.1)
Here A2 is the cell where you enter the necessary text.
Hi. I need a formula where if C9 is YES then it gives a score of 5, If C9 is NO then its gives a score of ZERO. Help please, its sending me round the bend
Hello Ian,
You can use the following formula:
=IF(C9="YES",5,0)
=IF(B2>0,C2=0,"sliding","rotary") i want help if it b2 greater than zero, and c2 equal zero, i need it sliding, but if not i need it rotary and this formula has something wrong
Hello Ahmed,
In order to meet both conditions, you need to add AND to your formula:
=IF(AND(B2>0,C2=0),"sliding","rotary")
I hope this helps.
Hello,
I have 1 list of 4000 emails and other list of 700 emails. How can I sort or check or highlight or check if that 700 is available or not in 4000 emails ?
Many thanks.
Best,
Ravi
Hello Ravi,
If the email lists are in different sheets, you can use the Compare Two Tables wizard in the Duplicate Remover add-in for your task. You can find more details and a link to download the product on this page:
https://www.ablebits.com/excel-suite/find-remove-duplicates.php
Hello everybody can someone help me, i need to link two tables together with a condition .
For example I have To tables tasks For week1 and tasks for week 2. And i want to make if the task didnt accomplished in week 1 it should be transformed automatically to week2.
Time WOB: tons Top Drive RPM: Result of value of time
when WOB>0 and Top drive
RPM=0 like 9 minutes in
a result column
1:34:00 AM 0 44
1:34:30 AM 0 44
1:35:00 AM 0 43
1:35:30 AM 0 44
1:36:00 AM 0 43
1:36:30 AM 0 44
1:37:00 AM 0 42
1:37:30 AM 0 43
these exactly are recorded time based data which is recorded every 30 seconds, so i need to get the exact sum value of the first time column like 02:12:15 in a separate column when wob>0 and Top drive rpm=0 this is the same question above
Hi everybody, could you help me please..i have two issues
first one: if i have a time column like each cell have a time value like 12:51:00 and the other cell down in same column 12:52:00 and so on all the column... i need to make a function which let me get the sum of the time column as a value like from 12:51:00 to 12:59 and i need the result equal 9 minutes.
second issue: if have i need to make a result if B2>0 and C2=0 i need D2= the value of A2.. thanks alot
Hello Ahmed!
1. Time in Excel is a fractional part of 24-hour period, i.e. 24 hours is regarded as 1. You need to deduct the first time from the last one to find the time interval. To display this interval in minutes, you need to multiply the result by 24 and 60 as there are 24 hours in a day and 60 minutes in an hour.
=(F10-F1)*24*60
Cell format is Number.
2. You can use the following formula:
=IF(AND(B2>0,C2=0),D2,"")
suppose the quantity in "A1"cell =1000
I want to type quantity in "B1"cell with following conditions -
if quantity of "B1"is lesser than "A1",take the quantity as it is.
if quantity of "B1"is more than "A1",take the quantity as "A1".
if quantity of "B1"is same as "A1",take the quantity as it is.
Pl send me the formula for above.
Regards,
Umesh M
Hello Umesh,
If you want to use the value in cell B1 as a condition in the formula, you need to enter the formula in a different cell:
=IF(B1<A1,B1,IF(B1>A1,A1,B1))
I hope this helps.
Hi
As I understand you would recommend using nested IF Function (for example : =IF(Con1,IF(Con2, "A","B"),"B") )instead of AND with if (=IF(AND(Con1,Con2),"A","B"))?
Is that right?
Many thanks.
Hello Arash,
Thank you for your question.
The choice depends on your task. When you use nested IF, you are saying that the cell can comply with one of the conditions and return the respective result. For example, your first formula would look something like this: =IF(Con1,"A",IF(Con2, "B","C"))
Excel would read it the following way: if condition 1 is true, then we should see "A", if condition 2 is true, then we should see "B", otherwise we should show "C".
When you use AND with IF, you'd want both conditions to be met. So when you type =IF(AND(Con1,Con2),"A","B") you say that if Condition 1 and Condition 2 are true at the same time, you will see "A", if not then you will see "B".
I hope this clarifies the way it works for you.
I want to know if i add three cells value and result is 100. This 100 how its came in words in excel putting formula or others way to get?
I need a formula that looks at multiple cells in a column and decides if the date shown in each cell falls between February 21, 2016 and February 27, 2016. If it does then it adds it to a running quantity in the cell where the formula exists.
Thank you very much
Hello Ty!
You can use the following formula:
=COUNTIFS(D1:D25,">"&DATE(2016,2,21),D1:D25,"<"&DATE(2016,2,27)) Where D1:D25 are the cells with dates.
Hi, I would like to have equation for: If a2>=5; Efficient, If a2=3; Average, If a2=2; Poor, If a2<2 ;"" (blank).
Thank you.
Hi Mitesh,
You can use several conditions in the formula:
=IF(A2>=5,"Efficient",IF(A2=3,"Average",IF(A2=2, "Poor","")))
Hi, I want formula of in lst column if date is 15.03.2015 in 2nd column March-2015 if date is 16.03.2015 in 2nd column April-2015. Please help formula.
Hi, I want formula of in lst column if date is 15.03.2015 in 2nd column March-2015 if date is 16.03.2015 in 2nd column April-2015. Please help formula.
I have a spreadsheet for stock market transaction. I need to do the following check. If it is a BUY(LONG) transaction, return profit as exit cost-entry cost. If it is a SELL(SHORT) transaction, function should return profit as entry cost-exit cost. My columns are D - BUY or SELL depending on type of transaction. G- Entry cost and K - Exit cost. I made the following formula .
If(D2=BUY, K2-G2, G2-K2). It is returning a #Name? error. How to make this formula.
Thanks for the help.
Hello Aravind,
Please make sure you include the text in quotes, e.g.
=IF(D2="BUY",K2-G2, G2-K2)
just an addition: It need to be able to find it in every row since I have a lot of rows.
Hi guys,
I have coloums of prices form different shops. I need to identify which row has the cheapest (minimum) price and have the outcome of the coloumn name (shop name). I can of course use =min to find the lowest, but how can I get the output of the shop name for each minimum?
Thanks!
Hello Anders!
You can use the formula: =INDEX(A1:A4,MATCH(MIN(B1:B4),B1:B4,0))
Where A1:A4 are the shop names, and B1:B4 are the cells that contain prices.
Hi,
How to fix selected sentences in at one location in excel ??
Example,
I have 2 different location name one of INDIA & second is USA. How can I make formula for no one can type any other location name accept only INDIA & USA.
Thanks.
Laxman Purohit
Hello Laxman,
You can use Data Validation in Excel. First you need to create a reference list with your location names, you can do it on any other sheet. Then select the cell where you want to get just one of these values, go to Data tab in Excel and select Data Validation. Choose to allow "List" and refer to your location names in the "Source" field. You can unselect "Ignore blank" if the cell has to have a value, and enter error alert on the respective tab.
Thank you so much Irina... !!!
You are very welcome :)
I have a list of user log ins on PCs. The same PC could be used by any number of users. So, just making a list of PCs that need to be updated and having 14000 lines of PCs, is there a way to parse the list to just include a PC name just once.
Ex:
A2=PC1 To Show PC1
A3=PC1 PC2
A4=PC1 PC3
A5=PC2
A6=PC3
A7=PC3
Hello Cal,
If you need to keep the original list, you can run our Duplicate Remover add-in, choose to look for uniques and copy them to a new worksheet.
Otherwise you can choose to remove duplicates from your original list to get a list of unique PC names.
Thanks Irina! I wasn't aware of that function.
Thank you Shvetlana. I had a couple of queries about 2 different formulae but after reading all the comments and the answers that you have given, I could figure them out on my own. Thank you!
I have Got the formula Thanks.
=IF(F7>=I7,"Ok",IF(AND(F7>=""),"","Not Ok"))
Hello Faheem Ahmad,
If you are trying to show "Ok" when cell F7 contains a value over 17, and to show "Not Ok" when it is 17 or less, then you can use the following formula:
=IF(F7>17,"Ok","Not ok")
If your task is different, please describe it in more detail.
Hello,
I'm trying to use an if function to pull data from one worksheet to another based on the text in a column.
Example: Sheet 1 has roughly 500 rows of data, and I want to pull only the rows that where "SS" is included (not exactly) in column C. I've failed so many different ways, not ever sure which formula example to share:/ Any help would be appreciated.
Dear try Pivot Table, might be it helps.
Hello Jason,
It sounds like you can filter the table by values in column C and copy all rows that contain "SS". If this doesn't help, please send a sample worksheet to support@ablebits.com and include a link to this blog post and your comment number. We'll do our best to assist you.
I appreciate the response and i took you up on your offer. I just sent you a copy of the spreadsheet and a bit more details. Thanks for your follow up.
Hi Svetlana
i have a formula below but i want to add one more thing if c2 is blank then answer should blank.
=IF(b2>=c2, "Ok", "Not Ok")
Thanks
Hello Faheem Ahmad,
Just like in the example above, you can use nested IF functions:
=IF(C2="","",IF(B2>=C2,"Ok","Not Ok"))
Thanks Dear <3
Hello!
I am a novice with excel trying to create a nested 'if' formula to calculate a bonus.
It needs to calculate '50-59' as '1', '60-69' as '2' etc.
This is what I have tried...
=IF(D47>=50=60=70495969<79,3,0)))
Neither is working for me and I have no idea what I'm doing?
Please can someone help as I am trying to create a salary sheet for a small business.
Hey Craig,
You can try following formula and can modify as per your need.
=IF(AND(A1>=60,A1<70),2,IF(AND(A1=50),1,""))
I assumed you have data in cell A1.
Let me know if this works for you. :)
Anil Dhawan
Hi Craig,
For this task, you'd better use nested If functions beginning with the highest group (70-79 in this example):
=IF(D47>=70, 3, IF(D47>=60, 2, IF(D47>=50, 1, "")))
Thanks for replying. I will put my question better this time.
I want to make a formula to say if D2 less than 1501 then "1"but if D2 is more than 1501 but less than 3001 then "2" and if D2 is greater than 3001 then "3". I just can't seem to use IF correctly to make this work.
hi,
=IF(D2=1501,D23001,"3","")))
Hello Philip,
You can use the following formula for your task:
=IF(D2>3001,3,IF(D2>1501,2, 1))
Just make sure you start with the highest number. If it's more than 3001, the formula will return 3, if it's more than 1501, it will return 2, otherwise, i.e. if it is less than 1501, it will return 1.
I require a code for
IF E4 = Closed then E4 fill colour will be Green if not it will be Red
Wonder if you can help? also need it for whole column eg E4-E20?? same formula just whole column
Hello Matty,
You will need to add two conditional formatting rules: click on "Conditional formatting" icon on the Home tab, choose to "Use a formula to determine which cells to format" and enter =$E2="Closed", set the necessary fill color and click Ok. Then create a similar rule for Red color depending on the value you have in other cells.
You can find a detailed description of conditional formatting in this blog post:
https://www.ablebits.com/office-addins-blog/excel-conditional-formatting-formulas/
Are there any rules while using the word "TRUE" and "FALSE" in IF formula
For example,
=IF(A2="TRUE","A","B") - Even A2 is true, this formula is not working. It gives always "B". Why? Then I just remove brackets and just put the formula like =IF(A2=TRUE,"A","B"), it is working. Any concerns?
Hi Magil,
The "TRUE" in brackets is a string, not boolean value.
The formula =IF(A2="TRUE","A","B") will return "A" if you have the "TRUE" as string in cell A2. Please try to type "TRUE" in cell A2 and change the cell format to Text.
if(V11>3 & V11<5)then (ok), if not (not ok)
any one can help :\
=IF(AND(V11>3, V11<5),"OK","NOT OK")
Why does this change what I write?
Hi,
use this formula
=if(D2=3001,"3",""))
=IF(AND(D2>1501,D2<3001=3001,3,""))
Formula didn't copy right - here you go.
=IF(AND(N2>1501,N2=3001,3,""))
Our blog engine often distorts "<" and ">" symbols in formulas, sorry for this, but we just cannot fix it on our side.
If my understanding of the task is correct, I'd suggest using nested If's:
=IF(D2>3001, 3, IF(D2>1501, 2, ""))
If D2 is greater than 1501 but less than 3001 it returns 2, if D2 is greater than 3001 it returns 3, an empty string otherwise.
I want to make a formula to say if D2 1501 but less than 3001 then "2" and if D2>3001 then "3". I just can't seem to use IF correctly to make this work.
I want to make a formula to say if D21501 but less then 3001 then "2" and if D2>3001 then "3". I just can't seem to use IF correctly to make this work.
In G8, enter an IF formula to calculate the share price difference between 2/25/2016 and 2/26/2016 for each of the 30 companies if that company’s share price was not zero on 2/26/2016. In case of a zero price, the formula returns “N/A”. Autofill the cells below to G37 with the formula in G8.Im not sure how to write this formula.
I'd need a bit more info to actually write up a formula, but sounds like you'll want to do a VLOOKUP
Hello!
In a situation #N/A may use the formula IFNA.
eg: =IFNA(VLOOKUP("Seattle",$A$5:$B$10,0),"Not found")
(IFNA tests the result of the VLOOKUP function. Because Seattle is not found in the lookup range, VLOOKUP returns the #N/A error value. IFNA returns the string "Not found" in the cell instead of the standard #N/A error value.)
Hello ,
I want your support for if condition formula ,,,, I do export from 2 plants into different destinations and I want that the formula to chose for the destination the plant from which it departure , fro exemple: lets say departure plants ,, (X1 and X 2 ) and destination as follow, i have rapa , rochling and stirling park from X1 and for X2 i have the rest.....) i want the formula to put x1 or x 2 depanding on the destination,
thanks in advance
Hi,
I was wondering if you could help me with a formula that would label all orders between 8:00 and 17:00 "Day" and all orders outside this timeframe "Night".
I had =IF(H2>=8,H2<=17,"Day","Night" but it doesn't work.
Thanks
Hi Clara,
use this formula
=if(and(H2>=8,H2<=17),"Day","Night")
Good day,
Can you help with this formula: If C2=1 then D2=E1
A B C D E
1 (%) Spent to date 0.00%
2 Feb-16 0 0.00% R -
3 Mar-16 0 0.00% R -
4 Apr-16 0 0.00% R -
5 May-16 0 0.00% R -
6 Jun-16 0 0.00% R -
In sheet 1 Month & year and in sheet 2 period ( from to )i want formula if the ending date is 15th, month & year taken in sheet 1 earlier month & year. if date is 16th month & year taken in sheet 1 after month & year in sheet 1
please help me.
My if statement does not work on text data, only numeric. I have changed the format to read General or Text for the two columns that I'm trying to compare and it is as if it does not know it is text?
Hello Vickie,
Please make sure you enter text in quotes. If it still doesn't work, please share the formula you are trying to use.
I want to enter an if function that says if something in cell A3 matches sheet 2 cells B2:B18 than insert what is in cell F2:f18.
Hello David,
You need to use the VLOOKUP function, please see this blog post for its detailed description:
https://www.ablebits.com/office-addins-blog/excel-vlookup-tutorial/
Hi,
need help to formula the following:
If A1 is ">40", A2 Value should be "1"
If A1 is "31-40", A2 Value should be "2"
If A1 is "30", A2 Value should be "3"
If A1 is "20", A2 Value should be "4"
If A1 is "<15", A2 Value should be "5"
I can only get the 1st and the 2nd correct.
results of 3rd-5th is the same as the 2nd which is "2"
--------------
I have another one which is perfect:
=IF(Q13<6,1,IF(Q13<=6.4,2,IF(Q13=6.5,3,IF(Q137,5)))))
but couldn't apply that same formula to the first problem.
hope anyone can help me.
Thanks!
Hi Ali.
You can use this formula:
=IF(A1<15,5,IF(A1=20,4,IF(A1=30,3,IF(AND(A1>=31,A1<=40),2,IF(A1>40,1,"")))))
I am having difficulty with a formula used to calculate whether a pupil has passed a unit in their course.
This is the formula, but when I enter P in either of the first 2 columns then I get #NAME. Any help would be much appreciated.
=IF(OR(BB7="p",BC7="p"),IF(or(BK7="p"BF7="p",IF(or(BL7="p",BG7="p",IF(or(BM7="p",BH="p")"P",""),""),""),"")
Hi Janine,
u try this
=IF(OR(BB7="p",BC7="p"),"p",IF(or(BK7="p"BF7="p"),"p",IF(or(BL7="p",BG7="p"),"p",IF(or(BM7="p",BH="p"),"P",""))))
Hi, this was very informative! Thank you so much!
I'm wondering if you can take your idea one step further. I currently have =IF(F2>I2, "2", "0"), so if F2 is greater than I2, my cell shows a 2, and if it is smaller than, it shows a 0... but how do I include if F2=I2, the cell will show 1? (In essence, I'm trying to calculate scores for baseball, where a win = 2 points, a loss = 0 points and a tie = 1 point. Thanks in advance!
Cheers,
Shannon
Hi Shannon,
=if(F2>I2,"2",if(F2<I2,"0",if(F2=I2,"1","")))
Thank you, Hemanth! This is just the question that I had as well. Very helpful.
Thanks to your question I've managed to solve mine. Many thanks x
Hi,
am using =LEN(N4)-LEN(SUBSTITUTE(N4,",","")) to determine the number of text values separated by commas. I need to count the number of text values in the cell which are separated by a comma. e.g.
cell b3 alpha,bravo, charlie
cell b3 contains 3 text values, but only 2 commas
How do we count the number of text values in a cell, or the number of commas + 1 ?
in pseudo:
if cell contains one comma,
then comma count is one, but the text value is two,
(if text values are separated by a comma, then this means that
there is two text values)
if there two commas found,
then there must be 3 text values, etc.
thanks!
Hello Steve,
Assuming there is always one text value more than there are commas, you can simply add 1 to your original formula:
=LEN(N2)-LEN(SUBSTITUTE(N2,",",""))+1
Hello,
I have a spreadsheet that I need to remove duplicates but I have multiple rows have the same "Students Name" but the variances are on 2 columns Yes for Pell and Yes for DL. If the student received Pell and DL it shows in 2 rows I need to have it in 1 row. Also some of the students only received Pell but not the DL. I know I did this If formula last year but I just can't remember exactly please help.
StudentName DL Pell FundSource
Aguirre, Leticia Y N DIRUNSUB
Aguirre, Leticia N Y PELL
Aguirre, Leticia Y N DIRSUB
Hello Sylwia,
It sounds like you need the Combine Rows Wizard add-in. If it doesn't fulfill your task, could you please show the expected result?
I want to use excel formula using if. (If I enter 1,00,000 the result is to come 15,000 in specific column
(If I enter 2,00,000 instead of 1 lac the result is to be come 16,000 in in the same specific column
(If I enter 3,00,000 instead of 1 lac or 2 lacs & the result is to come 17,000 in the specific column
(If I enter 4,00,000 instead of 1,2,or 3 lacs the result is to come 18,000 in the same specific column
(If I enter 5,00,000 instead of 1,2,3 or 4 lacs the result is to come 19,000 in the same specific colum
I need help to construct one formula
i.e.
if the value in A1 is greater than 10 than result will be 1 and if the value is less than 5 result will be .5
Hi,
=if(A1>=10,"1",if(A1<=5,"5",""))