by This tutorial focuses on various ways to calculate times in Excel. You will find a few useful formulas to add and subtract times, calculate time difference, or elapsed time, and more.
In the last week's article, we had a close look at the specificities of Excel time format and capabilities of basic time functions. Today, we are going to dive deeper into Excel time calculations and you will learn a few more formulas to efficiently manipulate times in your worksheets.
How to calculate time difference in Excel (elapsed time)
To begin with, let's see how you can quickly calculate elapsed time in Excel, i.e. find the difference between a beginning time and an ending time. And as is often the case, there is more than one formula to perform time calculations. Which one to choose depends on your dataset and exactly what result you are trying to achieve. So, let's run through all methods, one at a time.
Formula 1. Subtract one time from the other
As you probably know, times in Excel are usual decimal numbers formatted to look like times. And because they are numbers, you can add and subtract times just as any other numerical values.
The simplest and most obvious Excel formula to calculate time difference is this:
Depending on you data structure, the actual time difference formula may take various shapes, for example:
| Formula | Explanation |
=A2-B2 |
Calculates the difference between the time values in cells A2 and B2. |
=TIMEVALUE("8:30 PM") - TIMEVALUE("6:40 AM") |
Calculates the difference between the specified times. |
=TIME(HOUR(A2), MINUTE(A2), SECOND(A2)) - TIME(HOUR(B2), MINUTE(B2), SECOND(B2)) |
Calculates the time difference between values in cells A2 and B2 ignoring the date difference, when the cells contain both the date and time values. |
Remembering that in the internal Excel system, times are represented by fractional parts of decimal numbers, you are likely to get the results similar to this:
The decimals in column D are perfectly true but not very meaningful. To make them more informative, you can apply custom time formatting with one of the following codes:
| Time code | Explanation |
| h | Elapsed hours, display as 4. |
| h:mm | Elapsed hours and minutes, display as 4:10. |
| h:mm:ss | Elapsed hours, minutes and seconds, display as 4:10:20. |
To apply the custom time format, click Ctrl + 1 to open the Format Cells dialog, select Custom from the Category list and type the time codes in the Type box. Please see Creating a custom time format in Excel for the detailed steps.
And now, let's see how our time difference formula and time codes work in real worksheets. With Start times residing in column A and End times in column B, you can copy the following formula in columns C though E:
=$B2-$A2
The elapsed time is displayed differently depending on the time format applied to the column:
Note. If the elapsed time is displayed as hash marks (#####), then either a cell with the formula is not wide enough to fit the time or the result of your time calculations is a negative value.
Formula 2. Calculating time difference with the TEXT function
Another simple technique to calculate the duration between two times in Excel is using the TEXT function:
- Calculate hours between two times:
=TEXT(B2-A2, "h") - Return hours and minutes between 2 times:
=TEXT(B2-A2, "h:mm") - Return hours, minutes and seconds between 2 times:
=TEXT(B2-A2, "h:mm:ss")
Notes:
- The value returned by the TEXT function is always text. Please notice the left alignment of text values in columns C:E in the screenshot above. In certain scenarios, this might be a significant limitation because you won't be able to use the returned "text times" in other calculations.
- If the result is a negative number, the TEXT formula returns the #VALUE! error.
Formula 3. Count hours, minutes or seconds between two times
To get the time difference in a single time unit (hours ,minutes or seconds), you can perform the following calculations.
Calculate hours between two times:
To present the difference between two times as a decimal number, use this formula:
Supposing that your start time is in A2 and end time in B2, you can use a simple equation B2-A2 to calculate the difference between two times, and then multiply it by 24, which is the number of hours in one day:
=(B2-A2) * 24
To get the number of complete hours, use the INT function to round the result down to the nearest integer:
=INT((B2-A2) * 24)
Total minutes between two times:
To calculate the minutes between two times, multiply the time difference by 1440, which is the number of minutes in one day (24 hours * 60 minutes = 1440).
As demonstrated in the following screenshot, the formula can return both positive and negative values, the latter occur when the end time is less than the start time, like in row 5:
=(B2-A2)*1440
Total seconds between times:
To get the total seconds between two times, you multiply the time difference by 86400, which is the number of seconds in one day (24 hours * 60 minutes * 60 seconds = 86400).
In our example, the formula is as follows:
=(B2-A2)* 86400
Note. For the results to display correctly, the General format should be applied to the cells with your time difference formula.
Formula 4. Calculate difference in one time unit ignoring others
To find the difference between 2 times in a certain time unit, ignoring the others, use one of the following functions.
- Difference in hours, ignoring minutes and seconds:
=HOUR(B2-A2) - Difference in minutes, ignoring hours and seconds:
=MINUTE(B2-A2) - Difference in seconds, ignoring hours and minutes:
=SECOND(B2-A2)
When using Excel's HOUR, MINUTE and SECOND functions, please remember that the result cannot exceed 24 for hours and 60 for minutes and seconds.
Note. If the end time is less than the start time (i.e. the result of the formula is a negative number), the #NUM! error is returned.
Formula 5. Calculate elapsed time from a start time to now
In order to calculate how much time has elapsed since the start time to now, you simply use the NOW function to return today's date and the current time, and then subtract the start date and time from it.
Supposing that the beginning date and time is in call A2, the formula below returns the following results, provided you've applied an appropriate time format to column B, h:mm in this example:
=NOW()-A2
In case the elapsed time exceeds 24 hours, use one of these time formats, for example d "days" h:mm:ss like in the following screenshot:
If your starting points contain only time values without dates, you need to use the TIME function to calculate the elapsed time correctly. For example, the following formula returns the time elapsed since the time value in cell A2 up to now:
=TIME(HOUR(NOW()), MINUTE(NOW()), SECOND(NOW())) - A2
Note. The elapsed time is not updated in real-time, it refreshes only when the workbook is reopened or recalculated. To force the formula to update, press either Shift + F9 to recalculate the active spreadsheet or hit F9 to recalculate all open workbooks.
Formula 5. Display time difference as "XX days, XX hours, XX minutes and XX seconds"
This is probably the most user-friendly formula to calculate time difference in Excel. You use the HOUR, MINUTE and SECOND functions to return corresponding time units and the INT function to compute the difference in days. And then, you concatenate all these functions in a single formula along with the text labels:
=INT(B2-A2) & " days, " & HOUR(B2-A2) & " hours, " & MINUTE(B2-A2) & " minutes and " & SECOND(B2-A2) & " seconds"
To instruct your Excel time difference formula to hide zero values, embed four IF functions into it:
=IF(INT(B2-A2)>0, INT(B2-A2) & " days, ","") & IF(HOUR(B2-A2)>0, HOUR(B2-A2) & " hours, ","") & IF(MINUTE(B2-A2)>0, MINUTE(B2-A2) & " minutes and ","") & IF(SECOND(B2-A2)>0, SECOND(B2-A2) & " seconds","")
The syntax may seem excessively complicated, but it works :)
Alternatively, you can calculate time difference by simply subtracting the start time from the end time (e.g. =B2-A2), and then apply the following time format to the cell:
d "days," h "hours," m "minutes and" s "seconds"
An advantage of this approach is that your result would be a normal time value that you could use in other time calculations, while the result of the complex formula discussed above is a text value. A drawback is that the custom time format cannot distinguish between zero and non-zero values and ignore the latter. To display the result in other formats, please see How to show time over 24 hours, 60 minutes, 60 seconds.
How to calculate and display negative times in Excel
When calculating the time difference in Excel, you may sometimes get the result as ###### error because the difference is a negative time. But is there a way to show negative times properly in Excel? Of course, there is a way, and even more than one :)
Method 1. Change Excel Date System to 1904 date system
The fastest and easiest way to display negative time normally (with a minus sign) is switching to the 1904 date system. To do this, click File > Options > Advanced, scroll down to the When calculating this workbook section and put a tick in the Use 1904 date system box.
Click OK to save the new settings, and from now on negative times will be displayed correctly, like negative numbers:
Method 2. Calculate negative time in Excel with formulas
Is changing Excel's default Date System is not an option, then you can force negative times to display properly using one of the following formulas:
=IF(A2-B2>0, A2-B2, "-" & TEXT(ABS(A2-B2),"h:mm"))
=IF(A2-B2>0, A2-B2, TEXT(ABS(A2-B2),"-h:mm"))
Both formulas check if the time difference (A2-B2) is greater than 0, and if it is they return that difference. If the time difference is less than zero, the first formula calculates the absolute difference and concatenates the minus sign. The second formula yields exactly the same result by using a negative time format "-h::mm".
Note. Please keep in mind that unlike the first method that treats negative times as negative numeric values, the result of the TEXT function is always a text string that cannot be used in calculations or other formulas.
Adding and subtracting time in Excel
Basically, there are 2 ways to add and subtract time in Excel:
- Using the TIME function
- Using arithmetic calculations based on the number of hours (24), minutes (1440) and seconds (86400) in one day
The TIME(hour, minute, second) function makes Excel time calculations really easy, however it does not allow adding or subtracting more than 23 hours, or 59 minutes, or 59 seconds. If you are working with bigger time intervals, then use one of the arithmetic calculations demonstrated below.
How to add or subtract hours to time in Excel
To add hours to a given time in Excel, you can use one the following formulas.
TIME function to add under 24 hours
For example, if your start time is in cell A2, and you want to add 2 hours to it, the formula is as follows:
=A2 + TIME(2, 0, 0)
Note. If you try adding more than 23 hours with the TIME function, the specified hours will be divided by 24 and the remainder will be added to the start time value. For example, if you try to add 25 hours to "6/2/2015 10:00 AM" (cell A4) using the formula =A4 + TIME(25, 0, 0), the result will be "06/02/2015 11:00", i.e. A4 + 1 hour.
Formula to add any number of hours (under or over 24 hours)
The following formula has no limitations to the number of hours you want to add:
For example, to add 28 hours to the start time in cell A2, enter the following formula:
=A2 + (28/24)
To subtract hours from a given time, you use analogous formulas, and just replace "+" with the minus sign:
For example, to subtract 3 hours from the time in cell A2, either of the following formulas will do:
=A2-(3/24)
=A2-TIME(3,0,0)
To subtract more than 23 hours, use the first one.
How to add / subtract minutes to time in Excel
To add minutes to a given time, employ the same techniques that we've just used for adding hours.
To add or subtract under 60 minutes
Use the TIME function and supply the minutes you want to add or subtract in the second argument:
And here are a couple of real-life formulas to calculate minutes in Excel:
To add 20 minutes to the time in A2: =A2 + TIME(0,20,0)
To subtract 30 minutes from the time in A2: =A2 - TIME(0,30,0)
To add or subtract over 60 minutes
In your calculation, divide the number of minutes by 1440, which is the number of minutes in a day, and add the quotient to the start time:
To subtract minutes from time, simply replace plus with the minus sign. For example:
To add 200 minutes: =A2 + (200/1440)
To subtract 300 minutes: =A2 -(300/1440)
How to add / subtract seconds to a given time
Second calculations in Excel are done in a similar fashion.
To add under 60 seconds to a given time, you can use the TIME function:
To add more than 59 seconds, use the following formula:
To subtract seconds, utilize the same formulas with the minus sign (-) instead of plus (+).
In your Excel worksheets, the formulas may look similar to these:
To add 30 seconds to A2: =A2 + TIME(0,0,31)
To add 1200 seconds to A2: =A2 + (1200/86400)
To subtract 40 seconds from A2: =A2 - TIME(0,0,40)
To subtract 900 seconds from A2: =A2 - (900/86400)
How to sum time in Excel
The Excel sum time formula is the usual SUM function, and applying the proper time format to the result is what does the trick.
Supposing you have a few project times in column B and you want to add them up. You write a simple SUM formula like the one below and get the result in the default format such as hh:mm:ss.
=SUM(B2:B4)
In some cases the default time format works just fine, but sometimes you may want more, for example to display the total time as minutes and seconds, or seconds only. The good news is that no other calculations are required, all you have to do is apply custom time format to the cell with the SUM formula.
Right click the cell and select Format Cells in the context menu, or press Ctrl + 1 to open the Format Cells dialog box. Select Custom from the Category list and type one of the following time formats in the Type box:
- To display total time as minutes and seconds: [m]:ss
- To display total time as seconds: [ss]
The result will look as follows:
In order to add up more than 24 hours, you use the same SUM formula as discussed above, and apply one of the following time formats to the cell: To see how these custom time formats may look like in your Excel worksheet, please have a look at the screenshot below, where the same SUM formula is entered in cells A9 to A13: Note. The above custom time formats work for positive values only. If the result of your time calculations is a negative number, e.g. when you are subtracting a bigger time from a smaller time, the result will be displayed as #####. To display negative times differently, please see custom format for negative time values.
Also, please keep in mind that the time format applied to a cell changes only the display presentation without changing the cell's value. For example, in the screenshot above, cell A13 looks like text, but in fact it's a usual time value, which is stored as a decimal in the internal Excel system. Meaning, you are free to refer to that cell in other formulas and calculations. For more information, please see How to calculate and show over 24 hours, 60 minutes, 60 seconds.
How to sum over 24 hours in Excel
Format
Displays as
Explanation
[h]:mm
30:10
Hours and minutes
[h]:mm:ss
30:10:20
Hours, minutes and seconds
[h] "hours", mm "minutes", ss "seconds"
30 hours, 10 minutes, 20 seconds
d h:mm:ss
1 06:10:20
Days, hours, minutes and seconds
d "day" h:mm:ss
1 day 06:10:20
d "day," h "hours," m "minutes and" s "seconds"
1 day, 6 hours, 10 minutes and 20 seconds
=SUM($B$2:$B$4)
Date & Time Formula Wizard - quick way to calculate times in Excel
Now that you know a bunch of different formulas to add and subtract times in Excel, let me show you the tool that can do it all. Okay, almost all :)
Here comes Ablebit's Date & Time Formula Wizard for Excel:
In the Date & Time Wizard dialog window, you switch to the Add or Subtract tab, depending on which operation you want to perform, and do the following:
- Click the Show time fields link in the left part of the window.
- Supply values or cell references for the formula arguments. As you fill in the argument boxes, the wizard builds the formula in the selected cell.
- When finished, click the Insert Formula
That's it! For example, this is how you can add the specified number of hours, minutes and seconds to the time in A4:
If you need to copy the formula to other cells, fix all references except the cell containing the original time (A4) with the $ sign like shown in the screenshot below (by default, the wizard always uses relative references). Then double-click the fill handle to copy the formula down the column and you are good to go!
Besides time calculations, the wizard can also add and subtract dates, get the difference between two dates, and calculate age from the birthdate.
If you are curious to try this tool in your own worksheets, you are welcome to download the evaluation version of our Ultimate Suite below.
This is how you calculate time in Excel worksheets. To learn other ways to manipulate dates and times in Excel, I encourage you to check out the resources at the end of this article. I thank you for reading and hope to see you on our blog next week!
Available downloads
Excel Time Calculations - formula examples (.xlsx file)
Ultimate Suite - trial version (.exe file)
977 comments
hello. suppose i want to calculate OT hrs where staff sign in time is 9:00am and signout time is 3:00 pm. total working hrs is 6. after deducting 4 hrs which is compulsary to work, how could i find the exact time when OT starts? what will be the formula.
thank you for the help in advance
Hello!
If A1 is the start time, B1 is the end time, then OT in cell C1
=B1-A1-TIME(4,0,0)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Sir
the start time and end time in single cell how to calculate. i.e.
07:00-19:00
22:00-2:00
i need to reduce 1 hr. where working hors are more then 8 and 30 min where working hours are less then 8.
Hello!
Divide the time into two cells using this instruction: How to split cells in Excel: Text to Columns, Flash Fill and formulas.
You will receive the time as text. You can convert text to time using a math operation like:
=--LEFT(A1,5)
Find the time difference using the recommendations in the article above.
I am trying to figure out how to subtract time in excel. For example, I have to complete 250 hours of course work this summer. I am wanting to subtract the total hours I currently have from 250 hours, to come up with the number of hours I have remaining. I have 13:45 hours right now and can't seem to get the formula right to subtract that from 250 hours.
Any help would be much appreciated!
Hello Erin!
To record time in a cell more than 24:00:00, use the time format "37:30:55". Next apply regular subtraction
=B1-A1
I hope this will help, otherwise please do not hesitate to contact me anytime.
I'm racking my brain trying to figure this one out. I'm running a compliance audit whereby I need to work out how much time is worked before 6 AM and how much time is worked after. In other words, if my candidate worked from 1 AM to 9 AM, I need to be able to return a result that tells me 5 hours were worked before 6 AM. Any help is warmly appreciated.
Hello Adam!
If I understand your task correctly, the following formula should work for you:
=IF(A7 > TIME(6,0,0),TIME(6,0,0)-A7+1, TIME(6,0,0)-A7)
I hope this will help
I want to substract 8:00hrs in cell 1 from 4:00hrs in cell2 and also if cell 2 value is 9:00hrs so result should be zero.
Please help with query.
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(M2 <> TIME(9,0,0),IF(M2 < M1,M2-M1+1,M2-M1),0)
Hope this is what you need.
Hi, I want to calculate the elapsed time students attended my class online. The report shows the time in a format like this:
2020-05-12 15:41:08
When I subtract the value of the two cells, I give #VALUE! error. I need the results in h:mm format. I appreciate it if you could help me with a solution.
Hello Alireza!
Most likely, you have a non-printable character in front of the date. You cannot see him. This often happens when importing data from other programs into Excel.
Try using the CLEAN function:
= CLEAN(C2) -CLEAN(B2)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Dear Alex!
Thanks for the quick reply. Unfortunately, it doesn't solve the problem. The same #VALUE! error exists.
Hello! I need to calculate the time between 05-05-2020, 07:16:58 and 05-05-2020, 07:17:02. This is how it is populated on a report I download. I have tried =C11-B11 as a suggestion and also =TEXT(C11-B11,"d:h:mm:ss"), but I think the comma after date is causing issues.
Hello Sheree L!
The formula below will do the trick for you:
=DATEVALUE(SUBSTITUTE(B1,",",""))+TIMEVALUE(SUBSTITUTE(B1,",","")) - DATEVALUE(SUBSTITUTE(A1,",",""))-TIMEVALUE(SUBSTITUTE(A1,",",""))
or
=SUBSTITUTE(B2,",","")-SUBSTITUTE(A1,",","")
Remember to set the time format in this cell.
I hope it’ll be helpful.
Hi,
I have issue where I am entering time as text as we want to enter 9:00am in it's simplest form as 900 but have set format to 00":"00 which works well until you do calcualtions and sum totals.
I have a spreadsheet with 2 examples on it but not sure if I can send to you:-
!) entering time as text
2) entering time as time
both have there issues. We need to enter start time, end time then set a default for 30 min break which can be over typed with longer break (or if less than 5 hours worked no break) and sum the days paid hours.
Hope you are able to give me some guideance on this.
thanks, Chris
hello Chris!
I'm sorry, it is not very clear what result you want to get. If you enter the number 900 in a cell, then you can convert it to time in another cell. Regardless of the format, a number, not time, will remain in this cell. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.
In A1 i have a start time as 21:30:00 and in A2 an end time of 08:55:00 and have the formula of =IF(A2<A1,A1-A2+24,A2-A1)in A3; however A3 calculates as 12:35. Cells A1 and A2 set to [h]:mm:ss. Cells in A3 set to h:mm. I need A3 to calculate the actual time between 21:30 the previous evening to 08:55 the next morning in h:mm as the time of travel is through the night.
Thanks.
Note: A3 should calculate to 11:25 (11 hours and 25 minutes) elapsed time since commecing at 21:30:00, but calculates AS 12:35 (12 hours and 35 minutes).
Thanks for your support.
Hello Austin!
If I understand your task correctly, the following formula should work for you:
=IF(A1 > A2,A2-A1+1,A2-A1)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi
I have made a simple work schedule to show when each colleagues shift will be.
I have a single cell displaying their start and end time (eg 10:00-14:00).
the next column is for the number of hours in their shift.
Is there a way I can get it to work out the number of hours in the shift automatically, or would I have to have a start and finish time in separate columns.
I use the same sheet to print and put on the notice board so need it reader friendly.
thanks!
Hello Louise!
Of course, it’s better to record the start time and end time in two different columns. But in your case, you can use the following formula:
=TIMEVALUE(MID(A10,FIND("-",A10,1)+1, LEN(A10)-FIND("-",A10,1))) - TIMEVALUE(LEFT(A10,FIND("-",A10,1)-1))
Remember to apply the time format to the cell with this formula.
I hope it’ll be helpful.
Hy. The formula works. I have the same schedule format. But how do I sum up with this formula for multiple days to get the final time number?
Hello!
You need to find the sum of the cells and the original time (12:10, etc.). Use the guidelines from the "How to sum over 24 hours in Excel" section above.
I hope this will help
How do you calculate the difference of day and time between days into minutes in one cell?
for example:
I have a email that came in last night at 8:30pm and i answered to the email at 10:30am the next day. How many minutes is in between of my response time?
Also if it was during the weekend days how would it calculate the time?
Hello Roxy!
I recommend reading the first part of the above article, 'How to calculate time difference in Excel', to answer your question.
To be able to show more than 24 hours in a cell, please use this time format: "37:30:55". You can find it in the list of Excel time formats.
If Saturday and Sunday are traditionally considered to be days off, it is possible to exclude those 2 days from calculations with the help of this formula:
=IF(WEEKDAY(A3) < WEEKDAY(A2),A3-A2-2,0)
I do have two columns with date and time. I want to calculate the difference between them (so, that is pretty easy, only subtract). My issue: 1. End date sometimes is "Null" - in that case I tried to solve by adding if and setting the difference time to 999 or so. 2. I would like output to be in Days, Hours, Minutes, but days shown only if they are >0; and I want result still be a number (for the graph later). Original fields are in format yyy-mm-dd hh:ss. Is there a way to display this? I believe it is possible to do with IF by putting "" if month value is 0, but won't that put the result to text field format? Also, that is pretty lengthy formula, maybe there is a function or format that I am not aware of?
Hello!
If I understand your task correctly, please go to Format Cells, choose Number -> Custom Format and set
[>1]m"m." d"d." hh:mm:ss;[<=1] hh:mm:ss;@
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi,
I am trying to figure out how many hours worked in a day using military time. I am also trying to find the difference of hours worked from 8.5 hours. I have to work 8.5 hours a day. Sometimes I work more and sometimes I work less. I would like the formula to highlight a negative difference so I can make sure I work 8.5 hours a day.
Thanks in advance for your help.
how to figure out the diffrence between time in days if some of them have end date and some dont?
Hello SHAFF!
If I understand your task correctly, the following formula should work for you:
=IFERROR(DATEDIF(A1,A2,"d"), DATEDIF(A1,TODAY(),"d"))
I hope this will help, otherwise please do not hesitate to contact me anytime.
do im doing something wrong :(
can someone help me with this formula I try many time to calculate the hour time to make total duration time and still I am stuck ca some one help=(IF(E4>F4,1+F4,F4)-E4)*X1440 me on that. It's not calculating the duration on time i am try to calculated this formula but its not helping
Hello Caraball!
Please clarify what time is there in your cells F4 and E4 (dd:mm:yy hh:mm:ss or hh:mm:ss) and what result and in what format you would like to get. I won’t be able to help you without more detailed information on your problem.
AfterDifference in time than roundup gives wrong results when start time and end time is equal ROUNDUP((C3-D3),0)
Hello Manoj!
For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
Hi,
I have Excel sheet where open Date is available in A column, And Time is available in B column, and closing date & time available in C & D Column. How can i find total time duration between open date & closing date. Thank you for your advise.
BR,
John Paul.
Hi John,
The formula below will return you the number of days between open & closing date:
=INT(C1+D1-A1-B1)
In order to calculate this duration in hours, please use the following formula instead:
=TIME(,(C24+D24-A24-B24- INT(C24+D24-A24-B24)) *24*60,)
Note! Don't forget to set the Time format for cell E1.
Hi, SIR/MADAM
iam SRI SINDHU G. SADHU
i have to calculate time in calculate time i 24 hr formate and i have to mention time without ("AM","PM") how t calculate with formula in excel
for eg
if i state today 07:00 and i completed next day at 10:00 hear 07:00 is 7am and 10:00 is next day 10am hear i done my work above 24 hr (24 hr and "+" 3 hr extra) this how i can calculate with formula.....
thank you
How can I convert times to decimals in military time? I'm trying to write a sheet where I input time in and time out using 4 digit military time (6 AM as 0600, 2 PM as 1400), and receive total hours worked. For example, I have time in as 0800, Time out as 1630, and I'd like to get an answer of 8.5 for the number of hours worked. Not 8:30. No colons. Just decimals where half hours are displayed as .5.
Thank you
Hello Steve,
Supposing that your times are in A1 and B1 (800 and 1630 accordingly), the following formula will do the trick for you:
=(TIME(LEFT(B1, LEN(B1) -2), RIGHT(B1, 2), )-TIME(LEFT(A1, LEN(A1)-2), RIGHT(A1, 2), ))*24
I am needing a formula that subtracts hours worked from 40. I am needing to know the left over hours. Basically I need it to subtract worked hours for the week let’s say 25.50 from 40 hours allowed for the week and give me the sum of that. So 40 - 25.5 =14.50
Hello Amber!
If you enter working hours in the hh:mm:ss format, you can find the sum with the help of ordinary addition. Suppose you type the time in cells B2:B7 and get the sum in cell B8. However, when you sum several time intervals, the result can turn out to be over 24 hours. In this case, Excel resets the sum to zero and starts the operation anew. To show the correct sum of working hours, please apply a special format to B8: open the Format Cells dialog window, go to Number -> Time and choose "37:30:55" from the Type list. Then enter 40:00:00 which is your maximum working time in a separate cell, e.g. C1. After that, change the formula in cell B8 to see the left-over hours:
=IF(C1 < SUM(B2:B7), "Over 40 hours on "&TEXT((SUM(B2:E7)-C1), "hh:mm"), C1-SUM(B2:B7))
Ok, Thanks for your response, however I was not able figure out where to put that, should I put it in the very beginning? I just couldn't get it to work.I have IN, OUT, IN, Out, and if I put in say 6:30 for the first in without any of the others populated, the total time says 17.25 Hours, and I would like it to say 0 until I enter a out time. Thanks a lot for helping!
Hello Amos!
Please use the formula below:
=IF(COUNTA(C3:F3)>1, ((IF(C3>D3, D3+1, D3)-C3)*24)+(IF(E3>F3, F3+1, F3)-E3)*24, "")
Hi Alexander, Thanks so much for the formula that you posted, and it works great for when I enter the IN time in the morning, but when I enter the IN time after lunch it shows the 16.5 hours again. I suppose I just need to add something? I am lost when it comes to these long formulas. So I have IN, OUT, IN, OUT I enter the time to the closest 15 minutes, then the total column shows the hours. Please let me know if you have any thoughts to get the time to show only the hours in the forenoon if I enter the IN time in the afternoon. Thanks!
Hello!
Check what values you enter in C3 D3 E3 and F3. If only one value is filled, the formula does not count time. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you. Thank you.
Ok, so what I would like is if G3 (which is the total hours) does not show a total unless D3 or F3 is populated. Currently I have this formula in G3.
=IF(COUNTA(C3:F3)>1, ((IF(C3>D3, D3+1, D3)-C3)*24)+(IF(E3>F3, F3+1, F3)-E3)*24, "")
Currently it shows 17 Hours if I have a time in E3 but not F3. It seems like C3 and D3 are working exactly how I want them. Thanks a lot! Amos
Thank you.
I have a formula to calculate time in excel, which works good, but if I clock in at say 6:30 AM, (cell, C3) it shows a total time, even if the other cells are empty. Is there a way to not calculate time until more then one cell is populated? It is to clock in and out, AM and PM. The formula is,
=((IF(C3>D3,D3+1,D3)-C3)*24)+(IF(E3>F3,F3+1,F3)-E3)*24
Can someone please help me with this, or is there a better way of doing it? Thanks!
Just add some more nests to your formula to check if D3 and F3 are empty.
=If(D3="","") will check D3 and if it is blank will make the cell with the formula in it blank as well. Build this check into your existing formula and you will get what you are after.
Can any one help to find available cars in every 30 mins interval during 24 hrs schedule
total fleet (cars) 180 , routes 28. Pax capacity 14. turn around duration 90 mins per trip.
next day i need to generate report with actual transported and available buses to find shortage of cars in every 30 mins / 1 hrs.
I have a schedule with start times and finish times.
I made separate column for how many hours each day.
How do I add these times up to find how many hours per week?
From there I will need to make a separate sheet to calculate hours over 80 per pay period.
I thought it would be something like this:
=TEXT(R5:X5, "h:mm") but it isn't working
Hi Beth
you have made your result to be TEXT and you cannot calculate with text.
Also when a result is more than 24 hours you have to be careful with formats otherwise Excel will not display what you are expecting. Use cell format "General" or "Number" but not time. If you use time everything goes back to zero after 23:59 like a clock.
Apart from that, then calculate as normal =sum(R5:X5) or if you really want to =Sum(R5:X5,"[h]:mm") The bracket around the h tells excel to go beyond the 24 hour constraint it normally uses and you need that. Make sure R5 through to X5 are numbers not text as well and watch those formats, it can mess up your calculations big time.
I have start time and total hours worked for the day. How can I get the end time?
Hello Cindy,
To find out the exact end time, just use the formula below:
=A1+TIME(B1, 0, 0)
Where A1 is the start time and B1 is the total hours to work.
Hello Alexander, Im working on an overtime sheet. Where I need to calculate times between(16:00 to 21:59) & (22:00 to 07:59) in different columns
Hello!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you. Thank you.
i given one small example for this comment box
K Column 8:30 to L Column 10:00 =IF(K3>L3,1+L3,L3)-K3
M Column Result is 1:30
But in the Same M Column I need time difference in Minute in the same Cell like 90 minute
Change your formula to =(IF(K3>L3,1+L3,L3)-K3)x1440 and you will get your answer in minutes.
1440 being the number of minutes in a day.
Excellent information. Thanks a lot.
The difference between Old time New time= +/-
Hi, I'd like to count elapsed time but in the situation when dates and hours are in separate cells.
A1=Start B1=2019-01-12 C1=6:00
A2=End B2=2019-15-12 C2=20:40
I'd like the result to be divided into full days (24h) and the remaining time.
I need to make my work sheet for counting my flying hours. It's like that,
350.45hrs - 150.25hrs = 200.20hrs
Hello. I need assistance with writing a formula to calculate holiday hours for anytime worked before 5pm.
for example:
Time in is 11:46 am and Time out is 4:39
or
Time in is 2:00 pm and Time out is 12:00 AM
how can calculate extra working hours and minute in amount
As like-
Report Time Out Time Total time Working Time/per Day Extra working Time Per hours *50 Rs Extra working Amount
08:00 22:50 14:50 12:00 02:50 00:00 ??????
How do I add 26 hours to a time if it has to calculate it by office hours say 9 - 19.
Hello:
If I have start time and end time in one cell, how can i get the toal # of hours. For example: in one cell I have: 05:00 pm - 10:00 pm. How can i get the total # of hours which is 5 hours?
Thank you so much!
Is the end time always on the same day as the start time?
Total Hours = (End time - Start time) * 24
For example -> C1 = (B1-A1)*24
Where:
A1 = Start time
B1 = End time
C1 = Total Hours
Make sure the number format for the total hours cell is general or number.
Nakul Neel Ajay Ghanshyam
Date in Out in Out in Out in Out
1-jun 11:00 16:00 10:00 19:00 10:00 19:00 10:00 15:30
20:30 02:00 - - - - 19:20 02:00
2-jun 10:00 16:00 10:00 16:00 14:30 02:30 10:00 16:00
20:30 02:30 - - - - 20:30 02:30
3-jun 10:00 16:00 10:00 19:00 15:00 02:00 10:00 14:30
20:30 02:00 - - - - 19:40 02:00
How to calculate night/day
i am looking for the elegant way to calculate night and day power consumption. the problem is that night tariff is calculated from 23:00 to 7:00, and counter indications are not taken daily.
e.g.
26 October, 13:06
28 October, 11:26
4 November, 17:46
how to calculate the time (hours and minutes) that can be attributed to the night/day time?
Using the 12 hour format, I am struggling to calculate the duration of hours when the start time begins at PM and the out time ends at AM. For example, if I wanted to find the duration of hours from 12:30AM(A1) to 3PM(A2), I would use the formula =(A2-A1)*24, which is 14.5 hours. BUT this does not work if I were to calculate the duration from 3PM(A1) to 12:30AM(A2), which is 9.5 hours but formula =(A2-A1)*24 will give me -14.5. What formula would I use to find the difference of time from PM to AM?
Hello Brenda,
Here is the formula to solve your task:
=(IF(A2 > A1, A1+1, A1)-A2)*24
You can use the formula =(IF([@Start],[@End],[@End])-[@Start]) and write the end time as over the 24 mark rather than going back to 00:00:00. For example: start= 23:00:00, end= 25:00:00, and the duration it gives you will be 02:00:00.
The formula provided by Mary also works! If you want the same formula for the whole collumn though, that's what I use.
sdsf
1 hour to two hours and three minutes how much longer?
I struggled, pls help me. I am using an updated version and this wouldn't work for me. Do you know why?
Need to perform a calculation on an employee schedule (utilizing the 24 hour clock) where start time is 19:00 (A11) and end time is 03:00 (A12) and get an answer that is not in negative hours ( =SUM(A12-A11) currently returns -16). When I use the hours 16:30 (B11) and 23:30 (B12) that do not span midnight (2400) then the calculations are correct ( =SUM(B12-B11) currently returns 7:30), which I can easily convert to 7.5 hours, any suggestions without having to program the dates into the start times?
Hi Woody,
just add 24 hours if the time will be negative :
=IF(A12<A11,A12-A11+24,A12-A11)
expl : check if value A12 is less then A11; if so add 24 to the difference, else just use the difference.
Think it will work for you.
This worked.
But when we SUM such results with SUM formula, it doesn't show the right value.
Please give me a formula for total calculate...
00:49
02:08
00:29
-00:02
01:55
-01:36
total=?
There are multiple overlapping time line items e.g
Renjee: Cell B 01:23 Cell C 02:23
Renjee: Cell B 01: 40 Cell C 02:40
Basically i need to figure out the exact time logged in i.e 01:23 - 02:40.
Is there a way to work it in excel.
hI,
if I want to Calcutta the total working hours for an employee excluding break time. how I can do this? i.e. below
DUTY IN 23:00
BREAK OUT 0:30
IN 1:00
BREAK OUT 5:00
IN 6:00
LEFT 11:00
act WORKING HRS-....
Thanks
Calculate In to Out time.
In your case
3 time periods
Add all 3 of them.
If all employees strictly use 2 breaks in his shift.
I need to find the total in DAYS you get when you sum a column. My column is in hours.
Hi,
I need to be able to get the time worked from the start time, to the end time, 22:00 hrs start and 06:00hrs end.
Terry
Change the format in cells b2 and c2 to custom [h]:mm:ss
=IF(C2>=B2,C2-B2,C2+1-B2)*24
In cell B2 type in your start time
In cell C2 type in your end time
Copy and paste the top code in Cell D2
Thank you So Much!
You helped me a lot!
OMG!!!! You just saved me so much time!! This formula worked PERFECTLY!!! THANK YOU!!!
I would like to calculate elapse time how do I write a formualae to reflect that for e.g. start time 8:30 a.m. end time 7:40 p.m
=SUM(C9-B9)-D9
in C9 type your start time
In B9 type in your end time
Copy and paste the top line in cell D9
Wouldn't that cause a circular reference?
C9: 8:30
B9: 19:30 (which baffles me to put the End time in B and Stat time in C...?)
Then, in D9, we subtract those two AND subtract D9 itself from that?... ???
(Stop time) - (Start time) = (IF =0, then add one minute to stop time);
(08:00.50) - (08:00.10) = 0 (error)
Thus, 08:01 -08:00.10 = 1 (acceptable)
Query: how do you write the formulae reflecting this?
Thank you
I need to make a cell (minutes late) using 1 cell (Scheduled departure time) being subtracted from another cell (actual departure time). The trick is i need the time starting at 12:00 pm. Ex: Truck leaves at 12:15 am, but the Scheduled time is 11:45 pm. My current sheet shows 23:30 minutes late instead of 30 mins.