by In this article, you will learn various ways to concatenate text strings, numbers and dates in Excel using the CONCATENATE function and "&" operator. We will also discuss formulas to combine individual cells, columns and ranges.
In your Excel workbooks, the data is not always structured according to your needs. Often you may want to split the content of one cell into individual cells or do the opposite - combine data from two or more columns into a single column. Common examples are joining names and address parts, combining text with a formula-driven value, displaying dates and times in the desired format, to name a few.
In this tutorial, we are going to explore various techniques of Excel string concatenation, so you can choose the method best suited for your worksheets.
What is "concatenate" in Excel?
In essence, there are two ways to combine data in Excel spreadsheets:
- Merging cells
- Concatenating cells' values
When you merge cells, you "physically" join two or more cells into a single cell. As a result, you have one larger cell that is displayed across multiple rows and/or columns.
When you concatenate cells in Excel, you combine only the contents of those cells. In other words, concatenation in Excel is the process of joining two or more values together. This method is often used to combine a few pieces of text that reside in different cells (technically, these are called text strings or simply strings) or insert a formula-calculated value in the middle of some text.
The following screenshot demonstrates the difference between these two methods:
Merging cells in Excel is the subject of a separate article, and in this tutorial, we'll discuss the two main ways to concatenate strings in Excel - by using the CONCATENATE function and the concatenation operator (&).
Excel CONCATENATE function
The CONCATENATE function in Excel is used to join different pieces of text together or combine values from several cells into one cell.
The syntax of Excel CONCATENATE is as follows:
Where text is a text string, cell reference or formula-driven value.
The CONCATENATE function is supported in all versions of Excel 365 - 2007.
For example, to concatenate the values of B6 and C6 with a comma, the formula is:
=CONCATENATE(B6, ",", C6)
More examples are shown in the image below:
Note. In Excel 365 - Excel 2019, the CONCAT function is also available, which is a modern successor of CONCATENATE with exactly the same syntax. Although the CONCATENATE function is kept for backward compatibility, Microsoft does not give any promises that it will be supported in future versions of Excel.
Using CONCATENATE in Excel - things to remember
To ensure that your CONCATENATE formulas always deliver the correct results, remember the following simple rules:
- Excel CONCATENATE function requires at least one "text" argument to work.
- In one formula, you can concatenate up to 255 strings, a total of 8,192 characters.
- The result of the CONCATENATE function is always a text string, even when all of the source values are numbers.
- Unlike the CONCAT function, Excel CONCATENATE does not recognize arrays. Each cell reference must be listed separately. For example, you should use CONCATENATE(A1, A2, A3) and not CONCATENATE(A1:A3).
- If any of the arguments is invalid, the CONCATENATE function returns a #VALUE! error.
"&" operator to concatenate strings in Excel
In Microsoft Excel, the ampersand sign (&) is another way to concatenate cells. This method comes in very handy in many scenarios since typing an ampersand is much faster than typing the word "concatenate" :)
For example, to concatenate two cell values with a space in-between, the formula is:
=A2&" "&B2
How to concatenate in Excel - formula examples
Below you will find a few examples of using the CONCATENATE function in Excel.
Concatenate two or more cells without separator
To combine the values of two cells into one, you use the concatenation formula in its simplest form:
=CONCATENATE(A2, B2)
Or
=A2&B2
Please note that the values will be knit together without any delimiter like in the screenshot below.
To concatenate multiple cells, you need to supply each cell reference individually, even if you are combining contiguous cells. For example:
=CONCATENATE(A2, B2, C2)
Or
=A2&B2&C2
The formulas work for both text and numbers. In case of numbers, please keep in mind that the result is a text string. To convert it to number, just multiply CONCATENATE's output by 1 or add 0 to it. For instance:
=CONCATENATE(A2, B2)*1
Tip. In Excel 2019 and higher, you can use the CONCAT function to quickly concatenate multiple cells using one or more range references.
Concatenate cells with a space, comma or other delimiter
In your worksheets, you may often need to join values in a way that includes commas, spaces, various punctuation marks or other characters such as a hyphen or slash. To do this, simply put the desired character in your concatenation formula. Remember to enclose that character in quotation marks, as demonstrated in the following examples.
Concatenating two cells with a space:
=CONCATENATE(A2, " ", B2)
or
=A2 & " " & B2
Concatenating two cells with a comma:
=CONCATENATE(A2, ", ", B2)
or
=A2 & ", " & B2
Concatenating two cells with a hyphen:
=CONCATENATE(A2, "-", B2)
or
=A2 & "-" & B2
The following screenshot demonstrates how the results may look like:
Tip. In Excel 2019 and higher, you can use the TEXTJOIN function to merge strings from multiple cells with any delimiter that you specify.
Concatenating text string and cell value
There is no reason for the Excel CONCATENATE function to be limited to only joining cells' values. You can also use it to combine text strings to make the result more meaningful. For example:
=CONCATENATE(A2, " ", B2, " completed")
The above formula informs the user that a certain project is completed, as in row 2 in the screenshot below. Please notice that we add a space before the word " completed" to separate the concatenated text strings. A space (" ") is also inserted between the combined values, so that the result displays as "Project 1" rather than "Project1".
With the concatenation operator, the formula can be written this way:
=A2 & " " & B2 & " completed"
In the same manner, you can add a text string in the beginning or in the middle of your concatenation formula. For example:
=CONCATENATE("See ", A2, " ", B2)
="See " & A2 & " " & B2
Join text string and another formula
To make the result returned by some formula more understandable for your users, you can concatenate it with a text string that explains what the value actually is.
For example, you can use the following formula to return the current date in the desired format and specify what kind of date that is:
=CONCATENATE("Today is ",TEXT(TODAY(), "mmmm d, yyyy"))
="Today is " & TEXT(TODAY(), "dd-mmm-yy")
Tip. If you would like to delete the source data without affecting the resulting text strings, use the "Paste special - values only" option to convert formulas to their values.
Concatenate text strings with line breaks
Most often, you would separate the resulting text strings with punctuation marks and spaces, as shown in the previous example. In some cases, however, there may be a need to separate the values with a line break, or carriage return. A common example is merging mailing addresses from data in separate columns.
A problem is that you cannot simply type a line break in the formula like a usual character. Instead, you use the CHAR function to supply the corresponding ASCII code to the concatenation formula:
- On Windows, use CHAR(10) where 10 is the character code for Line feed.
- On Mac, use CHAR(13) where 13 is the character code for Carriage return.
In this example, we have the address pieces in columns A through F, and we are putting them together in column G by using the concatenation operator "&". The merged values are separated with a comma (", "), space (" ") and a line break CHAR(10):
=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2
The CONCATENATE function would take this shape:
=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)
Either way, the result is a 3-line text string:
In the same manner, you can separate final strings with other characters such as:
- Double quotes (") - CHAR(34)
- Forward slash (/) - CHAR(47)
- Asterisk (*) - CHAR (42)
- The full list of ASCII codes is available here.
How to concatenate columns in Excel
To join two or more columns, just enter your concatenation formula in the first cell, and then copy it down to other cells by dragging the fill handle (the small square that appears in the lower right hand corner of the selected cell).
For example, to combine two columns (column A and B) delimiting the values with a space, the formula in C2 copied down is:
=CONCATENATE(A2, " ", B2)
Or
= A2 & " " & B2
For more information, please see How to merge two columns in Excel without losing data.
Combine text and numbers keeping formatting
When concatenating a text string with a number, percentage or date, you may want to keep the original formatting of a numeric value or display it in a different way. This can be done by supplying the format code inside the TEXT function, which you embed in a concatenation formula.
In the beginning of this tutorial, we have already discussed a formula that concatenates text and date.
And here are a few more formula examples that combine text and number:
Number with 2 decimal places and the $ sign:
=A2 & " " & TEXT(B2, "$#,#0.00")
Number without insignificant zeros and the $ sign:
=A2 & " " & TEXT(B2, "0.#")
Fractional number:
=A2 & " " & TEXT(B2, "# ?/???")
To concatenate text and percentage, the formulas are:
Percent with two decimal places:
=A12 & " " & TEXT(B12, "0.00%")
Rounded whole percent:
=A12 & " " & TEXT(B12, "0%")
How to concatenate a range of cells in Excel
Combining values from multiple cells might take some effort because the Excel CONCATENATE function does not accept arrays.
To concatenate several cells, say A1 to A4, you need to use one of the following formulas:
=CONCATENATE(A1, A2, A3, A4)
or
=A1 & A2 & A3 & A4
When combining a fairly small group of cells, it's no big deal to type all the references. A large range would be tedious to supply, typing each individual reference manually. Below you will find 3 methods of quick range concatenation in Excel.
Method 1. Press CTRL to select multiple cells
To quickly select several cells, you can press and hold the Ctrl key while clicking on each cell you want to include in the formula. Here are the detailed steps:
- Select a cell where you want to enter the formula.
- Type =CONCATENATE( in that cell or in the formula bar.
- Press and hold Ctrl and click on each cell you want to concatenate.
- Release the Ctrl button, type the closing parenthesis, and press Enter.
Method 2. Use TRANSPOSE function to get all cell values
When a range consists of tens or hundreds of cells, the previous method may not be fast enough as it requires clicking on each cell. In this case, you can use the TRANSPOSE function to return an array of values, and then merge them together in one fell swoop.
- In the cell where you want the result to appear, enter the TRANSPOSE formula, for example:
=TRANSPOSE(A1:A10)
- In the formula bar, press F9 to replace the formula with calculated values. As a result, you will have an array of values to be concatenated.
- Delete the curly braces surrounding the array.
- Type =CONCATENATE( before the first value, then type the closing parenthesis after the last value, and press Enter.
Note. The result of this formula is static as it concatenates the values, not cell references. If the source data changes, you will have to repeat the process.
Method 3. Use the CONCAT function
In Excel 365 and Excel 2021, this simple formula will concatenate a range of cells in a blink:
=CONCAT(A1:A10)
Method 4. Use the Merge Cells add-in
A quick and formula-free way to concatenate any range in Excel is to use the Merge Cells add-in with the "Merge all areas in selection" option turned off, as demonstrated in Combining values of several cells into one cell.
Excel "&" operator vs. CONCATENATE function
Many users wonder which is a more efficient way to join strings in Excel - CONCATENATE function or "&" operator.
The only real difference is the 255 strings limit of the CONCATENATE function and no such limitation when using the ampersand. Other than that, there is no difference between these two methods, nor is there any speed difference between the CONCATENATE and "&" formulas.
And since 255 is a really big number and you will hardly ever need to combine that many strings in real work, the difference boils down to comfort and ease of use. Some users find CONCATENATE formulas easier to read, I personally prefer using the "&" method. So, simply stick with the technique you feel more comfortable with.
Opposite of CONCATENATE in Excel (splitting cells)
The opposite of concatenate in Excel is splitting the contents of one cell into multiple cells. This can be done in a few different ways:
- Text to Columns feature
- Flash Fill option in Excel 2013 and higher
- TEXTSPLIT function in Excel 365
- Custom formulas to split cells (MID, RIGHT, LEFT, etc.)
You can also find useful information in this article: How to unmerge cells in Excel.
Concatenate in Excel with Merge Cells add-in
With the Merge Cells add-in included in Ultimate Suite for Excel, you can efficiently do both:
- Merge several cells into one without losing data.
- Concatenate the values of several cells into a single cell and separate them with any delimiter of your choosing.
The Merge Cells tool works with all Excel versions from 2016 to 365 and can combine all data types including text strings, numbers, dates and special symbols. Its two key advantages are simplicity and speed - any concatenation is done in a couple of clicks.
Combine values of several cells into one cell
To combine the contents of several cells, you select the range to concatenate and configure the following settings:
- Under What to merge, select Cells into one.
- Under Combine with, type the delimiter (a comma and a space in our case).
- Choose where you want to place the result.
- Most importantly, uncheck the Merge all areas in the selection box. It is this option that controls whether the cells are merged or their values are concatenated.
Combine columns row-by-row
To concatenate two or more columns, you configure the Merge Cells' settings in a similar way but choose to merge columns into one and place the results in the left column.
Join rows column-by-column
To combine data in each individual row, column-by-column, you choose:
- Merge rows into one.
- Use a line break for the delimiter.
- Place the results in the top row.
The result may look similar to this:
To check how the Merge Cells add-in will cope with your data sets, you are welcome to download a fully functional trial version of our Ultimate Suite for Excel below.
That's how to concatenate in Excel. I thank you for reading and hope to see you on our blog next week!
Available downloads
Concatenation formula examples (.xlsx file)
Ultimate Suite 14-day trial version (.exe file)
447 comments
When i concatenate =1&2&3&4&5 it gives 12345
In my program i want to remove any one of the items, say 4
and it should show 1235.
Can any one guide me how to do it?
Thank you
Just minus 11110
concatenate =1&2&3&4&5 it gives 12345
then integer =int (12345) above value-11110
your answer will be there.
Hello,
If there a way to Concatenate and use Right at the same time?
Ex: 123456 to ***456
Doing so with on one column, ID number is 123456 then ID number 2 would be ***456
Thank You
Hello, Jess,
if your ID is in A1, then enter the following in B1 to get ***456:
=CONCATENATE("***",RIGHT(A1,3))
hi am trying use double code text file to be upload.
pls refer.below sample format.
"IH","INV-3456","2007-11-20","1","1","TESTING","2","1","AED","1000","CIF","","","",""
"ID","1234","03056980","NormalHSCode","N","kg","1","kg","1000","m","","1000","US","123456789012345","1","12352","","","11"
please help
Can u Please help me??
How can we find Price(numbers) from letters?
eg.A B C D
a 1 ab 12
b 2
c 3 bc 23
.....................
In column D i want the values of merged letters...
please help me
Can u Please help me??
How can we find Price(numbers) from letters?
eg.A B C D
a 1 ab 12
b 2
c 3 bc 23
In column D i want the values of merged letters
Sub Code()
' Range("C17").Select
' Selection.Copy
' Sheets("Sheet2").Select
' Range("B10").Select
' ActiveSheet.Paste
For x = 2 To 24
con = ""
Sheets("BB").Select
state1 = Cells(x, 9).Value
district1 = Cells(x, 10).Value
village1 = Cells(x, 12).Value
Sheets("AA").Select
For y = 2 To 60
state2 = Cells(y, 10).Value
district2 = Cells(y, 11).Value
village2 = Cells(y, 13).Value
If state2 = state1 And district2 = district1 And village2 = village1 Then
con = Cells(y, 15).Value = Cells(y, 15).Value + ("y14", " , ","x15")
'Sheets("BB").Select
Cells(x, 16).Value = Cells(x, 16).Value + ", "
End If
Next
Next
End Sub
y there is an error in concentation
thank u
how to add a space between word and number (Ex:ACT222) In a single cell.
Thank You.
If the text and numbers are always in blocks of 3 and 3 (e.g. ACT222, BOB876 etc.) then (assuming data is in cell A1):
=CONCATENATE((MID(A1,1,3))," ",MID(A1,4,3))
Hi Svetlana,
Great website. Is there vba formula that could help sort my text strings like this:
House1
House2
House3
Truck1
Truck2
Truck3
Result
House1|House2|House3
Truck1|Truck2|Truck3
Thank you.
Hello, Preston,
we don't build VBA formulas, but we can provide another option which you may find useful.
If your data starts in A1, enter the next formula in B1:
=INDIRECT(ADDRESS(ROW()*3-2,1))&" | "&INDIRECT(ADDRESS(ROW()*3-1,1))&" | "&INDIRECT(ADDRESS(ROW()*3,1))
This will return House1|House2|House3
and copy the formula to the row(s) below (read how do to it here) to apply for other group(s) of the data.
Hope it helps!
Hi,
After concatenation I want any part (any one of the cells to be concatenated) of the result as BOLD ITALIC. How to do it with VB and without VB?
Thanks.
How to connect text string for varing range given below
Input:
ST1 Cataract
ST2 Macular degeneration
AMD
ARMD
ST3 Diabetic retinopathy
nonproliferative retinopathy
diabetic eye disease
leaking blood vessels
ST4 vitreous hemorrhage
extravasation of blood
leakage of blood
ST5 Macular hole
macular break
Output:
ST1 Cataract
ST2 Macular degeneration OR AMD OR ARMD
ST3 Diabetic retinopathy OR nonproliferative retinopathy OR diabetic eye disease OR leaking blood vessels
.....
Since range is not fixed for each output how to use CONCATENATE or any other function
How can I concatenate two dates?
Column A: 3/1/17
Column B: 3/5/17
What I want for Column C: 3/1/17 - 3/5/17
Is there a formula for this? I seem to only be able to find formulae for text and not dates.
Nevermind I found it :)
=CONCATENATE(TEXT(A1,"dd/mm/yyyy")," - ",TEXT(B1,"dd/mm/yyyy"))
I have two columns with dates. Most times each column has data but some do not. I want to concatenate the two date columns into a single column. Here is what I am using: =TEXT(D2, "m/d")&" - "&TEXT(E2, "m/d"). This is working perfectly except when one of the columns is blank I get this result: 10/31 - 1/0. I want the formula to return just the single date when one column cell is blank. Help?
=IF(E2="",TEXT(D2, "m/d"),TEXT(D2, "m/d")&" - "&TEXT(E2, "m/d"))
Hi,
I have 3 columns, each column have a text. But there are cells which does not have any text and when I concatenate it leave two spaces. Please help how this can be sorted.
Thanks.
For example.
how are you how are you
how you how you
I want to perform set theory operation like A union B and A intersection B operation on two cells containing comma separated numerical values in two cells without repeating the values.
Kindly help me
Hi,
I have data in 2 column, same values repeated in both column need unique concatenate value for combination ex-
ColumnA ColumnB
A B =CONCATENATE(A2,"_",B2)
B A
C D
D C
Required unique concatenate A_B(for B_A also)
Result should
A_B
A_B
C_D
C_D
Pease help for given concatenate and vlookup formula
Thanks
=IF(B2>A2,CONCATENATE(A2,"_",B2),CONCATENATE(B2,"_",A2))
Hi,
the value are 4.89 &
this value in separate (not decimal place) Ans : = 4.00
how to use formula in this value..
thanx..
Hi,
A B
1 BMW 2010
2 2001 4.6L
3 2002 1999
4 2003 Honda
5 Chevy 1978
6 3.5L 602384
7 128435 2008
I want to keep just the data that looks like an YEAR from the 2 columns(A,B).
I tried to write a function that looks at A1 and see if it's a number with the character limit lower than 5, and if YES, to bring over the cell, if NOT to leave a blank space.
=if(ISNUMBER(LEN(A1)<5), A1, " ")
I tried something more complicated like this.
=if(ISNUMBER(LEN(A1)<5), A1, if(ISNUMBER(LEN(B1)<5), B1," "))
I wanted to look at A1 to see if it's a number with length<5, and if yes to bring over the cell, if NOT to look at B1 if it's number with length<5 and bring it over, and if NOT to leave a blank space.
Still didn't work.
I've tried this way as well using the & in the argument.
=if(ISNUMBER(A1)&LEN(A1)<5, A1, " ") or
=if(ISNUMBER(A1)&LEN(A1)<5, A1, if(ISNUMBER(B1)&LEN(B1)<5, B1, " "))
Still NO luck.
What am I doing wrong? :(((
Thank you in advance for any tip :D
name S/O, D/O
saira ali khan
mehboob ali ghulam ali
how i use formula concatenate here ? please help
Hi All,
It would be great help if you can suggest me best formula for below report.
[My Data is like....]
Name Visited Planned Date
------ ------- ------------
Red Yes 07/10/2016
Blue Yes 09/10/2016
Red Yes 10/10/2016
Green Yes 11/10/2016
Green No 12/10/2016
Red No 13/10/2016
Blue Yes 14/10/2016
[I need report like below....]
Name Visit Dates
------ ------------
Red 07/10/2016; 10/10/2016
Blue 09/10/2016; 14/10/2016
Green 11/10/2016
Please suggest best formula to create report. Data will be added regularly in my data tracker. And report will be updated automatically.
Please help. Thanks in advance.
Hi All,
I have formula =(C21-D21)/C21.
I want to change C and D in the formula based on some other cell value like.
Ex: cell H20 and I20 , if i enter A in H20 and B in I20 then formula should become =(A21-B21)/A21. 21 is dynamic(Range is 21 to 678 in table)
Thanks in Advance
Dears hi,
i have date in format dd,mmm,yyyy
date is
16-01-2017
17-01-2017
But want as in text format like
'16-01-2017
'17-01-2017
any one can help with this
thank you
hello all;
i want to concatenate cells from sheet 1 according to certain criteria
and i successfully did. But the problem i face now, if i insert new line between existing lines in the sheet 1 the function will skip the new line.
any idea how to make it on all lines?
Thank you
Regards
CORRECTION
Hello All,
I spent great deal of time trying to solve my case by searching on the web
for the correct Excel formula, but unfortunately I'm still looking for it.
I saw a lot of samples, videos, tutorial…still not yet found what I’m
looking for. I’m must confess, I’m new in this and it’s quite hard to
find the correct formula for the following problem (pretty tricky):
I have an article with Id# 300045 and this article has 5 pictures – 300045,
300045k, 300045ak, 300045bk.
I want to retrieve all 5 pictures to this specific Id 300045 as follows:
COL A COL B COL C COL D COL E
300045 300045 300045k 300045ak 300045bk
300045k 990099 990099k 990099bk
300045ak 915501 915501k
300045bk 915502
300045ck 930045 930045ak 930045kk
990099
990099k
990099bk
915501
915501k
915502
930045
930045k
930045ak
930045kk
Any ideas?
Thank you for your help.
Best regards,
Miguel
Hey,
I am using the concatenate command to put a group of things together. One of the numbers is a sum of a bunch of numbers from another page and when not formatted it has a number of digits after the decimal point (17.9476930697) In the original cell I have it formatted to only show 2 digits after the decimal point but when I run the command the formatting resets and shows every number after the digit point.
I have multiple cells and multiple lines so just "hard inputting" the number isn't much of an option and its a document that could undergo revisions.
Is there anyway to format numbers within a concatenate command?
Cheers,
The ROUND function can be used to change the number of decimal places being shown when you are concatenating - e.g. text in cell A1, number with 9 decimal places in B1. The following will reduce to the number part to 2 decimal places:
=CONCATENATE(A1,ROUND(B1,2))
hello all,
I have a situation need your advise on how to get my intended result in excel.
In sheet1--> column C --> row 10, I have a sentence / description referring to a sum of quantity (say 250MT) which is a sum of various units in sheet2 (say sum of 10 containers detailed with various other information).
the question is how to merge the cell of sum in sheet2 In sheet1--> column C --> row 10.
Appreciate your advise by email.
thank you
This is a really useful article. It allowed me to build my own simple binary converter in Excel. Thanks!
Hi Everyone,
I Do Make sale sheets for my company in excel, In A1 I put a company Name and and B1 i put the representative from our marketing team, like wise i already made a sheet with thousand companies and representative,i want that when i write a compan name while making sales sheet so the representative name auto fill in cell by the date above which i made,
can any one help me out for this.
How to concatenate ROW and COLUMN values?
I am trying to join text with number cell with CONCATENATE. Now number cell is formatted as if minus its in Red and if plus its written in blue. is it possible to reflect the same formatting with CONCATENATE?
Column A
330
340
320
232
343
Column B
05
05,08,09
03,04,08
01,02,05,06,07,03,04,08,09
06,01 0.45 23207
Price
0.50
0.25
0.98
0.58
0.45
Find_Price (After concatenation of column A & B)
33005
34008
32004
34009
23207
Dear All, I have a query related to mix of concatenate and lookup, so please see below my requirement and help for the same.
Column A Column B Price Find_Price
330 05 0.50 33005
340 05,08,09 0.25 34008
320 03,04,08 0.98 32004
232 01,02,05,06,07,03,04,08,09 0.58 34009
343 06,01 0.45 23207
I have a list of employee IDs with corresponding data, some employees have multiple rows of information. I'm trying to create a single row for each employee by moving the 2nd & 3rd lines of information onto a single line. Some employees have just one line, others 2 and some 3. Can a do an if statement to see if cell row below = cell row above & then concatenate? What happens to empty cells in the selection of cells?
Is there a way to grab the first initial of the word in column A and concatenate it with the contents of column B?
Column A Column B Column C
Jim Noriega JNoriega
John Doe JDoe
I was wondering if there is a way to concatenate based on if function.
Please see below.
Thank,
Input
--------|Class 1|Class 2|Class 3
Person 1-|---x---|-------| ---x---|
Person 2-|---x---|---x---| -------|
Person 3-|---x---|-------| ---x---|
Output
Class 1 Person 1, Person 2, Person 3
Class 2 Person 2
Class 3 Person 1, Person 2
I was wondering if there is a way to concatenate based on if function.
Please see below.
Thank,
Input
Class 1 Class 2 Class 3
Person 1 x x
Person 2 x x
Person 3 x x
Output
Class 1 Person 1, Person 2, Person 3
Class 2 Person 2
Class 3 Person 1, Person 2
Hello
If someone can help to take out and flight and combine the total sum of each destination
1.FEBRIANA/SALSABILA MS F BWN BKK YO A 051H I-BI796 SUB
1PCS 10KG
2.HABTESELSSIE/MELA MISS F BWN BKK YS A 049C I-BI828 BKI
1PCS 11KG
3.ISKANDAR/FRANS HUBE MR M BWN BKK YQ A 030A I-BI796 SUB
M 2PCS 20KG
4.KUSUMADEWI/LANYAWA MRS F BWN BKK YQ A 030B I-BI796 SUB
H 2PCS 20KG
Re:above
I should have said I only want to concatenate the ID numbers based on the ones who said no.
Hi
On one tab I have 2 rows of columns, 1 is an ID number and the other a simple yes or no response.
I only want to concatenate the results of those who's answer is No to another tab (lets say from tab B & tab A)
My range of ID's is B6:B35 and responses of Yes/No is K6:K35.
Each time I do this I am getting all ID's coming through so I'm not sure how to exclude these in a formula. I'm not experienced with macro's so that won't be an option if that's the only way to do it.
If it can't be done in one formula then that my next option is to create and hide a column on tab B that shows relevant ID's based on an IF function so that if there is no way to concatenate all values individually across two columns, I will be able to get the ones I need from one column. I'm just wondering there's a tidier way (hope that makes sense).
Thanks in advance.
Ian
Dear all,
it is possible to "force" Excel in some way, to count with the string, constructed by CONCATENATE, as the function?
For explanation - I have this data: CONCATENATE(„=“;“1″;“+“;“1″) and I need the result to see as "2" and not only as "=1+1"
Any idea?
Thanks for your answer in advance!!!
Hi Richard,
For this, use the embedded SUM function like this:
=CONCATENATE("=";SUM(1+1))
Hi Svetlana, yes, it count the embedded numerical example, but the result is still the string in the shape "=2". I need some solution, where the result is not a string, but the completely counted function (i.e. only "2").
In real, I have a little bit complicated data in my sheet, "1+1" is only example for easy explanation of my problem.
Richard,
The result of the Concatenate function is always a text string. If you want to return a number, use SUM or SUMIF function, or a combination of Sum functions. It's not possible to advise an exact formula without knowing the details of your task.
I have this data. May I know how can I achieve the results in column C by input (what) formulas? Thanks alot.
A B C
Name Code Formulas Results
P1 002 002, 003
P1 003
P2 004 004, 006, 007
P2 006
P2 007
P3 005 005, 008
P3 008
JUVITA F. RENDIZA in 1 column.. i would like to separate then in each column for Last name- Firtsname- Middle Name.. pls give me the formula
lots of thanks
How do I combine if i have a multiple rows like this
9005a
9006a
9007a
9008a
9010a
9011b
9032c
9033a
9034a
9035a
9113b
9114a
I want the result to be like this
9005a thru 9008a, 9010a, 9011b
but i only have limited number characters lets say i only have 50 characters. and the following series of numbers should be on the next row above the first result. it shows like this,
Row 1 : 9005a thru 9008a, 9010a, 9011b
Row 2 : 9032c thru 9035a,9113b, 9114a
and there should have ni repeatetive number.
Thank You in advance!
What do I write, if I want to have the output from referencing a large amount of cells, like =CONCATENATE(S33:S94), but I want a " " between each of the cell values?
In this case you should reference each cell individually and insert spaces in between, like this:
=CONCATENATE(S33, " ", S34, " ", S35, " ", ..., S94)
If you have too many values this would take forever. I found an easier solution. I had to merge the values of 2000 cells down a column, say column B, into one cell with a | between each value. Listing 2000 cells individually would have taken forever.
In C2 I put the formula =CONCATENATE(B1&"|"&B2)
Then, in C3 I put =CONCATENATE(C2&"|"&B4)
Copy the 2nd formula down as far as you want. In a moment I ended up with cell C2000, that had 2000 values all in one cell separtaed by |.
For the second formula I meant in C3 put =CONCATENATE(C2&"|"&B3)
Please Somebody tell me I need formula i want that Suppose any mathematics digit add in any person name how can i get any mathematics digit add in any Person name to apply by formula.
Sir,
May I apply concatenate formula for more then 1000 cell.
A1 B1
Aug-16 BR BANDAR
How do I combine both of above cells (A1 & B1) into "Bandar August-16" by dropping the word "BR" ?
Hi Asmiza,
Does A1 contain a date in the mmm-dd format or text "Aug-16"? You can check this by selecting cell A1 and viewing the value in the formula bar.
If it's a date, you can use the following formula:
=TEXT(A1, "dd-mmmm") &RIGHT(B1,LEN(B1)-SEARCH(" ",B1)+1)
If it's a text, then use this one:
=A1 &RIGHT(B1,LEN(B1)-SEARCH(" ",B1)+1)
hi All,
How to convert 3-10-10-10-10001 In 310101010001. ?
Please Help
Hello Azeem,
You can use Excel's Find and Replace feature (Ctrl+H) and replace dashes with nothing, i.e. you type a hyphen (-) in the "Find what" box, leave the "Replace with" box empty and click Replace All.
Hi
I'm combining two cell using formula CONCATENATE. first cell contains different formats in single cell i.e. CYBER-METRIC and ARIAL. other cell has text content.
final Result is changing the whole content into ARIAL format.
we need text to be just the same as cell1 with mix of different format (i.e. Both cyber-metrics & Arial in single Cell).
Please tell whether it is possible or not.
Hi, Hope you can help
I have Column A and Column B
in Column A, I have A1 to Axx
In column B , I have B1 to Bxx
I need to create a list something like this
A1:B1 A2:B2 A3:B3......Axx:Bxx
So I can use something like this
=CONCATENATE("List ",B1,":",D1," ",B2,":",D2," ",Bxx,":",Dxx )
My question is, how can I enter all the cells in the column easily?
Thanks in advance
hi
my doubt is ,if i can use concatenate for the below data ,
SL NO NAME DOCS TO BE TAKEN OUTPUT SHOULD BE
123 HARI SALARY SLIP SALARY SLIP,MARKSHEET EXP CERT
123 HARI MARKSHEET
123 HARI EXP CERT
124 TIM SALARY SLIP SALARY SLIP, EXP CERT
124 TIM EXP CERT
125 LOGAN SALARY SLIP SALARY SLIP