by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4763 comments
hello,ma'am I have Excel sheet of Indian population and I have to classified accordingly by Tier -1 to Tier -4 so how can I put condition in this sheet.
Tier-1 =10000000 population
so on till tier -4
Thank you.
Give me a formula for making a result sheet in which i want the result
there is four NOS(Subject)
if student's marks in all NOS is 0 Then Absent.
if student's marks >=70 in all NOS Then Pass.
if student Passs a NOS and fail in rest of the three NOS Then NOS PASS.
if student's marks in all NOS is <70 Then Fail
Hi, i cannot seem to get this formula down.
Use an IF function in cell J18 to calculate the commission earned for beverages for order 1. The beverage commission is 10% of the total sale if the customer buys a beverage. If the beverage sale amount (cell D18) is greater than 0 the beverage commission equals the sales total (cell G18) multiplied by the beverage commission rate (cell G12). Otherwise the beverage commission is 0. Use appropriate relative and absolute cell references.
I am trying to create a formula that if text = (specific text) then add 1, and the total number of (specific text) fields there are in that column.
I have a specific ticket type for an event in column F in this spreadsheet, and I am trying to create a formula at the bottom that will tell how many of each ticket type there is.
Hello Jeanette!
To count the number of cells with a "specific text" you can use the COUNTIF function. For example:
=COUNTIF(B1:B8,"specific text")
Hi Guys,
Please help on the following:-
Gross profit margin>=20% = 0.7%
Gross profit margin>=25% = 1%
Gross profit margin>=30% = 1.5%
Gross profit margin>=35% = 2.0%
Gross profit margin>=40% = 2.5%
Hello Theng!
You can enter the following formula: =IF(F1>=40,2.5,IF(F1>=35, 2, IF(F1>=30, 1.5, IF(F1>=25, 1, IF(F1>= 20, 0.7, 0)))))
F1 contains Gross profit margin.
I have a spread sheet that as A as the Roster, B as the Go or No Go, C as a number value between 1-40, and D as 4 classifications.
1-23=Unqual (NOGO)
24-29=Mark(GO)
30-35=SS (GO)
36-37=Ex(GO)
I want to make a formula that when i type in the number value in C, it will automatically fill in B and D with the info i need based on the table above all the way down the rows.
Hello, thanks for your time.
I'm building a spreadsheet in which I have a list of names, and need these names to represent a value. For instance, if cell AL5 states "COL", "TOR", or "BAL", it should be assigned a value of two, but if cell AL5 states "TEX", "BOS", "NYY", or "ARI", it should be assigned a value of 1. Please help put together a formula to do this; I've got the first part at =(IF((OR(AL5="TOR", AL5="BAL", AL5="COL")), "2"))
I have a spreadsheet in which I the if has 2 requirements to be correct, and if so then it will be this number, but if its below it needs to equal zero, and if it is above it equals a fixed number. How do I get it to have 2 options if false?
=IF(AND(F1>29999,F1<70001),(F1-30000)*0.02,40000*0.02)
the 40000*0.02 is if its greater than 70001 but if it is less than 29999 then it needs to be 0
any help?
Hello Chase!
You can use two nested IFs:
=IF(F1>29999,IF(F1<70001,(F1-30000)*0.02,40000*0.02),0)
Hey All
I would appreciate any guidance on the following formula please:
If column A =1 and column B = 2 return X otherwise return Y.
Many thanks
Alice
=If(A1=1,If(B1=2,"X","y"),"y")
Hello everybody!
That seems so simple but I can't do it :(
I would like to know the formula for this:
If any text is found in cells T23 U23 V23 or Z23 this same text should be copied to this cell where the formula goes (C23).
This text could be any of these four: Apple/Pears/Peaches/Grapes
Thank you so much
Hi Augusta,
What if 2 or more cells (T23, U23, V23, Z23) contain different texts? Which one should be copied to cell C23?
Hi Guys
I have this project wherein I want to check the ROWS and look for Installed or Blank and will input C or Complete on Column A, If it sees 1 just do nothing
A B C D
1 Installed Installed
2 1 1 1
3 Installed
Hi sanjay...
In this way, using the formula...
=VLOOKUP(C55,Sheet1!A:E,5,FALSE)
=IF(O14>"80""A",O14>"60""B",O14>"40""C")
I want to know how to check whether a value is repeated in a column.
e.g:
123
231
132
123.
for a column that is as large as A3:A500.
Thanks
I want to find out that if someone given a date and time, I should get a response block or empty. For the same I applied If and Datevalue formula but it is working only when I mentioned the excel column address, not on the range. Can you please: IF(AND(W4:W300=DATEVALUE("07/16/2016"),X4:X300=1),"BOOK","EMPTY")
Please suggest...
in if condition calculate the "n" number of times
For a Hotel Maintenance Log. I have a column for recording room numbers and want to apply a condition to a certain room number, so that front desk staff know what to do differently for this one apartment. I tried:
=IF(A2=1307, "call owner")
but no luck. Grateful for any ideas - thanks
No worries - I have solved it:
=IF(A2=1307,"CALL OWNER","")
This leaves the cell blank if it's not for 1307, so works perfectly.
Hi
I have a nested IF AND formula that looks at times [HH]:MM It works fine until I have time over 24hours. I have this section in my formula:
IF(AND(N2>=TIME(24,0,1),N2<=TIME(48,00,00)),"Between 24-48hrs")
It doesn't work though...any ideas??
Not to worry..I have solved it by converting time to decimals and working the > or < off those figures rather than time!
Criteria Cell1 and Cell2 having numbers which may be higher,lower or same.
What will be the formula to get in Cell3 as reply "Higher", "Lower" or "Same" any 1 will be answer.
=IF(AND(A1=A2),"SAME", IF(A1<A2,"LOWER","HIGHER"))
I have a score range to grade students A,(85-100) B, (75-84) C, (65-74) D, (50-64) & E (0-49).
How would I enter the values using the IF function so that when I drag down using the handle it automatically give grading. Please help.
Thanks.
I have two sheets,
1st sheet "A" column contains order no. in sequence and and "E" column contains Name of customer
in 2nd sheet if I put any order No. in "C" column "D" column should show respective customer name of particular order No. from sheet 1.
For eg.
in sheet 1
A22=2200 E22=Dettol Incorporation
if I put 2200 in sheet 2 in c55 than D55 should show as E22 in sheet 1 ie. Dettol Incorporation
Thanks
Dear Svetlana
i will put order no.in sheet 2 in sheet 2 in c column
than in d column should show company name of respective order No. from sheet 1
please help
thanks
got it, i found solution,
=VLOOKUP(C55,Sheet1!A1:E500,5,"FALSE")
thanks
In cell E8 I have write =IF(G8="W",0,1)+IF(G8="WF",0,1)+IF(G8="I",0,1) to got 0 in E8 when I write in G8 W WF or I otherwise 1. But I get 2 in cell E8 When I write W WF or I. Tell me the mistake why it comes 2 instead of 1?
Champs need ur help i am rookie with excel and cant fig out the following formulae to apply
Cell A2 = if Cell A1 is less than Cell B1 then Value should be cell A1 Minus cell B1 else if cell A1 is greater than cell B2 then value should be A1 Minus B2 ,,, and if the value of A1 is between B1 and B2 then should just say "ok"
Example A2 = where the answer will be
A1 = 3.3 B1 =2 B2 =3 this case A2 should give an answer as 0.3 and the cell should go red or any other colour,, please somebody help out
Dear Svetlana Cheusheva please reply waiting for the same, If you are busy it's okay take your time.
and if cant be done please drop a message it cant be done so that i can drop this file of mine
Have a good day
Hello Manish,
Assuming that the value in B2 is always greater than in B1, you can use this formula:
=IF(AND(A1>=B1,A1<=B2),"OK", IF(A1<B1,A1-B1, IF(A1>B2,A1-B2,"")))
To highlight A2 with color, select it and create a conditional formatting rule with this formula =ISNUMBER(A2)
Here are the detailed steps to create formula-based conditional formatting rules.
Dear Svetlana ,
Thank you it works awesome ,,but i dont get a negative answer as in the answer is right but without a negative sign
Example A2 = where the answer will be
A1 = -3.3 B1 =2 B2 =3 this case A2 should give an answer as ( -0.3)
Rest all is fine thank you for the help your ( Excel-lency)
Dear Manish,
In your original post, the first condition to check was as follows:
"if Cell A1 is less than Cell B1 then Value should be cell A1 Minus cell B1".
And it is exactly what the formula does: A1 (-3.3) is less than B1 (2), so the formula returns -5.3 (-3.3-2)
If you expect a different result, then please list all of the conditions in the order they should be checked in the formula. (Nested IF's check conditions in the order they appear in a formula; if the first condition is met, other conditions are not checked).
Please i have numbers from 1 to 10 representing several texts in a collumn. i need a logic that can help me sort the out once without writing the logic one cell to another.
Hello,
I am currently updating my company's Excel files. I wanted to add the day's date in a cell if a project is marked completed. ive' used the following formula: =IF(ISTEXT(U:U), NOW(), ("")). it worked but I am facing a problem. the projects that were marked completed had the date in the cells next to them but the dates keep changing everyday. can you please help me with telling me the right formula to add an unchanging date using IF function?
Thank you,
Maan
Reply
Hi, Kindly help me how to settle this ;
cell A1 is 55, and eveyday change its value
cell B1 is the Day
cell C1 is to copy the A1 at that day.
now the next day B2, A1 is 70 , so how can I automatically change the C1 value to 70 ??
Thanks in Advanced
Hello,
Can you tell me, how cell can refer to a range with equal sign, in such a formula (which is working):
"If(B1=C1:C300;E1:E300;0)
Thank you in advance!
Hi, I need a formula for one cell:
IF A2 has a value between 101-122, then text "below average"
IF A2 has a value between 123-144, then text "average"
IF A2 has a value between 145-200, then text "above average"
IF A2 has a value between 201-250, then text "not acceptable"
Thank you.
Hi Maria,
You can use this formula:
=IF(A2>200,"not acceptable", IF(A2>144,"above average", IF(A2>122,"average", IF(A2>100,"below average",""))))
ok I am trying to create a score chart. Where the same cell returns a different value based on what is in that cell. if someone keys a 0 it returns a 5, if a 1 or 2 it returns a 4, if a 3 or 4 it returns a 3. something along the lines of
=if(Q5=0,5),if(Q5=1,4),if(Q5=2,4)...
thank you
oh I got it...
=IF(Q38=0,5,IF(Q38=1,4,IF(Q38=2,4,IF(Q38=3,3,IF(Q38=4,3,IF(Q38=5,2,IF(Q38=6,2,IF(Q38>=7,1,""))))))))
Hi,
I wanted use the formula with more than one logical test. what should I do. how to do so.
Let's say. If,a1="Thursday","OFF","Working:)
Apart from Thursday I also wanted to use Friday. What can I use to do so.
Hi Tanveer,
If you want to display "OFF" for Thursday and Friday, you can use the following formula:
=IF(OR(A1="Thursday",A1="Friday"), "OFF", "Working")
If you are looking for something different, please clarify.
How to pay you thanks,
you were awesome.
Yes that is what I meant and it is working.
Thank you very much for your help.
Have a good one.
Hi,
Can you help me on below query.
I have have Holiday calendar till 2060 and i want to change weekend holiday to Monday (if holiday falls on either Saturday or sunday)
Question Answer should be
01-May-16 Sunday 02-May-16 Monday
23-Oct-16 Sunday 24-Oct-16 Monday
10-Dec-16 Saturday 12-Dec-16 Monday
Please solve the below problem:
Column A1 to A4 contains: 3 or 2a or 2b or 1.
Formula: Column B1 to B4 require: IF(A1=3,100, IF(A1=2a,50, IF(A1=2b,25, IF(A1=1,0)))
Hello Nandu,
Your formula is correct except that text strings like "2a" should be enclosed in double quotes:
=IF(A1=3, 100, IF(A1="2a", 50, IF(A1="2b", 25, IF(A1=1, 0, ""))))
how can change 1 is (1st Page),3 is (3rd Page),5 is (5th Page),8,12,16,20,24 is (Last Page),2,4,6 is (others Page)
Hi,
Please for eg, A2 = A3 result should = to True, but it should automatically be colour coded as well, if possible how so?
please,
=IF(and($M$2,$N$2="All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5)
,if(and($N$2="All",KPI!$M$2"All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5,Data!AH:AH,$M$2)
,if(and($N$2"All",KPI!$M$2="All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5,Data!Ai:Ai,$n$2)
,IF(and($M$2,$N$2"All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5,Data!AH:AH,$M$2,Data!Ai:Ai,$n$2)
join both of them
IF($N$2="All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5),(SUMIFS(Data!AF:AF,Data!E:E,KPI!C5,Data!AI:AI,$N$2)))
Hi,
please I have 2 drop list one for the for Year in cell (M2)(all, 2013-2016),
=IF($M$2="All",SUMIFS(Data!AF:AF,Data!E:E,KPI!C5),(SUMIFS(Data!AF:AF,Data!E:E,KPI!C5,Data!AH:AH,$M$2)))
I need to apply other one for Activity in Cell (N2) it
please reply to me to send you my file
Hi guys... can some one please help me out ... I m new to excel...
i have set of Time and i wanted to categorise them into each one hour...
for Example -
Time
X = 1:13 AM
X = 2:15 AM
X = 6:19 AM
X = 7:15 AM
if my X = 1:13 AM time is falling between range of 1:00 AM to 1:59 AM then the value should return the category as "1 AM to 1:59 AM" , if my X = 2:15 AM time is falling between range of 2:00 AM to 2:59 AM then the value should return the category as "2 AM to 2:59 AM" .........
Categories are below -
1 AM to 1:59 AM
2 AM to 2:59 AM
3 AM to 3:59 AM
4 AM to 4:59 AM
5 AM to 5:59 AM
6 AM to 6:59 AM
7 AM to 7:59 AM
8 AM to 8:59 AM
9 AM to 9:59 AM
10 AM to 10:59 AM
11 AM to 11:59 AM
12 AM to 12:59 AM
please help me to formulate the function
I want to know about one formula, the details are as below;
col A - Location
Col b - Salary
col c - ratings
col d - ?
in column d, I want a formula that some selected location will fall under A group and the percentage of increment given will be 7 and the rest will fall under B group and the percentage of increment given will be 5. Can you think of a formula for the above.
Hello I am trying to create a worksheet with employees names in column B (which I choose daily from a validation list) when I click on the names I want their internal rate to populate in column J and external rate to populate in column J automatically-I have these names & rates on a separate sheet and right now am using the drop down list to do it manually-there must be a better way... Can this be done?
Sorry I meant internal rate in column G and externalrate in column J
Hi, can someone help me with an IF formula as follows:
If Cell C17 contains "PASS", and Cell C30 contains "PASS", then PASS should be returned, if not, FAIL should be returned.
Hi May,
What you need is an If formula with nested AND like this:
=IF(AND(C17="PASS", C30="PASS"), "PASS", "FAIL")
How can get a formula to calculate the mark up on an item based on the category code. We have 3000 items and 40 categories. We have a master list on a separate worksheet for the categories with their markup. I want to markup the cost based on the category. For example:
Worksheet #1 Worksheet #2
Category Cost Sell Price Category Markup
SNA 10.00 BOT 1.5
CAP 15.00 SNA 1.8
CAP 1.6
I can use an IF formula, but I'm hoping there is something quicker as opposed to typing a 40 item nested IF formula. Thanks.
hi , I am trying to write a nested formula. the formula I am using is
=if(c4="jose","good",or(c4="jesus","better",""))
The problem that I am running into is, that it reads the first nested formula but it will not read the second. can you help me with this formula. or recommend another
Hi Jesse,
You don't need OR in nested IF's:
=IF(C4="jose", "good", IF(C4="jesus","better",""))
thanks
Hi,
I am using an IF statement to check if 2 cells match.
However where 1 cell is blank (not yet populated) it will reflect as "same"
Can I use isblank in combination to bring back a blank cell if both referenced cells aren't populated.
=IF(AC118"",(AC118=P118,"SAME","CHANGE"), "")
Hi!
Try this formula:
=IF(AND(AC118="", P118=""), "", IF(AC118=P118,"SAME","CHANGE"))
Hi,
Could somebody help me with this issue:
I'd would like a formula where this condition is met.
A1 B1 C1 D1
A2 B2 C2 D2
A3 B3 C3 D3
A4 B4 C4 D4
The formula for all cells in column A: if the cell below is empty return to the first cell in column D. So for example if cell A5 is empty I want the value of D1. But also A6 is empty so i want the value of D2. Can sb help me with this?
Thanks you in advance
Nicolas
i'M SORRY I meant using the today statement...
I need to create a if formula to populate an statement for this:
5/29/16 10:25 PM
I need to collect any data that if before today at 3:00 pm
any help is welcome,
Thanks !
=IF(N8:N19="Completed","Yes","No")
i have tried this to test list of cells which are updated thru a data validation list its not working please anyone can help.
The list of Data validation referes like this
Completed , in progress , on hold , new
these are the four validation can be selected now i want this above formula to work to tell me once are completed.
=IF(N8:N19="Completed","Yes","No")
i have tried this to test list of cells which are updated thru a data validation list its not working please anyone can help.
Formula below wont halve the figure as it should
result when c33 is 2 is 100%. When c33 is 0 the result is only changing to 95%
=IF(C33="0", R16/2, R16)
hi i need a follow for below.
= 90% 1%
>= 100% 1.30%
>= 110% 1.50%
>= 115% 1.75%
thank you