by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
I have three columns. Columns A and B contain date & time information and column C contains the difference (in minutes) between A and B. The formula being used in column C is TEXT(B2-A2), "[mm]". Currently if nothing is in column A or B the formula in column C shows 00. I would like for it to show blanks.
Please help me understand why I am unable to use the following formula so as to not see 00 in column C:
IF A2>0, TEXT(B2-A2), "[mm]", " ". Explanation: If columns A and B are not populated, column C should appear as blank and not contain 00.
Are you able to create an IF then statement in excel and embed another function formula?
Example:
Column A2 contains a start date and time: 5/15/20 14:15.
Column B2 contains an end date and time: 5/16/20 08:09.
Column C2 contains a formula to caculate the duration between columns A and B in minutes: TEXT(B2-A2), "[mm]".
I am looking for a formula where blanks will appear in column C2 if column A2 is not yet populated. I want to include the TEXT formula throughout column C, in order to auto populate the column C once columns A and B have data. Currently, using the formula TEXT(B2-A2), "[mm]" yields 00 in column C2 if A2 is blank.
I tried the following formula, but cannot get it to work: If A2>0, TEXT(B2-A2,"[mm]", " " Explanation: If nothing is in column A, column C should be blank (i.e. not show 00). Thanks in advance for your assistance.
Hello Joe!
Use the IF function with two conditions
=IF(AND(A2<>"",B2<>""), TEXT(B2-A2,"[mm]")," ")
If there is anything else I can help you with, please let me know.
Hi. I am trying to create a formula that says:
If (a1 =1 then c1 = 50) ( a1= 2 then c1 = 60) (a1= 3 then c1 = 70) (a1 = 4 then c3 = 10)
Thanking you in advance.
Hello Jeff!
A formula can only set a value in the cell in which it is written. The formula in C1 cannot change cell C3.Therefore, I assume that C3 is a mistake. Change C3 to C1. The formula in C1 is
=IFERROR(CHOOSE(A1,50,60,70,10),"")
Or use the If function
=IF(A1=1,50,IF(A1=2,60,IF(A1=3,70, IF(A1=4,10, "") ) ) )
Hi,
Could you please help me? I have column J as text - apple;orange;bananas;vegetables (spinach, fenugreek, etc); acai berry. I want to create Column K as 1 if there is orange in Column J and 0 if not OR 1 if there is spinach in Column J and 0 if not. How can I do that? Please advise. Thank you for your help!
The formula will return 1 if there is "orange" in column J.
=IF(COUNTIF(J:J,"orange") > 0,1,0)
Hope this is what you need.
Hi Alexander,
Thank you for your help but unfortunately the formula did not work. Just to clarify each row in J has continuous text such as Row 1 = apple;orange;bananas;vegetables(spinach,fenugreek,etc);acai berry
Row 2 = orange;bananas;vegetables(spinach,fenugreek,etc)
Row 3 = apple;orange;bananas
and so on
Also there is no space between the text and semi colon and following text
Please advise
Hello!
The formula I sent to you was created based on the description you provided in your first request.
However, as far as I can see from your second comment, your task is now different from the original one. Hence, the formula fails to work.
I also assume that the phrase "each row in J has continuous text" actually means "every cell in column J contains text."
Try the following formula:
=IF(IFERROR(SEARCH("orange",J2,1),0)>0,1,0)
After that you can copy this formula down along the column.
Hi,
Let say i have text "export" in C2 and C20 . Can I use formula =if(C2=C20,countifxxx,0) ?
So if I want to change the text 'export' I don't need change every formula. is that possible?
thanks to advice.
Hello!
In your IF formula, it is important that C2 = C20. What will be recorded in these cells does not matter. You can use nested functions as a TRUE or FALSE condition, including COUNTIF.
There are payroll list for June 2020
1) Fill June Payoff with this rule: if monthly Wage is less then 20 000, then pay 20 000. In other case pay just Wage itself.
What value should put in Value _if_ false
Hello Christina,
Please try the following formula:
=IF(A2<20000,20000,A2)
Hi Alexander!
Thank you for a great and helpful site!! I have three cells (B13, C13, and D13) that can contain numbers (usually nothing or somewhere between 1 to 10). If one (or more) of these three cells contain a number (if none of them are empty), I would like to extract a name that is written in cell C7 - and with the sum of the three cells (B13, C13 and, D13) listed with an "x" before the name. Example: B13 [1], C13 [empty], D13 [5], C7 [Ronni] - would generate: "6x Ronni". Is this possible to make? Thank you very much for your help!!
Sorry, let me correct my question:
I have three cells (B13, C13, and D13) that can contain numbers (usually nothing or somewhere between 1 to 10). IF one (or more) of these three cells contains a number, I would like to extract a name that is written in cell C7 - and with the sum of the three cells (B13, C13 and, D13) listed with an "x" before the name. Example: B13 [1], C13 [empty], D13 [5], C7 [Ronni] - would generate: "6x Ronni".
Hello Ronni!
Please use the following formula
=IF(OR(B13<>"",C13<>"",D13<>""),CONCATENATE(B13+C13+D13,"x ",C7),"")
I hope this will help, otherwise please do not hesitate to contact me anytime.
Thank you very much, Alexander! It works perfectly! Now, I'm trying to pull different cells with the formula that you helped me with, to list the names into the same cell/sentence, though I can't figure out why I can't make that work. Your single formula works.
=IF(OR(B14"";C14"";D14"");CONCATENATE(B14+C14+D14;"x ";C7);
=IF(OR(B35"";C35"";D35"");CONCATENATE(B35+C35+D35;"x ";C28);
=IF(OR(B56"";C56"";D56"");CONCATENATE(B56+C56+D56;"x ";C49);
=IF(OR(B77"";C77"";D77"");CONCATENATE(B77+C77+D77;"x ";C70);
=IF(OR(B98"";C98"";D98"");CONCATENATE(B98+C98+D98;"x ";C91);
=IF(OR(B119"";C119"";D119"");CONCATENATE(B119+C119+D119;"x ";C112);
=IF(OR(B140"";C140"";D140"");CONCATENATE(B140+C140+D140;"x ";C133);
=IF(OR(B161"";C161"";D161"");CONCATENATE(B161+C161+D161;"x ";C154);
=IF(OR(B182"";C182"";D182"");CONCATENATE(B182+C182+D182;"x ";C185);
=IF(OR(B203"";C203"";D203"");CONCATENATE(B203+C203+D203;"x ";C196);
=IF(OR(B224"";C224"";D224"");CONCATENATE(B224+C224+D224;"x ";C197);
=IF(OR(B245"";C245"";D245"");CONCATENATE(B245+C245+D245;"x ";C238);
=IF(OR(B266"";C266"";D266"");CONCATENATE(B266+C266+D266;"x ";C259);
=IF(OR(B287"";C287"";D287"");CONCATENATE(B287+C287+D287;"x ";C280);
=IF(OR(B308"";C308"";D308"");CONCATENATE(B308+C308+D308;"x ";C301);
=IF(OR(B329"";C329"";D329"");CONCATENATE(B329+C329+D329;"x ";C302);
=IF(OR(B350"";C350"";D350"");CONCATENATE(B350+C350+D350;"x ";C343);
=IF(OR(B371"";C371"";D371"");CONCATENATE(B371+C371+D371;"x ";C364);
=IF(OR(B392"";C392"";D392"");CONCATENATE(B392+C392+D392;"x ";C385);
=IF(OR(B413"";C413"";D413"");CONCATENATE(B413+C413+D413;"x ";C406);
=IF(OR(B434"";C434"";D434"");CONCATENATE(B434+C434+D434;"x ";C427);
=IF(OR(B455"";C455"";D455"");CONCATENATE(B455+C455+D455;"x ";C448);
=IF(OR(B476"";C476"";D476"");CONCATENATE(B476+C476+D476;"x ";C469);
=IF(OR(B497"";C497"";D497"");CONCATENATE(B497+C497+D497;"x ";C490);
=IF(OR(B518"";C518"";D518"");CONCATENATE(B518+C518+D518;"x ";C511);
=IF(OR(B539"";C539"";D539"");CONCATENATE(B539+C539+D539;"x ";C532);
=IF(OR(B560"";C560"";D560"");CONCATENATE(B570+C570+D560;"x ";C553);
=IF(OR(B581"";C581"";D581"");CONCATENATE(B581+C581+D581;"x ";C574);
=IF(OR(B602"";C602"";D602"");CONCATENATE(B602+C602+D602;"x ";C595);
=IF(OR(B623"";C623"";D623"");CONCATENATE(B623+C623+D623;"x ";C616);
;""))))))))))))))))))))))))))))))
Ideally, I'd also try to separate the strings with a comma and space, so it'd generate 5x Ronni, 2x Alexander, 1x Pedro - though trying to take small babysteps here, haha.
Once again, thank you for taking your time to help!
If A+ then "Outstanding"
If A then "Excellent"
If B+ then "Very Good"
If B then "Good"
If C+ then "Satisfactory"
If C then "Acceptable"
If D+ then "Partially Acceptable"
If D then "Insufficient"
If E then "Very Insufficient"
For this condition I used "=IF(N7, IF(N7="A+", "Outstanding", IF(N7="A", "Excellent", IF(N7="B+", "Very Good", IF(N7="B", "Good", IF(N7="C+", "Satisfactory", IF(N7="C", "Acceptable", IF(N7="D+", "Partially Acceptable", IF(N7="D", "Insufficient", "Very Insufficient")))))))))" but it show "VALUE!".
Pls Help me
Hello!
If I understand your task correctly, the following formulas should work for you
=IF(N7="A+","Outstanding",IF(N7="A","Excellent", IF(N7="B+","Very Good",IF(N7="B","Good", IF(N7="C+","Satisfactory",IF(N7="C","Acceptable",IF(N7="D+","Partially Acceptable", IF(N7="D","Insufficient","Very Insufficient"))))))))
I hope it’ll be helpful.
=IF(R3="CLower",V3*100%)
How can I make the above formula repeatedly and give me different relevant answers without false or true
Hello James!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find, what problem or error occurred. Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you. Thank you.
Would it be possible to use an IF statement, to say if a cell is still empty after a date has passed the "True" would be "OK" and "False" would be "Late"?
Hello Doug!
If I understand your task correctly, the approximately this formula should work for you:
=IF(AND(B2 > A2,C2=""),"OK","Late")
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi,
could you please help.
I am trying to find a way to do this using an IF statement that would do the following: IF(A=B,C,do nothing), in other words if the condition A=B, is true, put the value C in the cell, else if the condition fails, leave the old value in the cell. There is a way to do this in Excel but I haven't been able to find. Instead I have to manually open each report sheet and do a copy and paste from where the report I receive.
Hello Bewar!
If a value is already written in the cell, then it is no longer possible to write the formula into it. The Excel function can’t change values in other cells, it returns a value only in a cell where it is written. You'd better use VBA to solve your task.
Hi,
what a good and clear explanations on the website, credits to the maker. however i am not an excel expert and still cant figure out how to move on with what i want
i have 2 check boxes 1 in H4 (with comment 12hrs) and 1 in I4 (with comment 24hrs)
now i want in the mergedbox below H/I 5 to appear a text when checking one of the boxes
if box H4 is checked i want to see 1 x operator
if box I4 is checked i want to see 2 x operator
every time i try to make an if formula excel gives an error that i start a formula and i need to put an ' before the text. can you please help me :)
thanks in advance,
regards kasper,
Hello Kasper!
If I understand your task correctly, the following formula should work for you:
=IF(H5=TRUE,1*H9,IF(I5=TRUE,H9*2,H9))
I don’t understand what “operator” is, so I replaced it with H9.
Hope this is what you need.
unfortunately its not working, 1x operator is just the text I want to show in cell H5
so like they only need one person for 12 hours work or 2 persons for 24 hours of work
I’m sorry but your task is not entirely clear to me.You did not explain your problem in detail.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you. Thank you.
Hi, sorry my story is not clear.
in short i have 2 check boxes and i want to show a text in an other cell when checking the check box 1 and if i checking check box 2 i want to show an other text in a different cell
regards kasper
Hi,
Good morning to all of you.
Please suggest me a formula.
=if(A1>=10,"Same Value of A1", if(A1<10, "Please Put One Zero Before Value of A1"))
Hello Praveen!
Unfortunately, you did not write what result you wanted to receive. Perhaps your formula should be written as follows:
=IF(G2> = 0.5 * C2, "APPROVE", "DISAPPROVE")
Hope this is what you need.
Hi, I've been reading your article and i must say it's outstanding. However though it was useful in some areas I still found myself stuck.
I've been trying to insert an if function
=If(G2>=0.5,C2,"APPROVE", "DISAPPROVE")
But its not working
Any Help is appreciated
Hello Cresia!
Unfortunately, you did not write what result you wanted to receive. Perhaps your formula should be written as follows:
=IF(G2> = 0.5 * C2, ”APPROVE”, “DISAPPROVE”)
I hope my advice will help you solve your task.
Thanks for the article.
I need help with writing out a formula that says, if column B = yes and column C = yes, then D should say True.
So far I tried:
=IF(B2="YES",TRUE(IF(C2="YES",TRUE),False))
Looking forward to hearing from you.
Rgs
The formula below will do the trick for you
=IF(AND(B1="Yes",C1="Yes"),TRUE,"")
Write in cell D1.
I recommend that you study this instruction about using AND and OR with the IF function.
Hi
I would like to return a value to be 1 if the division of the two cell equals or greater than 1 and .5 if it's less than 1
=if(c5/d5>="1","1",".5")
I inputted the formula above but it's not showing the proper value..
Hope it makes sense. Much appreciated, ty!!
Hello Priscilla!
If I understand your task correctly, the following formula should work for you:
=IF(C5/D5 >= 1,1,0.5)
I hope this will help
i have "NEFT/BKIDN20137329397/GCHZ0000M12104/ " in one worksheet and "BKIDN20137329397" in other workbook with some values. how to use if formula to bring these values in first worksheet.
Hello
I am struggling with an IF formula, hopefully i have explained it clear enought.
I want to return a value to cell V1 (the cell i am entering the formal into), if the value of cell U1 is greater than 0.1. The value i want to return is in cell T1, if the value is less than 0.1, i want to return a value of 0.
Any help would be much appreciated
Thank-you
Hello Sarah!
If I understand your task correctly, the following formula should work for you:
=IF(U1 > 0.1,T1,0)
I hope this will help
Hello Mathew
How can I delete a group of numbers that have same last digit from a list.
For eg: 10, 22, 31, 32, 35, 38, 40, 42, 44, 50, 51, 52, 62, 63
From this list numbers have last digit '2' are to be deleted. 22, 32, 42, 52 and 62
I appreciate any help.
Thank you.
Hello,
I am struggling with my nested IF formula. I am trying to return a "Y" or "N" if the given date meets certain requirements but sometimes strings of text can be found in the cell. If the string of text matches I would like it to return "N" or "Y" based off the requirements. Any help would be greatly appreciated.
=IF(EDATE(A5,12)<TODAY(),"N",IF(A5TODAY()+30,OVERDUE,IF(SEARCH("OVERDUE",A5),"N","Y"))))
Hello Matthew!
If I understand your task correctly, the following formula should work for you:
=IF(EDATE(A5,12)
Hello,
I have some dates in column K that I periodically add to or update, also some blanks that don't have dates added yet. I would like a formula for column L that gives dates 6 months in the future if there is a date in column K. However, if there is no date (blank cell) in column K, I would like the corresponding L cell to remain blank until a date in inputted into the K cell. Hope that makes sense! I appreciate any help.
Hello Teresa!
If I understand your task correctly, the following formula should work for you:
=IF(K1 <> "",EDATE(K1,6),"")
After that you can copy this formula down along the column.
Hope this is what you need.
I cant find what the problem is with this simple thing
=IF(BASE!MONTH=ENGINE!B1,"yes","No"
Hello Herman!
You did not indicate exactly which error occurs in your formula. However, MONTH is a function and cannot be a link. Therefore, BASE! MONTH does not make sense and is a mistake.
The formula lacks the brackets at the end.
If you give more complete information, perhaps I can still suggest something else.
I have a row of cells which have values in for lab results - I can't figure out a formula to work out a minimum value where values are either numbers or come as say <0.05 etc. i.e where they are less than the laboratories limit of detection (<LOD). I want the minimum number so i want it to register that <0.05 is less than 0.06 either through the presence of a less than symbol or any other way. I tried to play around with any cell being greater than 0 calculate a minimum and for where cells do not to populate as"<LOD". i.e. 1.9 , < 0.05, 0.29 would return a minimum of "<LOD". 1.9, 0.06, 0.29 would return a minimum of 0.06 and < 0.05 < 0.05 < 0.05 would return a minimum of "<LOD". Any help would be greatly appreciated - I can't find any examples where you have an if statement followed by a function if the statement is true, and to present a text value if not ("<LOD").
Hello Nic!
If I understand your task correctly, the following formula should work for you:
=IF(NOT(ISERROR(MATCH("<*",A7:A15,0)>0))," < LOD",MIN(A7:A15))
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi Alexander,
Thank you for your time - this seemed to work perfectly. Is there a way to do the same for the max, i.e highest number or <LOD if all are less than detection. I've tried playing around with the formula to try for max but can't get it to work for all cases. Please could you assist. Thanks again.
Hello Nic!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find. It’ll help me understand it better and find a solution for you. Thank you.
Hi Alexander.
So I have two columns in the spread sheet, one which calculates the minimum concentration from all the values from the lab results, which now works using your formula to pick the lowest concentration - <LOD (< limit of detection) or the lowest number if above that. The second column I need your assistance with is to work out the maximum value for all the cells in the row, as before some have < 0.05 for example, if all the concentrations are above this that's fine but it doesn't populate an answer for where all are <LOD. And the maximum in that case would be <LOD. Hope that clarifies things?
Hello Nic!
If I understand your task correctly, the following formula should work for you:
=MAX(--(SUBSTITUTE(A7:A10,"<",""))) Hope this is what you need.
I am having trouble with this If Formula. =IF(K3/31*(X3-H3+1)+M3 >200, "$50"), 200, "$50)
3.33 X 24 days = $79.92, M2 =150 (150 + $79.92 is more than $200 so I need the return to be $50. If less than $200 I need the total of (K2/31)*(X2-H2+1).
ANY help would be greatly appreciated. Please and thanks
Hello Dusty!
Your explanations are not very clear, but I can assume that something like this would suit you
=IF(K3/31*(X3-H3+1)+M3 > 200, "$50", (K2/31)*(X2-H2+1))
If I did not guess, then explain in more detail and accurately your problem.
I have a row, the 'amount' row, containing numerical figures from about 100 to about 1000000. I need a formula that will put corresponding figures in another cell. For example if the figures In the 'amount' row are greater than 100 and less than 5200, 100 should go to the cells beside the "amount" row, which I'll call the 'charge' row. And if the cells contains figures greater than 5,200 and less than 10300, then 200 should be in the 'charge' row, so that at the end, I can calculate the total charge for every single amount figure.
Hello!
I recommend that you study the article on our blog about IF functions with several conditions.
Hope this is what you need.
Hello,
Can you please assist me to create formula for following scenario
When I put patient's name in a cell, patient's UHID unique number should reflect automatically or vice versa
Thanks
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? Thank you!
I am looking for a help finding a formula
If cell A1 is a negative number it will turn to a positive number and if cell A1 is a positive number it will turn to a zero.
Hello Vincent!
If a number is written in the cell, Excel can only change it using VBA. An Excel formula can only change the value of the cell in which it is written. But if a number is written in the cell, then you will not be able to write the formula into it.
The formula in cell B1 might look like this:
=IF(A1 < 0,-A1,0)
I hope it’ll be helpful.
I'm having trouble using the IF logic statement- here it is =IF(C2=7592.00,1251.80,0. What Im trying to say is if the value in C2 is (7592.00) if true input 1251.80, if false input 0.
C2 actually does not contain 7592.00. Its referencing and reading a value from another cell in a different sheet. ='DRP Implementation'!N127 Result is Im not getting the result I want 1251.80 if 7592.00 is present. Is it because C2 is a ref cell and not a discrete numerical value? How would you correct this?
Hello Larry!
First off, please check your Excel settings: Excel - File - Options - Advanced - Update links to other documents. Also, please go to Data->Edit Links and make sure the autoupdate for each link is enabled.
Check the automatic calculation in your Excel. Go to File -> Options -> Formulas -> Calculation Options and switch to Automatic option there.
Note! In this case, you'll need to hit Shift+F9 to recalculate the formulas in any workbook you're working with.
Hope it'll help, otherwise please do not hesitate to contact me back.
Hi! I am trying to create a complicated If Then statement and haven't had success. Could you help?
If the text in a cell says "Participant #1", then I want it to tell me the name which is found in cell C2. But if the text says "Participant #2" then I want it to tell the name in cell D2. And so on through to Participant #4. If there is no text then leave it blank.
=IF("Participant #1",E2, IF("Participant #2",F2, IF("Participant #3",G2, IF("Participant #4",H2,"")))
This is what I had, but is saying I cannot coerce my formula into a boolean equation... what on earth?
Thank you so much for help!
Hello Penny!
If I understand your task correctly, the following formula should work for you:
=IF(B1="Participant #1",F2, IF(B1="Participant #2",G2, IF(B1="Participant #3",H2, IF(B1="Participant #4",I2,""))))
Hope this is what you need.
I ended up having to use this sequence, which I got from an excel whiz that I happened to connect with through a friend:
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(K2, "Participant #1", $E2 & " " & $C2), "Participant #2", $F2 & " " & $C2), "Participant #3", $G2 & " " & $C2), "Participant #4", $H2 & " " & $C2)
K2 is the cell of the activity participants, E2 / F2, etc. are the Participant First Names, and C2 is the last name
Hi,
Wondering if someone can please help me with a formula?
If column G contains the text "Yes", then I want column I to generate a sequential number, starting at 001. If G contains "No", then no number is to be generated and the cell will remain blank, and the next sequential number (002) will appear the next time column G contains "Yes"
I understand the IF function, but am struggling with the numbering part.
So far I have =IF(G:G="Yes","*","")- I need to fill in the * part!
Thanks :)
Hello Amy!
Please try the following formula:
=IF(G1="Yes",COUNTIF($G$1:G1,"Yes"),"")
After that you can copy this formula down along the column.
Please go to Format Cells, choose Number -> Custom Format and set
00#
Or instead of the number in the cell, you can write text and not use custom format:
=IF(G1="Yes",TEXT(COUNTIF($G$1:G1,"Yes"),"00#"),"")
I hope this will help
Hi,
I am trying to write IF functions based on multiple criteria. I need a formula to demonstrate that IF cell V8 is a date that you put in, for example 20/04/20 and cell W8 is <= 16:00:00 (time), then cell Y8 can be either 20/04/20 or 21/04/20 (or whatever the next business day is) and cell Z8 can be equal to or less than 12:00:00 (time) the next business day, if true then pass, If false then fail.
Thanks
Hello Philip!
I’m sorry but your task is not entirely clear to me. I can only help you if you accurately describe all the conditions. For example, you wrote that cell Y8 can be either 20/04/20 or 21/04/20. So what date should it be there? Z8 may be equal to or less than 12:00:00 the next business day. Is it 10:00 a.m. or 11:00 a.m.? For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
hello,
I wanted to put a date in one cell then it will populate in other cell. for example if I put a date in A1, whatever I put in A1 should populate in A3, A5, and A7. If I put a date in A3 then it will populate in A1, A5, and A7. If I put a date in A5 then it will populate in A1, A3, and A7. If I put a date in A7 then it will populate in A1, A3, and A5. Hope you can help me with this. Thank you
Hello Winterstory!
Please note that a cell may contain either a value or a formula. Since it is unknown which of your cells should be filled with data, which should be auto-populated by the formula, your task can be accomplished with the help of VBA only.
good day sir, I would like to ask, if there's a formula that when I put "paid" automatically a blank cell will pop up where I can input the date. Thank you
DEAR SIR,
1. amount 15000 below amount fix 1800 amount 30 days but less days amount per day less
2. 15000 and above amount fix 12% amount
please share excel formula
Hello!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
I select a date from cell Q33 ( 04-May-2020), and in cell R33 add some duration to it from either P34, or Q34 and or R34 (Year, month and day respectively). In this case 0 years (P34), 0 months (Q34), 200 days (R34) which gives me 16-Nov-20 in R33. The date so arrived at in R33 should not be greater than year end date i.e, 31-Mar-21. If it exceeds it should return FALSE in R33, if not it should return the correct date.
I tried following formula, but it does not work. Please help.
=IF(DATE(YEAR(Q33)+P34,MONTH(Q33)+Q34,DAY(Q33)+R34)>(DATE(YEAR(Q33)+(Q33>DATE(YEAR(Q33),3,31)),3,31),"FALSE",(DATE(YEAR(Q33)+P34,MONTH(Q33)+Q34,DAY(Q33)+R34))
Thanks in anticipation.
Hello Mahesh!
The formula you wrote does not work. I don’t quite understand why you have the end of the year - March 31. May 4 plus 200 days is November 20, and not November 16, as you have.
I suggest using the formula
=IF(DATE(YEAR(Q33)+P34, MONTH(EDATE(Q33,Q34)),DAY(Q33))+R34 > R33,Q33,DATE(YEAR(Q33)+P34,MONTH(EDATE(Q33,Q34)),DAY(Q33))+R34)
where R33 is the end date of the year.
Hello Alexander!
This is used for calculating interest on investment starting and ending in same Fin. Year (FY).
We have FY starting 1 April and ending 31 March e.g., 1-Apr-20 to 31-Mar-21.
Thus tenure can be max 1 year or less than 12 months or less than 365 days or in months and days.
Starting date (Q33) is always =TODAY() and cell is locked, but end date (R33) can not be more than 31-March of FY. Thus if tenure input (P34 Y, Q34 M, R34 D) given is such that end date goes beyond 31-March cell (R33) must return "FALSE".
First part of formula has to add tenure to start date, > (THEN) part of formula has to find FY end date using start date, and (else) part has to either give end date or if more than FY end date return FALSE.
Tried your suggestion, but it seeks >#REF! as follows: =IF(DATE(YEAR(Q33)+P34, MONTH(EDATE(Q33,Q34)),DAY(Q33))+R34>#REF!,Q33,DATE(YEAR(Q33)+P34,MONTH(EDATE(Q33,Q34)),DAY(Q33))+R34). This is because formula is being built in cell R33 so it cannot have input >R33
Kindly suggest.
Thanks.
Hello Mahesh!
I copied the formula from a blog in Excel and made sure that it works. Perhaps the error #REF! caused by incorrect copying. To make the formula fit your needs, use
=IF((EDATE(Q33,Q34+P34*12)+R34) > DATE(2021,3,31),FALSE,EDATE(Q33,Q34+P34*12)+R34)
Hello Alexander.
This formula works.
But, I would request you to help make year change automatic i.e., there should be no need to change (2021,3,31) with every FY change in >DATE(2021,3,31) e.g. if date next year is 09-May-2021 it should become >DATE(2022,3,31). Please suggest replacement of Date(2021,3,31) with a formula to achieve it.
Thanks.
Good day,
If a cell has no amount - in need to make it zero.
I use to use this formula and now it is not working:
=if(d4"",0,D4)
Hello Christa,
Please try the following formula:
=if(D4="",0,D4)
I hope it’ll be helpful.
Hi, I am struggling to set the formula for the following:
Column B needs to read May if the value in column C is between May 1 and May 31, 2020.
Hello Candice!
Please try the following formula:
=VLOOKUP(MONTH(C1), {1,"January";2,"February";3,"March";4,"April";5,"May";6, "June";7,"July";8,"August";9,"September";10,"October";11, "November";12,"December"}, 2,0)
I hope it’ll be helpful.
Hi,
Similar Question with the dates. I have a source data and I want to get the dates based on cut-off.
1. Row 1 . May 23 - June 20, 2019. Payments made was June 21 (Column C). I would like my Column D to read July.
2. Row 2. April 23 - May 22, 2020. Payments made was April 25 (Column C). I would like my Column D to read May.
Can I use "IFS Function" for this? Thank you in advance.
Hello Philip!
I cannot recommend you which function to use - IF or IFS, since you did not say anything about the conditions under which the formula will determine the month in column D. If there is one condition, then you can use IF. But this is only an assumption. No information needed to answer.
Hi Candice,
Assuming column C contains dates, you can extract month to column B with this simple formula:
=TEXT(C1, "mmmm")
Hi,
I am trying to do an IF then formula but having trouble coming up with it. I have 4 different columns that I mark with an X dependent on which patient meets which column. However I want an additional column (if,then column) that will calculate if I have put in X in any of the 4 columns in that row and to mark it by yes if there is an X or no if there is not. Can you assist with this?? Thank you!
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(COUNTIF(A1:D1,"X") > 0,"X","")
I hope it’ll be helpful.
Hi,
I am using a formula like "=IF(D49>=35,"PASS", IF(E49>=35,"PASS", IF(F49>=35,"PASS", IF(G49>=35,"PASS", IF(H49>=35,"PASS", "FAIL")))))"
In this any one cell 35 also its coming "PASS". Please get me some solution in this and resolve with an appropriate formula.
Hello MURALI!
I’m sorry but your task is not entirely clear to me. What result do you want to get? Could you please describe it in more detail? Thank you!
Hi I am trying to create a formula that allows me to quickly match the same data that appears in 2 columns
so if text in column A has a match with text in column b no matter what row it is displayed in, display OK can you please help?
Hello Belinda!
You can learn more about column comparison in Excel in this article on our blog.
Hope you’ll find this information helpful.
Hi, i am so terrible with code, a little help with the following would be much appreciated.
how do i write an if statement for, If Column 'N' has text 'Not completed' then Column 'O' must be a mandatory cell to fill(text required)
I need an IF statement that determines the unfilled up cell.
ex.
if a number of cells like 05,P5,Q5,R5,S5,T5,U5,V5,W5 which belong to step 1, step 2 and soon are blank I need to specify which step is missing.
Hello!
If I understand your task correctly, please try the following formula:
=SORT(IF($O$5:$W$5="", COLUMN($O$5:$W$5)-15,""), ,1,TRUE)
I hope this will help, otherwise please do not hesitate to contact me anytime.
my question is that,
my formula is accurate, but i want that if in my selected cell no any data in formula cell show that " - " character,
mostly when your selected cell not have data , your formula cell show that " #value! "
I want that show as like " - ", with out effected the formula,
please help me in this task.
Hello!
You can learn more about about error handling in formulas in Excel in this article on our blog.
Hope you’ll find this information helpful.
I am trying to use =IF... If the text in C48 equals a picklist (five different products) I would like cell E48 to equal the dollar value associated with the picklist name.
Hello Paul-Simon!
I think you better use the VLOOKUP function in cell E48. I recommend this article on our blog.
Thanks
Hi I would like to create a formula that gives out 100% if "Text1" or "Text2" but a variable percentage that I put in on my own if "Text3" or "Text4". I have at this point reached this formula which does not seem to work: = IF(OR(A3="Text1";"Text2";);100%;"")
Excel complains and says that my conditions for OR formula needs to be a number, but my conditions are in text so I dont know what to do, so maybe another forumla similiar to OR but you can use text. Maybe some sort of If and Else formula needs to be used here but I dont know how.
Hello Edgar!
Please try the following formula:
= IF(OR(A3="Text1",A3="Text2"),100%,"")
I hope it’ll be helpful.
If you are trying to match two different spreadsheet, one spreadsheet has a number that matches the other spreadsheet but you need to enter the code number in another cell on the other sheet can you write a formula for that ?
Hello Tom!
I recommend reading this article https://www.ablebits.com/office-addins-blog/compare-two-excel-files-sheets/
Your description of the problem is very short, so it's hard to advise you something. Which value do you want to insert into a cell on another sheet?
For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
Hi- am I able to get a cell to say “1 week” if a different cell says “Extreme”?
If so can multiple choices and responses then be made to the same cell?
Hello Nicola!
I recommend that you study the article above, as well as the article on our blog about the IF function with multiple AND/OR conditions
Hi Svetlana
Please if I have a formula like this:G1=A1&B1&C1&D1&E1&F1 the value of the cells are in words not numbers.the formula actually gave me the my desired results but how can I give a demacation like " , " in between each words. Secondly, how can I make the results to centralized in the cell.
Thanks.
Hello Enity!
If I understand your task correctly, the following formula should work for you:
=A1&" "&B1&" "&C1&" "&D1&" "&E1&" "&F1
or
=CONCATENATE(A1,"",B1,"",C1,"",D1,"",E1,"",F1)
To center the text, use the menu Alignment - Center.
I hope it’ll be helpful.
How to I extract text before the Qty ? suppose I just want to extract "bought" from 1st line
Bought 300 CODX @ 10.3
Sold 300 CODX @ 10.5
Sold Short 300 TWTR @ 24.7
Bought to Cover 300 TWTR @ 24.857
Hello Shahid!
Please try the following formula:
=LEFT(A1,FIND(" ",A1,1)-1)
I hope it’ll be helpful.
I am in if assistance. This is what I am attempting to do. I need to calculate the total amount (dollars) that meet delinquency days. For example, Column A is the amount, Column B is the days late, and return the total in other cells based of a time span. "0-29" in Cell A7, "30-59" in Cell A8, and "60-89" in cell A9
Hello Thad!
Please try the following formula:
=SUMIFS(A1:A15,B1:B15,">0",B1:B15,"<30")
=SUMIFS(A1:A15,B1:B15,">=30",B1:B15,"<=59")
=SUMIFS(A1:A15,B1:B15,">=60",B1:B15,"<=89")
I hope it’ll be helpful.
I need a simple formula, but cannot seem to figure out the answer. I need an IF statement. If there is text in either C8 or C9 greater than 0, then ((c8+c9)/c5) then show -. So far I have =IF(C8>0,((C8+C9)/C5),"-") which works if I have text in c8, but I cannot figure out how to include c9. I may not always have text in C8 and still need the percentage to calculate if c9 has text too, Thanks
Hello Gabriel!
If I got you right, the formula below will help you with your task:
=IF(OR(C8>0,C9>0),(C8+C9)/C5,0)
Hi,
If you have four categories like some, little, none and regular and you want them to prioritise them then how could you do that using IF function or VLOOKUP function?
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you. Thank you.