by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1645 comments
Hi Svetlana,
i am trying to do conditional formatting on multiple cells. For example, in row B i have 100 values, in row C i have another 100 values - i want to format the cells so that if the value in Row C is over the the value in Row B it will highlight green, and if the value is lower it will highlight in red. The problem i have is i can do this for individual cells but i've tried so many formulas and just can't seem to get it right for multiple cells.
Please please help!
Many thanks and kindest regards in advance
Jamie
Hi, I am facing a similar issue as Jamie has stated. I need to check the values of cells in Row 2 and color code corresponding cells in Row 5. Individual formulas for each cell work, but I am unable to extend formatting collectively over a range.
Please help.
Best Regards
Sreeram R
Hi Sreeram,
Similarly, please make sure you use absolute row references in your formulas, i.e. put a dollar sign before the row number so that it is not changed: C$5.
Hi Jamie,
Most likely you have absolute references in your conditional formatting rules. To compare values in each row, select the cells you want to format and add two rules with an absolute column and a relative row reference, e.g.
=$C3>$B3
You can find more information about the difference between relative and absolute cell references here:
https://www.ablebits.com/office-addins-blog/relative-absolute-cell-references-excel-conditional-formatting/
Hi,
Need help on excel, I would like to know if there any formula for the excel that if I click on a single cell the contents of that cell will reflect on the other cell but the same work sheet.
Example:
The format is
Cell data
A1 1
A2 2
A3 3
A4 4
if I click Cell A1, the data will reflect on
E1 = 1, and if I click cell A2, the data will also reflect to E1 = 2, and so forth.... to which cell I click the data of that cell will still reflect on E1.
Thank You
Hello,
You may be able to do this with the help of VBA in Excel. We don't write macros, but you can post your question on the VBA branches of the following websites: https://www.excelforum.com/ or https://www.mrexcel.com/
I have many entities in cells and i want to sum some maximum out of all the given what i have to do.
Thanks
Hello Zia,
Could you please describe your task in more detail? If possible, please send a sample spreadsheet with your data and the expected results to support@ablebits.com and include a link to this blog post and your comment number.
We'll do our best to assist you.
Anyone know how to compare conditionally formatted colored cells in a column and color a cell in another column? VBA, formula, anything that can do this?
Thanks,
Andrew
Hello Andrew,
Could you specify if you are trying to compare the values of the cells or their colors? If you have a sample spreadsheet you could share with support@ablebits.com, it would help us understand your task and the expected results better.
I have data in 2 different sheets. I want to color the cell of sheet 1 which is not available in sheet 2.
e.g. if sheet 1 contains
Fruit-apple, mango, grapes
Vegetable- cabbage,carrot,potato
in sheet 2 it contains
Fruit-apple, grapes
Vegetable- cabbage,carrot
then mango & potato should be colored out.
Kindly suggest a way to solve this.
Hello Dipun,
You can use the following formula in your conditional formatting rule:
=ISNA(MATCH(A2,Sheet2!A$2:A$5,0))
I have a specific need:
I need a Bar Chart where the colour of a Bar should change based on the text Value in particular column on the table
For. Eg.
Teh followign cell references:
A1: Worktype A | B1: 30
A2: Worktype B | B2: 40
A3: Worktype C | B3: 60
Should show up as WT A - Green Bar; WT B - Orange Bar and WT C - Red Bar
Every time the Work Type repeats in the table, the bar should automatically be of the colour mentioned in the rule. Is this possible?
Hello Rahul,
If you are trying to customize the color of the data series in your bar chart, please see this blog post for detailed steps:
https://www.ablebits.com/office-addins-blog/excel-charts-title-axis-legend/#change-default-chart-colors
If your task is different, please describe it in more detail.
I am trying to use a 3 color scale formatting rule where each row of data contains the low/medium/high standards that should drive the formatting rule. This type of formatting rule doesn't want a relative reference which forces all of the formatting rules to just the very first low/medium/high standard to set the color.
Other web postings suggest highlighting the whole range that the formatting rule should be applied to and then change the cell references to relative from absolute. However, I can't get this to work, excel will not accept a cell reference that isn't absolute.
Hello Tom,
Unfortunately this is a limitation in Excel: you can't use relative references for 3-color scale formatting, icon sets, etc. You either need to create a rule for each line, or specify the start and end points of the range with absolute references.
Hello,
Maybe someone will be able to help me :) Thanks in advance!
The thing is:
I have a value in B5 and this value needs to be in the range "-1% of B3; +1% of B3" to be approved for use. Next problem, I have an empty raw between 3 and 5, that I cannot delete and still need to use the formatting (the same when I have two or three empty raws between values that need to be compared). If value between "-1% of B3; +1% of B3" then the B5 cell gets green.
How can I make it that the formating take the good value to compare it with, and that it ignores empty cells but goes up to the cell where the first value is. This value will change in function of the previous B value.
Is that clear?
Thank you for your help!
Hello John,
You need to create a conditional formatting rule with the following formula:
=ABS(B5)<=ABS(B3/100)
Cannot get this working and am going mad. I've tried all three combos (i.e. $E26, E$26, $E$26 but none works.
Across columns E to M, I want to white out cell(row 27) if cell(row 26) is blank.
So I'm using:
Formula: =$E26="" Applies to: $E$27:$M$27
or
Formula: =E$26="" Applies to: $E$27:$M$27
but neither works. Any/all help would be apreciated. Thanks!
Hello Alison,
If you need to keep the row reference but look at different columns, you need to use the following formula:
=E$26=""
Please make sure you select formatting for the rule, e.g. no background color.
You can find more information about the difference between relative and absolute references in this blog post:
https://www.ablebits.com/office-addins-blog/relative-absolute-cell-references-excel-conditional-formatting/
Very informative article! Great job!
Very informative article. However, I am still stuck. I have tried several formulas but I can't seem to get my spreadsheet to corporate with me.
I am trying to do a conditional formatting formula for the following situation: if C1>1 and A1>10 the C1 text will turn red.
Hope you can help me:)
Thank you,
Heather
Hello Heather,
You can use the following formula to combine both conditions in your rule:
=AND($A1>10,$C1>1)
Is it possible to use conditional format the Text Value of a formula result into two different colors?
eg., if the formula of a cell result is ="GBPUSD", possile to format the "GBP" to Red color and "USD" to Blue color?
Hello Ian,
This is not possible, conditional formatting rules are applied to the selected cells, you can't apply them to values at the moment.
This information was exactly what I needed.
I needed to highlight two columns (Date and Days) if the Days value was < 9 and the Days value is NOT BLANK.
Column E contains a Cutoff Date.
Column F contains the difference in days between Today's date and the Cutoff date: =DATEDIF(TODAY(),E2,"D")
1) Format the Cutoff Date (column E) if it is Styles > Conditional Formatting
- New Rule > Use a formula to determine which cells to format
- Rule: =AND(ISBLANK(F2)=FALSE, F2<9)
-- Applies the rule if column F is NOT BLANK and is < 9
2) Format the Days (column F) if it is < 9 days and is NOT BLANK; highlight the value in RED.
- Applied the same Conditional Formatting as #1 above.
It worked perfectly! Thank you for the great details.
Correction to my initial comment...
1) Format the Cutoff Date (column E) if it is Conditional Formatting
- New Rule > Use a formula to determine which cells to format
- Rule: =AND(ISBLANK(F2)=FALSE, F2<9)
-- Applies the rule if column F is NOT BLANK and is < 9
2) Format the Days (column F) if it is < 9 days and is NOT BLANK; highlight the value in RED.
- Applied the same Conditional Formatting as #1 above.
Hi,
I'm trying to get a conditional formatting to work;
=AND($C2='Calculation Sheet'!$C$32,$AF2<='Template Master'!$D$32)
C2 is a cell that will change between values [R, 1, 2, 3, 4, 5, 6]
and
'Calculation Sheet'!$C$32 currently equals the value "1"
$AF2 value is currently 5
and
'Template Master'!$D$32) value is currently 13
I would like AF2 to change colour if both conditions are met;
When C2 and 'Calculation Sheet'!$C$32 equal the same value "1"
and
The value entered into AF2 is less than or equal to 13
Any help would be great!
Thanks.
Ben
Hi Ben,
Your formula looks correct and it works with the conditions you listed. Could you please specify if you don't get the expected results?
You are the best I have seen so far. My question is, When columb "D" decreases, I would like columb "E" to reflect the date that it decreased. How would I do that? Thank you.
Hi David,
Thank you for your kind words. Regrettably it is not possible to reflect the data change by using conditional formatting. You can create a rule for column D being equal to some value, less than or greater than a certain value, but not for the value increase or decrease.
in conditional formatting. how can compare in three column condition is Only in three which customer is % of growth do not consider -% value
JAN FEB MARCH
63% -22% -22%
250% 45% 45%
331% -8% -8%
101% 20% 20%
260% 34% 34%
21% -63% -63%
76% -6% -6%
556% -59% -59%
47% 116% 116%
290% -74% -74%
pls help
Hi,
If I wanted to fill certain amount of cells in a row to match a value kind of a progress bar how could I do that?
Hi,
I need to set a conditional formatting in cells. I need column m to be highlighted if (m1-n1)>10%
how can i do that?
Thank you!!
You have a great resource here, just taught myself some simple conditional formatting. Now for the hard stuff.
I'd like to use conditional formatting based upon where the cell's data comes from.
I have a spreadsheet that displays information coming from MS Query (which itself gets it from a SQL ODBC).
I just had an end-user supply incorrect information to a doctor because they had copy-pasted a row of old information above the query results.
Is there a way to conditional format the cells based upon where the data comes from? In this case, the erroneous data didn't have an underlying "Edit Query" (Data/Properties) option.
Svetlana, thanks for this great information! I have a question that may be simple, but after toying around for a bit, I can't figure it out. Can you help me with the formula?
My situation is, I want all the cells in Column A to change color when the corresponding cells in Columns T through AC EACH have a Y entered in them.
(The Y means Yes, and the Color Change in A, which contains applicant's names, would signify that the applicant has all parts of their application, where parts are respectively marked as received by a Y in the corresponding column T through AC. Until the cells in columns Y through AC have a Y entered in them, they are left blank).
Are you able to share a formula or advice for this? I am open to further questions, and grateful for your time!
Mike
Hi
I am wanting to use conditional formatting to make a cell D5 green if () 5% and carry this along the row, always using the cell above, so its never the same cell I am wanting to use- is this possible.
Great site! Thanks for all the good info.
I would like to use conditional formatting to color one cell (K7) based on the individual numeric values contained in one column (K8 thru K1000). The individual numeric values in the column (K8 thru K1000) are the result of a mathematical formula. Conditional formatting color of K7 would be based on the value of any individual column value. Example: green for any cell value >5 and red for cell value >10. Thank you in advance for your help.
Hi -
I'm pretty good with lots of excel formulas (counts, database, financial, and the basics), so I must be missing something really obvious here.
I've been using excel all morning, and sent a file to someone for input. After I got the file back, any excel file I open and try to do a basic sum of two rows returns zero.
Cell 1: 100
Cell 2: 3
Cell 3 =a1+a2 returns zero
1. I've checked the calculation window and it is set to automatic
2. I've checked the cell format and made sure it's numbers.
3. I even cut and pasted the cells as values and numbers just in case
what is up?
Thanks!
Hi,
Thanks for the help so far. I'm far better off than when I started, but can't quite get this right.
I'd like to highlight a specific cell; A60, containing text "beef" only if a cell in other ranges (B17:Z17, B19:Z19, B21:Z21, B28:Z28, B35:Z35, B49:Z49) contains text "beef". Is that possible?
Thanks
Amy
I'm trying to count items on a list that are grouped together. For example:
Column A
Dog
Dog
Dog
Dog
Cat
Cat
Cat
Fish
Fish
Fish
Fish
In column B I'm trying to get those numbered:
Column A Column B
Dog 1
Dog 2
Dog 3
Dog 4
Cat 1
Cat 2
Cat 3
Fish 1
Fish 2
Fish 4
Fish 5
Is there a formula that would get me what column B looks like? Right now its a manual process and very time consuming with the amount of data I'm using.
Can I attach and send a small file? Conditional formatting with % in 2013 does not seem to work.
Is there a way using conditional formatting to highlight cells when cells in two adjacent columns are within 10% of each other? So for example if the value of d3 is within 10% of of the value in E3 and the value in e3 is within 10% of of the value in d3, then highlight both e3 and d3.
Hai,
Is it possible to provide conditional formatting from one sheet to another sheet in a work book. (office 2007 version)
i tried with this below equation but i am getting error message.
Please see the equation I tried =Sheet2!$B$1="NO" and the message is " you cannot use references to other worksheet or workbooks for conditional formatting criteria ".
Any solution for this??
Hello, I have a question about conditional formatting.
I am trying to set up a spreadsheet for training at my company. What I would like to do is I want to set up a formula that if a cell does not match another cell, it turns a red color but when it does, it turns a green color. I am pretty sure it is conditional formatting but I am so inexperienced with excel that I have no clue what I am doing. Please help!
You are amazing!
Continued...
So, if either one of the cells in 1 row, has a time that is not 5 min more or not 5 min less (even the same time) than any of the other cells in the same row, it must make them Yellow. So in the below instance all will be yellow.
01-10-15 21:44 01-10-15 21:30 01-10-15 21:45 01-10-15 21:30
I need to do a conditional formatting, where if the time (data format is dd-mm-yy HH:ss) in one cell is less than 5 mins more or less than 5 min less than the other cell.
eg:
A1 A2 A3
01-10-15 21:44 01-10-15 21:30 01-10-15 21:45 01-10-15 21:30
Dear everybody, I have a following problem, and I hope that somebody will help me with that :)
I need to do the following in an Excel document:
If in the column X I have a value "approve" (text value), than the corresponding value from the X-1 column has to be multiplied by 1000 (in the same row, off course).
Is there a formula that can help with this? Thank you so much in advance! Regards, Valentina
I am trying to create a formula for dates and am having a problem. I want to enter a day 1 and the rest of the days populate as needed. I have the rest of the dates formulated so that they populate correctly but I need to figure out how to formulate the day one date in order to make the others follow when I enter day 1. (day 1, day 14, day 21, day 28 and so on). This is a schedule to create dates in the future on specific dates. Like I said I can't get the dates to populate when I enter day 1. Can anyone help?
hi there,
i have created a condtionl formating in colum A, where it has dates, and it will highlight if day i experied in red, 5 days remining amber and 15days yellow "which works really fine. on next colum i want to have a formula which will help me to remove colours from previous colum (condtional rule) if i just type "OK".
Can you help me please ?
hi there,
i have created a condtionl formating in colum A, where it has dates, and it will highlight if day i experied in red, 5 days remining amber and 15days yellow. on next colum i want to have a formula which will help me to remove colours from previous colum if i just type "OK".
Can you help me please ?
I have highlighted some lower and upper values in my cells using conditional formatting.
How can i generate a chart with same colors which i highlighted using conditional format?(i want my chart also to automatically show the colors which i used for the cell)
I'm trying to highlight a cell if it contains certain words: ie. if it says "apple or strawberry or orange" filling it in purple. I want to create multiple rules of the same type but using different words, so one set would be one color and the other set another. But I can't even get this to work! I was trying to use the OR function, this is the last formula I tried.
=OR(strawberry,blueberry,banana,blackberry,orange,apple,raspberry,pineapple,melon)
Hi
If range of cells (all of cell in selected row) are blank,highlight a row
using conditional formatting.
I can highlight a row if a cell is blank but it does not work for range of
cells blank.
What I mean is, if any cell of the selected row has any value or text, I do not want to highlight. I only want to hight rows that are blanks (rage of cell).
Would appreciate your help.
Name Date Address Invoice No Amount
Ganesh 1/1/2015 Uttar Pradesh, India 10215 50
Prem 2/1/2015 Uttar Pradesh, India 10216 1500
Radhe Since B4:E4="" highlight this row
Krishna 4/1/2015 Uttar Pradesh, India 10218 300
Hari 5/1/2015 Uttar Pradesh, India 10219 400
Shiva Since B7:E7="" highlight this row
Shanti 7/1/2015 Uttar Pradesh, India 10221 80
Om Since B9:E9="" highlight this row
Kiram 9/1/2015 Uttar Pradesh, India 10223 700
Good afternoon,
I need to change/increment the date in column 2 by 1, 2, or 3 years in column 3 based on the fill color in column 1.
Name Date Date2
Name1 January 1, 2014 January 1, 2015
Name2 January 2, 2014 January 2, 2016
Name3 January 3, 2014 January 3, 2017
Thanks in advance
Hi,
I don't know if anyone will respond to this or not, but I'm working on an excel spreadsheet and have a tricky conditional formatting question.
I have already formatted column D, but I need help with E. What I am looking to do is this: Column D is the status of a lab, column E is the overall facility status (My four criteria are: lab not being used, lab is down, lab is limited, and lab is up and operational). So, 1=lab is operational, 2=limited, 3=down, and 4=not being used. For column E, I would like to say if the overall facility is operation, limited, down, or not being used. So, if, for example, the labs for one facility (D2-D4) contain at least one status that is down, the facility should also be considered down....and so on and so forth. But, if one of the labs is not being used, but the other two are operational, the facility should be operational.
Is there a way to do this? I have been trying to figure this out for a couple of hours and have had no luck. It seems like all of the formulas I come up with do not narrow down my criteria enough. I do not know SQL stuff...but any other help will be appreciated! Thanks!
Which formulas or conditional formatting can I use to say that IF value in Column I,L,O,R,U,X is than value in Column AG, make it red?
How do I write the code for a list of variables associated to one colour?
So I have a list of codes in a single column - efx, mbc, dad, hif and I want to highlight them all in the same colour.
Does anyone know how I do this?
Thanks
I want my conditional formatting to search column $E (E8:E250)and if it says "Waived" or "Exempt", $G (G8:G250) is crossed out. This is what I have found so far but can not seem to figure out how to add the "Exempt". Also when doing the formatting of the cell it will not allow me to do a cross border within the cell.
=ISNUMBER(SEARCH("Waived",E8))=TRUE
Hi,
I've been searching for ages to get an answer to the following and being a complete novice at excel not having much luck in getting a resolve. Any idea how I can do the following:
I have a s/s with columns of dates and then rows of chargeable and non-chargeble. In the table data I have hours. I need to highlight any non-chargeable work over 0 in red and then any chargeable work over 30 in blue. Can I do this in 1 go by conditional formatting? Please help :)
Hi Keira,
According to your description, it is possible. If you can send us your sample workbook to support2ablebits.com, we will try to help you.
Thanks Alex. Is there an email address for the support2ablebits? Thanks again for looking at this.
Hi,
When using Conditional Formatting:
In cell U2, I would like to populate a formula in the cell if K2 says "Income"
I've tried different ways and I can't get it to work. Help?!
A
Hello ajensen,
Conditional formatting changes a cell's format, but it cannot change the contents of a cell. Probably, it makes sense to enter the following formula in U2:
=IF(K2="Income",YOURFORMULA,"")
Hi Svetlana,
Thx for the great tutorial regarding conditional formatting.
I am having a specific scenario and struggling to find a solution.
I have a data sheet that is sorted by column C and then F.
In my column D, I have dollar values and I need to match the negative ones against the positive ones (but the column C and F values for both negative and positive number must be same) and highlight.
If you could help me regarding this, it would be great.
Thx
I'm not sure if you've already answered this; I've gone through the comments twice and none seem to address my particular situation (unless I'm blind... twice over :p ).
I've created the conditional format:
Cell Value $g$2 | (format red fill) | =$H$2
So if the values in H2 and G2 are not the same H2 has a red fill. What I want to do now is do the same for the rest of my cells from H3:G3 on down the column. The only way I've been able to do this so far is to create a rule for each and every cell which gets quite tedious as some of my lists are 50+ items long. Is there a quicker way to just copy that conditional formating where the cells automatically change with each row?
Hi,
I have a sheet that I want to format.
Column B,C,D will have numbers entered manually (rows 10-50).
Column E will be the sum of B+C+D
Column L will contain a "Y" sometimes.
Here is what I need to do....
I know how to set it up to highlight the highest single value in B or C or D.
And I know how to set it up to highlight the highest value in Column E.
What I don't know how to do is to NOT include in the conditional formatting, any rows where column L has a "Y".
Any assistance is greatly appreciated.
Thank you!
Hello, I’m trying to use Conditional Formatting to Highlight the Header Row cells if any cell in that column is not blank. So I used =ISBLANK(G2:G10000), but when I use the format painter to apply this rule to the adjacent header row cells, the G2:G10000 reference doesn’t change. So, each column header is looking back at G2:G10000. How can I build my Formula so that Conditional Formatting will highlight the Header Row if the cells each column meet the conditions, as I paint the formula across the header? -Thanks, Ron M.