How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4763 comments

  1. Could you tell me what is wrong with this formula
    =IF(R3<=24,24-Q3,R3=0)

    • The value_if_false argument. You cannot use R3=0 because the formula can return a value only in the cell in which it is entered.

  2. Hi,
    can someone help me answer the below;
    I would like to search, for example, "major" or "minor" in C1, if C1 contains either major or minor, i want to return "True".

    table below;
    C1= major minor young old , return "True"
    C1= major young, return True
    C1= minor old, return True
    C1= young old, return False.

    Much appreciate for your help.

    Regards,

    • Hi Bravo,

      Here you go:

      =IF(OR(ISNUMBER(SEARCH("minor",C1)), ISNUMBER(SEARCH("major",C1))),TRUE, FALSE)

  3. Hi Svetlana,
    Can You help me to this formula.
    I want to correct this beacuase it always appear ) or #value
    =IF(F13>1,L13=F13),IF(F13<1,ROUND((B10-0.065*2)/F13+1),"")

    Thanks,
    ken

  4. Hi Svetlana,
    I have a query regarding cell value restriction. I want to restrict the use of a certain letter in a cell if a corresponding cell value is greater than a certain amount i.e. if D35 has a value greater than 3, then D32 restricts me from entering the letter D. Is there a formula to do this?
    Regards,
    Paul

  5. Svetlana

    I have a cell with text such as TX,EP. If TX appears it should
    be mutiplied by 5%. I tried the following but it does not seem to
    work

    =IF(AF2739= "TX", AF2739*0.06,)

    Need your help to point out whether this is the correct manner
    of doing it. Thanks

    • Sorry should be AG2739*.06

      • H Thong,

        You probably meant "multiplied by 6%". If so, the formula =IF(AF2739="TX", AG2739*0.06,) is correct.

        • Svetlana

          Thanks

  6. Sir/Madam
    what I want is, if, a1=>1 then b1 will be "sometext"(whatever iwant)
    I used one formula =IF(A3>="","","--rana--").
    but when i am typing in cell a1 is 090, b1 is not responding. Means, before 90 the 0 is not considering.
    Pl. let me know the salvation.
    Thanks

  7. can u give me any formula for allouting different room to different age group

    as example
    age is 30,32,45,56,66,75,65,78
    there are 5 room as j1 j2 j3 j4 j5
    what should be the formula
    please reply fast

  8. Hi,

    I'm using an IF formula which is designed to look at a data tab and find a match for a number in one column and return the corresponding values from another column. This is working well expect one of the numbers, 3370, is also returning the values attached to 333700 and 533700. How do I ensure that the values returned are just for an EXACT match and not numbers which include 3370??

    Hope you can help!

  9. I will say again that for some reason greater than and less than symbols won't show

    • Hi Hardwareman,

      Our blog engine cuts off greater than and less than symbols quote often, sorry for that. I think you can use a nested IF formula like this:
      =IF(T11<>"","", IF(R11<>"",F11,""))

  10. the first formula should read =if(p11K10,P10-K10,"")

  11. I have a list of names in column F and numbers in columns K and P. In column R I have formula =if(p11k12,p12-k12,""). Then in column Q I have, so far, =if(r11,f11,""). This shows the name in F11 in Q11 if there is a value in R11 and it works.
    I need to extend this formula so that if there is a value in column R then show the name in column F but if there is a value in column T then show nothing (leave blank).
    Help please

    Kind regards Tony

  12. Hi,
    I want to make a cell turn blue if I enter a date or red if I enter text.
    I cant figure this out....searched everywhere for info.
    Thanks,
    Jack

    • Hi JACK,

      You can create the conditional formatting rules, with the following formulas:

      Blue: =ISNUMBER($A2)

      Red: =ISTEXT($A2)

      Where A1 is the top-most cell with data in the column, not including the header.

  13. I have a name in column A. Depending on what it is, column B should have another name. For example. A says "Alaska" B would say "West" or if A said "New York" B would say "Eastern", etc. Can't make it work. Thanks for your help.

    • Hi Paula,

      What you need is a nested IF formula like this:

      =IF(A1="Alaska", "West", IF(A1="New York", "Eastern", ""))

  14. Hi there.

    I'm trying to create an IF statement that will return nothing if there is nothing in the cell adjacent, but if there is anything text or number in that cell, then it will perform a formula.

    Example

    A1 Says, "Hello" then B1 will perform (B1*B6)

    I can get an IF statement to result in nothing if A1 is blank, but I can't figure the right way to have it do a formula if there is something in A1.

    • Hi George,

      Simply put the calculation in the value_if_false argument. For example,

      =IF(A1="", "", B1*B6)

  15. I would like to return a list of numbers separated by commas and & signs in an if statement, such as

    =IF((B14<8.75), 5, IF((B14<11.25), 5 & 7.5, IF((B14<13.75), 5, 7.5, & 10, IF((B14<17.5), 5, 7.5, & 12.5, IF((B14<22.5), 7.5, 10, & 15, IF((B14<27.5), 10, 15, & 20, B30))))))

  16. Can IF function for dates be used in a library system?
    I want that the book I've borrowed is in its due date, the date would turn to red or there will be notification that it's already due.

  17. Hi Svetlana, I need help with a formula. I need to compare E1(total sale) to F1(goal)and display 10% of E1(total sale) if the store made or surpassed its F1(goal) and 0 if it did not make its goal.

  18. hi Svetlana, thnx for your help but i need it again. please guide me to make this farmula.
    A1="UA" i want cell A1 to be color in red
    how it will work?
    like if i put the word UA in A1 i want A1 to be filled with Red color otherwise if i put anything else it stays normal

  19. Try this @Adeel
    =if(G1=100,G1=200,F1*30)))

  20. @Adeel
    put this formula in H1
    =IF(G1=100,G1=200,F1*30)))

  21. @Adeel wait 2 min bro miss Svetlana already given me this formula.. let me share it with you

  22. hi Svetlana, thnx for your help but i need it again. please guide me to make this farmula.
    A1="UA" i want cell A1 to be color in red
    how it will work?

  23. I want to link a document so that if it is greater than today it =A4 and if it is less than today it =A3. Say the document with A3 and A4 is called pizza. What would this formula look like?

  24. I want to know the formula as per following data:

    F G H
    1 50 100 (I want if G1 value is less than 100 so F1 multiply with 10 but if G1 value is greater than 100 and less than 200 so F1 multiply with 20 and if G1 value is greater than 200 so F1 multiply with 30 and answer came in H1)

    kindly provide assistance

    • Hi Adeel,

      Here's the formula for H1:

      =IF(G1<100, F1*10, IF(G1<200, F1*20, F1*30))

  25. Hi Svetlana Cheusheva,
    am just looking to put one formuls to calculate the tax value using IF function.the things are like follows....

    Suppose if there three columns f j and h
    if i enter the value in f as 5.5% then it should give me the value of the f*h in the column j

    ex: (in column j) =IFf=5.5% then it should calculate the value of f*h.
    could you plese help me out in this...

    • Hi KIRAN,

      If you need a formula exactly for 5.5%, then enter the following one in cell J2:
      =IF(F2=5.5%, F2*H2, "")

      The above formula multiplies F2 by H2 if F2=5.5%, and returns an empty string otherwise.

      If you are looking for a more universal formula that multiplies a value in column H by whatever percentage you enter in column F in the same row, then use this one:

      =IF(F2<>"", F2*H2, "")

  26. Hi Svetland,

    I am using this formula to find out whether 2 values exists in a column, if it doesn't, I want the result to indidate "NO", if it does, then "YES". However, it shows us "FALSE" for those that does exist. Can you check what I did wrong?

    Thank you!

    =IF(ISERROR(VLOOKUP("AP1902"&TRIM($J51)&TRIM($Q51),$C:$C,1,0)),IF(ISERROR(VLOOKUP("A80201"&TRIM($J51)&TRIM($Q51),C:C,1,0)),"NO","YES"))

  27. Hi Svetland,
    Please help me write this IF formula correctly. i have a cell with different figures but some are missing data sets.
    i want a command that says IF F3>1 then the answer should be 1, IF F3<1 then it should be 0 but if F3 is empty (meaning there is no number there) it should be empty. meaning if F3 is empty, leave blank.
    Kindly assist.
    thank you

    • Hi NASCO,

      You can use a nested IF formula like this:

      =IF(F3>1, 1, IF(F3<1, 0, ""))

      Please pay attention that the formula will also return an empty string if F3=1. So, you may probably want to add one more condition to the formula or replace F3>1 with F3>=1.

  28. Hi

    I am a total excel self taught newbie working on an Excel Workbook recording expenditure and wondered if there was an easy way to input the following in formula format:

    If a number is 50 to 100 minus 5% if a number is greater than 100 minus 10% in excel

    EG if the number in cell K20 is between 50.00 & 100.00 then 5% is deducted and if the number is 100.00 or more then 10% is deduced, I have managed to create a formula to deduct 5% if the number is 50.00 using the IF function =IF(K21>$M2,N2,)
    K21 = total
    M2 = 50.00
    N2 = % sum

    The above works fine however it is picking all amounts above 50.00 as I am unable to set the parameters so it only picks up amounts above 50.00 but less than 100.00

    Any suggestions?

    Many thanks

  29. What if I want more than one logical test in my formula?

    eg: If I want "IN TRANSIT" and "DISPATCHED" to be covered by one formula only.

    Awaiting Response

    • Hi Aditya,

      You can do this by using nested IF functions, for example:

      =IF(A1="IN TRANSIT", value_if_true, IF(A1="DISPATCHED", value_if_true, [value_if_false]))

      • Thank you so much. you were a great help.

  30. Hi,

    Thanks for above test eg.it lot me help to learn IF formula.

    Thanks.

  31. Hi,
    This is what I am trying do
    if value on A1 between
    0-154 A2 0
    155-462 A2 -1
    463-770 A2 -2
    771-1049 A2 -3

  32. thank u vry mch

  33. If i put red as value in one cell,what is the formula for appearing the same color in next cell

  34. how do you count if a column has two words like phone, mail
    and if a filter is applied at another column , the formula should count as per the filter applied not all the cells of the texts of the first column

  35. Hey so I have a file with 5 Columns and 5000 Rows, there is data in each row, some rows are in Times New Roman, others are in Ahora.

    I want to create a statement which basically says,

    IF X is in Times New Roman then its a Yes, If not then its a No....PLEASE HELP ME!!!

  36. Hi Svetlana,

    Can you please resolve the issue with my formula. I am trying to enter multiple logics with multiple values.

    =IF(D1>22,"This is a VERY HIGH risk study"), IF(D1>17,"This is a HIGH risk study"), IF(D1>12," This is a MEDIUM risk study"), IF(D1<=12,"This is a LOW risk study")

    Thanks

    • Hi Jamil,

      When using nested IF's, all closing parentheses should be at the end of the formula, like this:

      =IF(D1>22,"This is a VERY HIGH risk study", IF(D1>17,"This is a HIGH risk study", IF(D1>12," This is a MEDIUM risk study", IF(D1<=12,"This is a LOW risk study"))))

      • Thanks Svetlana, Works like a dream.

        BW

        J

  37. Respected Mam
    Actually we have some data base sheet in excel and we want to get a particular data from the sheet as we have "Ch. No. 000122 issued to Mr. Dilip I317018893 khargone(Cancelled)" in row and we want to get only "I317018893" form this data so please guide me the proper formula of excel so that I can easily do it.

    Thanks and regards
    Satish

  38. Hi Svetlana,

    i have this issue with my formula:

    D1 : due date
    E1 (value) : =NOW()-D1
    F1 : open or closed

    what i'm trying to do is, when i choose F1 as closed, i would like to have E1 value to be '0'. this is my formula which is still in error : =IF((NOW()-D1),(F1=Closed)),'0'.

    please help,thanks in advanced!

    • i managed to find the error and fix the formula. Here is the fixed formula =IF(F1="Closed","0",NOW()-D1). =)

  39. how can i right a formula if i want result of that cell is equal or less than zero to return zero value?

    Thank you,

    Tien

    • Hi Tien,

      You can use a formula similar to this:
      =IF(A1<=0, 0, "")

  40. I have two worksheet, in the first one it comes only one column with electronic component designators(example R3-resistor), in this column for each designator(resistor, capacitor or diode), corresponds a row. however in the other spreadsheet i have like more than one designator(the same designators as the first one) and it corresponded part number. what i want is a formula which compares designator and give me the part number in the first column. thank you

  41. Hi,

    I am trying to use IF function with multiple conditions but I am not getting the results I want to. Some times it works on one or two values but as I change the values to validate the formula it start making wrong outputs.
    So far I made this formula;

    =IF(C7>=70,"In Range",IF(C7<=100,"In Range",IF(C7<=69,"Low Alkalinity",IF(C7<=59," Too Low Alkalinity Can damage Plaster, Vinyle, Grouting etc",IF(C7<=49,"Danger Zone can't control pH levels",IF(C7=110,"Scaling can happen any time",IF(C7>=150,"HIGH Alkalinity",IF(C7>=200,"Pool equipment damaging",IF(C7>=250,"Stop Bathing in Pool HIGHLY DANGEROUS"))))))))))

    safe range is between 70ppm to 100ppm and I am trying to get remarks according to findings if findings are getting as low as 70 it should show relative comment in remarks column and if finding are more than 100 it should show accordingly or else if its in range it should say "In Range" in Remarks... Please some one help I need this one. Thanks in advance .....

  42. All I want is D33 to return 100 if B33 is Yes and 0 if B33 is No. So I tried =IF(B33="Yes",100,0) but I keep getting a #NAME error. What am I doing wrong?

    • Hello Cindy,

      The formula is correct, given that B33 is always either "yes" or "no".

      In Microsoft Excel, the #NAME error occurs when Excel cannot not recognize the function's name. Hardly someone can misspell IF's name, but maybe you are using a non-English localization of Office?

  43. I AM TRYING TO GET A CATEGORY LIKE FOLLOWING.
    123 42 HR
    456 52 MR
    258 50 HR
    159 55 MR
    756 70 LR

    HELP TO SOLVE

  44. Good Day! Please help.

    I'm trying to get a total of the amount of days used in a month in a numerical form (to be used for a running total formula). The days are either full days and half days used, but the input is in mixed form.

    This is what I tired but it didn't work: =IF((OR(B5:AC5=F,"1",B5:AC5=0.5,".5"),SUM(AE5:AE5))

    Thank you so much for your help.
    Alaine

  45. How do I calculate days using info in 2 separate columns but tell the formula to only calculate it using the column that has a value in it?

    • Hi Julianna,

      Please explain how exactly you want to calculate dates. Simply pull a date from a column that has a date in it? And what if both columns have dates?

  46. Good morning!
    Now could u also help me out for the following:
    I have different ranges of a quantity and one single cost for that particular range.
    For Ex. 5000 to 10000 = Rs. 120000
    11000 to 20000 = Rs. 115000
    21000 to 30000 = Rs. 100000
    31000 to 40000 = Rs. 98000
    and same pattern continues for further more values...

    request for early reply...
    thanks in advance

    Anwaar

  47. A B C D E
    1 Date 3X5.5 6X5.5
    2 03-23 6X5.5 345 345
    3 03-24 3X5.5 580 580

    please help, thanks!

  48. I have work with formulas previously but I need to get this formula correct:

    =IF(K2"",K2,IF(AND(L2="",I2="Regional"),DATE(2015,5,29),""))

    How to write a nested if from above when :

    I2=Panama date(2015,7,29)
    I2= Singapore date(2015,6,8)
    I2= UK date(2015,10,8)
    I2= Mexico date(2015,6,10)
    I2=Italy date(2015,11,22)

    Thank you for your help

  49. L10 12 , L1016

  50. Why i can't write this?

    =SUM(IF(AND(J1012),(M10-K10+(L10-J10)*60-60),IF(AND(J1016),M10-K10+(L10-J10)*60-15,M10-K10+(L10-J10)*60)),IF(AND(J1112),M11-K11+(L11-J11)*60-60,IF(AND(J1116),M11-K11+(L11-J11*)60-15,M11-K11+(L11-J11)*60)))

    there have another two need to add up.

    • =SUM(IF(AND(J1012),(M10-K10+(L10-J10)*60-60),IF(AND(J1016),M10-K10+(L10-J10)*60-15,M10-K10+(L10-J10)*60)),IF(AND(J1112),M11-K11+(L11-J11)*60-60,IF(AND(J1116),M11-K11+(L11-J11*)60-15,M11-K11+(L11-J11)*60)))

      • =SUM(IF(AND(J1012),IF(AND(J1016)IF(AND(J1112)IF(AND(J1116),

        • IF(AND(J10 less than 13, L 10 more than 12), (J10 less than 17, L 10 more than 16)
          J11, L11, same as above.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)