by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1645 comments
Hi,
I have a spreadsheet that contains information, I have two search criteria, then when they find a match they highlight the row.
What I need to do though is - when I put in two search parameters, I want the row to highlight in a different colour.
At present search one highlights in Green, the second blue.
Each column after M has a keyword on which I search, and I have upto column AB and down to 20000.
Hope that all makes sense.
Hi, I'm trying to conditional highlight a cell based on the text in another cell which I can do but I'm having trouble in a particular situation. The formula I'm using is =c6="roller" with green fill format. This works fine except when c6 has its own conditional highlight, which is to display with a red fill with a zero value. If I right roller in an empty cell with no formatting and direct the formula to that cell it works fine. Any help would be greatly appreciated. Thanks in advance.
Hello, I'm having a hard time getting my excel sheet to do what I want...
If any cell in column G contains "YES" then it turns green. That much I have.
Now, (if column G has YES) I want column P to highlight RED until it is filled, in which case I want it to go back to no formatting.
I want the red to prompt me to enter data there when I receive it.
Is there a simple way to do that?
Thank you!
Good afternoon
my problem is
i want to write in row (A1) 1000 and auto write Sunil in Row (B1) and
then again write if row (A1) 1400 then auto write Omji in Row (B1) thru conditional formatting
Thanks for the guidance.
Using your tip, I can conditionally format to color a column depending on whether the next cell to each cell is blank or not.
it helped in reducing my work.
I'm trying to create a conditional formatting rule, but nothing seems to be working, could you help.
I like to create attendance tracker sheet and almost completed but one condition format understand.
In Automated attendance sheet in one employee Cell Condition applied as R (Staff Resigned)then i want to be next all cell range format blank or RRRRRRR..
Hi,
I want to change the color of the cell depending upon the sum of the column.
For Example In the below salary column if I enter 10 the color should be green because the sum of column is less than 100.When I enter the next value 50 ,the color should be green since the sum(10+50) is less than 100,
When I enter 70 the colour of that cell should be red since the sum (10+50+70) has exceeded 100.
Salary
10
50
70
Please help me to find a solution.
Hi Svetlana! Thank you for your examples. I have one issue with my excel. Lets say I have Supply time (the old one) and new supply time. I made a conditional formating in a separated row like this new supply time -old supply time and if the result is positivi we have increase in a supply time if it is negative we have a decrease and if the result is 0 we donot have any changes. BUT i have an issue with the decreased supply Hi Svetlana! Thank you for your examples. I have one issue with my excel. Let’s say I have Supply time (the old one) and new supply time. I made a conditional formatting in a separated row like this new supply time -old supply time and if the result is positive we have increase in a supply time if it is negative we have a decrease and if the result is 0 we do not have any changes. BUT I have an issue with the decreased supply time, because I still have some cells that are not fellfield with the new supply time and in my new row it is showing that there is a decrease. What rule to create to highlight the cells that are still not fellfield?
After that i have to show some results like every week how may items I already fellfield with a supply time how many of them decreased or increased but how can I do this if I’m working with a filter. The function COUNTIF doesn’t work in this case.
Thank you in advanced!
I'm trying to highlight a cell only if it is a result of a formula. IF the cell is an entered value i don't want the cell formatted.
I want to highlight only the cells in a column that have values derived as a result of a formula. If the cell has a numerical value entered in the cell i want the cell to remain unformatted
one cell is highlighted with conditional formatting -the rule is if the date is in the next month it will be formatted & highlighted.Now i want to highlight the entire row on the basis of this rule applied on that specific cell.what is the procedure.
Might not be the right section for this, but seems the most likely.
I am constructing a costing spreadsheet with multiple criteria that will effect the cost of items I work with. What I would like is to have a drop down menu with various 'levels' of input, say 'Super Premium', 'Premium' and 'conventional'. I would then like to have that selection refer to and apply a different numerical value in a formula in another cell.
I know how to create basic drop down menu's, what I need help with is applying the different numerical values to my formula based on the selection.
Sorry mic-copied formulae I am using I have :
=AND($P13="<100",$D13<TODAY())
Hiya,
I wondered if anyone could assist ? I am trying to do some conditional formatting as per below :
IF values in P13 is less than 100% AND the date in Column D is Less than today - make the whole line red with black text. I am using the below formula and choosing the format but it just doesn't seem to do anything ! Confused !
=AND($P13"<100",$d13<TODAY())
Thanks in advance
G
Sorry mis-copied formulae I am using I have :
=AND($P13="<100",$D13<TODAY())
Hi there is there a way to have one cell state a specific text if another cell is below a certain number?
I have starting date in cell A5 and ending date in cell G5. I want all the dates between A5 and G5 including dates in cel A5 and G5 in some range.
Please get me the formula for the same.
Thank You !
HI i need a conditional format to state in a cell a certain value if it is within a range.
for example:
1 to 100, the cell should show A
101 to 200, the cell should show B
201 to 300, cell = C
and so on...
also,
i have this dilemma:
a cell should show "O" if a value is within +/- tolerance; or should show "Y" if the value is = to the maximum tolerance; or should show "X", if the value doesn't meet the tolerance
example:
tolerance is +/- 0.5
the cell should show "O" if value is any of the following: -0.4, -0.3, -0.2, -0.1, 0, 0.1, 0.2, 0.3, 0.4
or
the cell should show "Y" if teh value is exact to the tolerance, +0.5 or -0.5
or
the cell should show "X", if the value is less than -0.5, and greater than +0.5
any help is highly appreciated..thanks!
Hi,
I want to format a cell into three different colors based on condition provided to different cell, let's say if value in cell 7 it is red.
Kindly guide me.
I'd like to make the font in a cell change to white (or disappear) when the content in the cell next to it is also in white font. How do I go about doing this please?
Hello,
I am trying to apply conditional rule to highlight my dates ranging from monday-sunday to highlight current week, How can I apply this rule?
Hello,
I have a spread sheet that tracks vehicle hours. In column B is the vehicle hours which are updated weekly. In column G is the last service hours. Starting at row 2 I would like G2 to be green when B2 is equal to or greater than G2 and less than G2+499, would like G2 to be orange when B2 is greater than G2+500 but less than G2+999 and would like G2 to be red when B2 is greater than G2+1000.
Could you help me with the formular please as no mater what I try I can't seem to get it to work.
Thanks
Hello, Carl,
you need to create the rules for conditional formatting that would apply to G2 (G:G if for the column). Try the following rules:
For green:
=AND(B2=G2,B2<(G2+499)) For orange: =B2>(G2+500)
For red:
=B2>(G2+1000)
Hope this helps!
I have a spreadsheet for work, in which i record correspondence. I have a column for "days open" (C) and a column for whether the sender is VIP (G). The non VIP letters have a deadline of 15 days, VIP letters have 15 days. I want the days open cells to be highlighted when VIP correspondence goes over 5 days open, and non VIP goes over 15 days. I'm using =IF(G2="Yes", C2>5, C2>15), but for some reason it is highlighting all cells regardless of value. I also have a conditional formatting rule for any cell reading "Closed" but i don't imagine it affects this.
THANK FOR GIVING SUCH GOOD SERVICES I WANT TO FOLLOW BY USING MY EMAIL ACCOUNT
Hi, I want to use conditional formatting to highlight a cell a particular colour dependant on whether other cells are filled in.
To put into context, I use to spreadsheet as a checklist for traders:
Trader Name - Risk Assessment Received - Hygiene Certificate etc..
Then once I have checked the box to show I have received all the information I want the cell at the end of the row to turn green after all the cells in the range are shown to not be empty.
I have achieved this for one row using a method listed here. However, I have several rows I want this to apply to and if I copy/paste or drag down it doesn't apply to formatting to the specific row, it just bases it on the first row.
I hope this makes sense.
Hi, Dom,
Supposing your data ranges from A to H column, try this formula as a formatting rule:
=COUNTIF($A2:$H2,"")=0
where "=0" checks whether the cell is blank. Notice, that we use absolute references for columns and relative for rows (to apply the rule to the next rows of the same column). Also, keep in mind that the formatting rule may multiply itself, when you drag it to another cell. For more info: COUNTIF.
Is there a way to highlight 'A-F' if 'B' has specific text in it? To happen infinitely, not solely on one column. Database purposes.
To highlight 'A-F' according to the text in 'B' create a formatting rule. To do that, go to Home tab, Styles box, Conditional Formatting > New rule. Use a formula below there and apply the formatting to the range of columns that you wish to highlight
=$B1="ENTER_THE_TEXT_TO_LOOK_FOR"
This point of the topic will provide you with example pictures on how to create and edit the formatting.
If the value is more than 2000 or equal to 2000 write 2000. same as if the value is less than 20 or equal to 20 than write 0 in excle sheet.I need help please.
if the value is 2000 write 2000. I would like to work above condition in excle sheet(i am using excle 2010)
I'd like to make a To Do calendar with the Format
as a meaning of
08-09 From 8 to 9 but I got 08-sept as a result
09-10 From 9 to 10 but I got 09-Oct as a result
Please help
My question is: Can Excel automatically insert a column with information from one book into another. This would either push a column over to insert the data or put in the column at the end of the current data. So this would be on going adding a new column up to a total of approximately 20 columns. The other book would always copy over the same column. This may be some high level stuff. Thank you very much in advance for your help.
Kindest Regards,
Todd Haig
Hello, Todd,
the only way for Excel to do that automatically is with a help of VBA code. Try asking for it on MrExcel forum.
This is a very helpful article, Thank you.
I do have one question. I am trying to fill in a cell with text based on the text in another cell. For example if A1=Apple put Applesause in D5, but if A1=Orange then put Orangejuice in D5.
I am not the best with formula's or conditional formatting, and am hoping someone can help me out.
Thanks - Tia
Hello Tia,
place the following formula in D5:
=IF(A1="Apple","Applesause",IF(A1="Orange","Orangejuice",""))
Keep in mind, that if there's neither apple nor orange in A1, D5 will remain empty.
What a great article - Thanks!
I have solved a lot of my requirements from the information I have learned here. However I have one formatting problem that has got me stumped. I have a row of data that contains numbers in some cells and text in others. What I really want to be able to do is automatically highlight a cell if the number in it is larger that the previous number in that row bearing in mind that number might not be in the immediately previous cell. e.g A1 - 1000, B1 - 1000, C1 - 1100, D1 - 1100, E1 - "text", F1 - "text", G1 - 1200, H1 - 1200 In this example I would want C1 to be highlighted as well as G1. C1 because it is larger than B1 (the previous number in row and it is larger than it) and G1 because it is larger than D1, again the previous number in the row.
Hopefully that (a) make sense and (b) someone can put me out of my misery.
Thanks in advance - AJ.
Hi AJ,
I'm afraid it won't be possible, because you will need to construct a complicated array formula, and array formulas can't be used in conditional formatting.
hi i would like to know about the method to put color for the cell or cell content based on another cell value. Can you help me
This is a great article, and has really helped me out. I do have one question that I can't figure out though that I thought maybe someone could help me with. I have column D filled with project numbers, and column F with either "projected" of "revised". I'm trying to find a way to locate the duplicates in column D, and from there pick out the "projected" to hide (or highlight with white on white) since it is not valid after there is a revised.
I have come up with:
=AND($D1=$D2,$F2="projected")
though this highlights the "revised" for some reason, and also misses a number of duplicates in column D.
Any help would be GREATLY appreciated.
Thanks!
I am trying to format cells in a single column that are greater than a value for a single in the column. To describe better, I have a list of values in the column, all corresponding to people. I need to highlight those that out donated our Leader. So I can compare all the values in the column to a value of a single cell. So all cell values in the range/column will be compared to a single cell. I can't figure out how to have every value compare to the single cell. Below is what I have and I5 is the 'leader' value.
=$I2>I5
This doesn't work because as $I2 moves down the list, I5 turns to I6, etc.
Hello Stuart,
This happens because of relative references. To fix the cell you are comparing to, add dollar signs before the column as well as the row reference, i.e.:
=I2>$I$5
If you still have difficulties, please specify what range of cells you are comparing to I5.
Hi! I am trying to create a spreadsheet to keep track of when physical cards would expire. I want the spreadsheet to auto fill yellow when the physical will expire in 30 days and auto fill red when it will expire in 7 days. I have done this in the past but it has been a while and I can't seem to remember the formula.
Thanks!
Conditional formatting: How can we apply conditional formatting in a column based on data from another column.
Eg: I need to format rows in Column A based on data in the same row from Column B
If the row in column B has text "I win", Column A should be highlighted green. In the same way I should e able to apply for the whole column A
Thanks in advance
HI! I'M TRYING TO FORMAT A WORK SHEET WHERE EVERY VALUE ENTERED IN COLUMN SAY L, SHOULD PRECEDED BY THE 'TRUE' TEXT IN COLUMN M.
SO IF I ENTER ANY PERCENTAGE VALUE IN COLUMN L, I SHOULD GET THE VALUE TRUE IN THE CORRESPODING CELL IN COLUMN M. i tried data validation and conditional formatting,they both seem not to work
PLEASE HELP,IT'S an urgent request.
Thanks!
Hi Kamo,
You can use the IF function in column M that will check if the cell in column L is blank, e.g.:
=IF($L1<>"","TRUE","")
I hope this helps
I want to write an equation for a column in which each value depends on the value before it. EX: if my equation is y=X+1 and the first number in my column is 1 then the next number should be 2 and then the one after should be 3 and so on
Hello!
I have a question and i would really appreciate an answer on this one.
I have a cell (E7) which drops down and gives us 4 options. Next to that cell, i have a 52x18 table (F10:W61). The cells in this table show a particular value for each of the 4 options mentioned above. For instance:
If i select "Availability" in the first cell, the F10 shows me 90%, G15 shows me 60% and so on.
My objective is to set color ranges. I can achieve this for 1 set of values, by selecting "format only cells that contain", and inputing the range. The problem is, if i change the text value in E7, the rules stay the same, and i need the following rules.
If i select first option of E7:
from 0-75% -> Red
from 75-90% -> orange
from 90-100% -> Green
If i select second option of E7:
from 0-80% -> Red
from 80-95% -> Orange
from 95-100% -> green
and so on. The rest i can do by myself. Thank you so much!!
I'm not sure if you have answered something like this before but here goes... I have a cell that I want to highlight if the value on the next cell is not blank.
for example:
N2 has 3 but O2 is empty the conditional format will not do anything but if N2 has 3 and O2 is not blank the conditional format will highlight the whole row.
This is the current formula: =IF($N2=3,1,0). this highlights all rows if N2=3 regardless if O2 is empty.
hi
i want to do conditional formatting to avoid duplication of entries or highlight entries which are duplicate using multiple columns criteria.
e.g. i want to highlight column D with values in column A, B, C & D are repeated at the same time in the sheet somewhere else? Is it possible
17-Feb-15 20 1 5
17-Feb-15 16 2 4
17-Feb-15 20 2 3
17-Feb-15 20 1 5
Now row 1 and row 4 all the entries are same. How can i highlight with the same set of entries are getting repeated in the sheet?
If I want to change the colour of Column D based on the columns A/B/C having text of Y or N what is the best method. ie. YYY = Red NNN = Green, any other combination has amber?
Thanks in advance
Hi,
i want to know when i am writing a column name (problem details) and another column name(result) so need when i put result onle(pass)thst's time problem details column is atowmatic highlighted in green such as
Complaint Details Result
Hard Disk Damage Solved
Hard Disk Damage
before putting solved complaint details column is red color.
when i put solved in result column then complaint details column is turn into green color.
please need your immediate response.
I currently have a Conditional Formatting set up to color code the cell Green if DBSK is entered for the first time within a row. Although, if a second entry of DBSK is entered within the same row, I need that cell to turn Yellow and then if the same DBSK entry is made a 3rd time within the row, I need that cell to then turn red. What is the best way to go about coding this or conditional formatting it?
High im new to excel and i was wondering if it would be possible to get column k to be highlighted when a row has data but nothing is entered in the k column. then when an entry is made in column k the highlight would be removed.
for example lets say in row 5 i have in column A- NUMBER, column b- last name, column c- first name, column d- employee #,... and in column k is titled date approved.
so the premise would be that k would be blank until i entered a date and if that could be highlighted when blank so that it can stand out and the highlight removed once a date has been entered. if you can help that would be great
Hi, I am hoping that someone could help!
I am trying to colour format rows depending of the information of two columns.
Column E is limited to YES or NO
Column F are years
I want to add conditional formatting so:
= YES and under or equal 30 go green
= YES and over 30 go yellow
= NO and under or equal 30 to blue
I would appreciate any assistance you could offer.
Thanks so much!
Nuria
Hi Nuria,
You need to create a conditional formatting rule for each color using the AND function:
1) =AND($E2="YES",$F2<=30) for green cells
2) =AND($E2="YES",$F2>30) for yellow cells
3) =AND($E2="NO",$F2<=30) for blue cells
Hi Irina,
Is that possible to paste that resulted cell to another excel without any condition in new excel.
For Ex: Pasting the values to another excel.
Hi, I have dataset,as below, how can I write formulae which will output a Y into column B if there is a "Y" present in column A? Is it possible to extend this also for further similar conditions? Thanks
A B
1 XXZ1 N
2 XYX2 Y
3 ZSD3 N
Hi Aaron,
You can use the combination of ISNUMBER and SEARCH functions to look for specific text within your cells:
=IF(ISNUMBER(SEARCH("Y",$A1)),"Y","N")
Hi, I wanted to know if it was possible to highlight a number of cells based on the value to the left column. For example, I type in the value 1, and 1 cell to the right of that value is filled in green, I type in the value 7, and the next 7 cells to the right of that value are filled green. Is this possible?
I'm trying to do something that should be fairly easy, but I'm having trouble making it happen.
Simplified: I have dropdown lists in C3 (Where did we go?). And the distance from home to the place gone in E3. The options for the dropdown list are stored in I3-I33 (Names of locations) with an associated value in J3-J33 (Distance traveled).
What I would like is for E3-E36 to return the values in J3-J33 if the C3-C36 dropdown option is entered.
C3-C36= Dropdown List
E3-E36= Result from J3-J33
I3-I33= Dropdown List options
J3-J33= Distances for each option chosen
So, if I choose "Grand Canyon" from C3s drop down, and it is located in I8, the distance of 2000 miles is listed in J8. I would like that value to show up in E3.
I can make it work for one specific number but not for the entire list.
"=IF(C4=I3:I33,J3:J33)" only returns the correct answer if C4=I4. I need it to return the value in the J3-33 cells.
Thanks for any help,
-Rob
Hi Rob,
The easiest way to go would be using the VLOOKUP function in column E:
=VLOOKUP(C3,I3:J33,2,FALSE)
If will match the value from C3 to a value in column I and return the corresponding record from column J. Please see this tutorial to learn more about VLOOKUP.
What an awesome blog! great stuff here!
I am trying to find a solution to a conditional formatting using a formula issue (I THINK!)...
Please see image at: to see what I am hopeful of achieving.
Thx!
well - I tried to post a url in that...
trying again here without the brackets
sbonham.com/ganba/GymSheetMockup.jpg
Thank you very much for your kind words, Steve, and thank you for the screenshot.
I'm sorry, but there is no easy way to check several words that are in cell B3. One possible solution would be taking the key words into separate cells, selecting the range with comments, and creating a Conditional Formatting rule for each key word with the following type of formula:
=SEARCH($B$3,E6)
Here $B$3 is the cell with the key word and E6 is the first cell of your range with comments.
Hi
I want to format a series of cells 2*4 (represents 1 day)to green if the combined value is 0/blank.
=SUM($B$6:$C$9)=0 goes for the same cells =$B$6:$C$9 so far no problem. But how do i autofill this formua over a sheet with hundreds of cells working 2*4.. Is it even possible or do i nedd macro?
Thanks.
/fred
Hi Fred,
Could you describe your data structure in more detail? Do you want to sum values in range B6:C9 and then B10:C13, or are 2*4 groups arranged in a different way?
Thats correct, downwards would be B10:C13 an to the right D6:E9 and so on.. And if the sum of these 8 combined cells are 0/blank i want them all (ex. B6:C9) to be green, if the value is something else they should become white. All 8 of them. The formula above does this, but it wont autofill over the sheet like i want..
Thank you for the details, Fred,
Please select all your data and use the following formula for the Conditional Formatting rule:
=SUM(INDIRECT( ADDRESS((INT((ROW()-2)/4)*4+2),(INT((COLUMN())/2)*2))&":"&ADDRESS((INT((ROW()-2)/4)*4+2+3),(INT((COLUMN())/2)*2+1)) ))=0
You can read about the INDIRECT function in this blog post.
Another way to go is use OFFSET function:
=sum(OFFSET(INDIRECT(ADDRESS((INT((ROW()-2)/4)*4+2),(INT((COLUMN())/2)*2))), , , 4, 2))=0
Sorry, i don´t get this.. Im about to give up on this.. Thanks anyway!