Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4506 comments

  1. Hi

    I have a question...

    I have 3 columns

    A is the year
    B is either jetski or boat
    C is the answer sheet

    I would like it that if A is blank it gets an error message in C

    If its jetski in B then C displays £15
    If its boat in B then C displays £25
    if its neither in B then there is an error message in C

    Thanks.

  2. Hi I am running a score prediction league with some friends and need a formula that will give the following:

    4 points for correct score (e.g 2-0 predicted and actual score is 2-0)

    2 points for correct result and margin of goals but incorrect score (e.g 2-0 predicted and actual score is 3-1)

    1 point = correct result (e.g 2-0 predicted and actual score is 1-0)

    0 points= incorrect result (e.g 2-0 predicted and score is 0-2)

    In terms of my excel file the actual score will go in Column G (home team goals) and column H (away team goals)
    And the predicted score will be in column J (home team goals) and column K (away team goals).

    Any help would be greatly appreciated as I have tried multiple formula's with no luck so far! Thanks

    • Anyone able to help with the above? Thanks

  3. Hi,
    sir can i classify letters into different columns according to no. of letters by using if formula...?
    For Example,
    1 2 3 4
    a am aim arms

  4. I'm not sure IF is the right function to use with my excel. I have a huge list of data with name and items. How can i generate every item with the same name?

    eg:
    Cell A | Cell B
    1. John | Bread
    2. May | Butter
    3. Henry | Tomato
    4. John | Carrot
    5. Kylie | Bread
    6. John | Apple
    7. John | Butter

    My output, i need to list what item John buying.

    Cell A10 | Cell B10 |Cell C10 | Cell D10 | Cell E10
    John | =IF(ISNA(INDEX(B1,MATCH(A10,A1:A7,0)),"-",INDEX(B1,MATCH(A10,A1:A7,0)) | =IF(ISNA(LOOKUP(2,1/A1:A7=A10),B1:B7)))"-",LOOKUP(2/1(A1:A7=A10,B1:B7) |

    Im unsure what to put in D10 and E10, to complete the list of item for John.
    can anyone help?

  5. column 1 "H/RENT ~ CQ#4018598" need to return CQ#4018598
    column 2 "REC:01 JBL/02/ILM LC- 009322010166 " need to return 009322010166
    column 3 "IT PRODUCT ~ CQ#4752400" need to return CQ#4752400
    column 4 "REC:05 JBL/02/ILM LC- 009329910166 " need to return 009329910166

    So how can i find them in one formula.

  6. i can use help to determine an equation for the following:

    we're running a contest where a certain quantity of sales above 5 earns the rep 2x the tickets for sales beyond that. The data should look like this:
    3 sales = 3 tickets
    4 sales = 4 tickets
    5 sales = 5 tickets
    6 sales = 7 tickets
    7 sales = 9 tickets
    8 sales = 11 tickets

    6 or more sales gets the rep 2x tickets on that sale. can someone help me?

  7. IF D1=PASS, and D2=PASS as well as D3=PASS, then CELL D4=PASS OR VICE VERSA.
    IF THERE ARE CELLS HAVING 2 PASS THEN ITS PASS, IF THERE ARE CELLS HAVING 2 FAILS THEN ITS FAILS.

  8. I want single formula for below quivery. I want calculate PF in different categories to calculate.

    If he have pf than only we deduct 12% on Basic+Da, if he dot have pf than not to deduct and Normally we have calculate pf 12% on Basic+DA on salary, The sealing limit is 15000, If he cross 15000 employee has give permission letter to deduct on actual if they not given written acceptance than we will take cutt of 15000 only.

    1) His Salary (Basic+Da) is 5000/- but he dot have pf
    2) His salary is (B+D) is 10000/- he done pf
    3) his salary is (B+D) is 17000/- he done pf but not given acceptance letter
    4) His salary is (B+D) id 18000/- he done pf but he given acceptance letter
    all of four query i want single formul.

  9. Hello,
    I've looked through the blog and the posts and cannot find an answer, so I appreciate any help you can give.
    Currently I have this formula
    =IF(EXACT(N1,"Done"),IF(M1"",M1,NOW()),"")
    I want to maintain the timestamp in "M" cell right after changing data in "N" cell and have new data in "L" cell.

    =IF(EXACT(N1,"Done"),IF(M1"",M1,NOW()),"") and IF(EXACT(N1,"Modeling Request"),IF(L1"",L1,NOW()),"")

    is this possible ?

  10. Recommended: If UOM (I5) cell will be mlg then Total in KGS (K5) cell result Converted Milligram to KGS. If UOM (I5) cell will be grm then Total in KGS (K5) cell result Converted gram to KGS.

    Please someone help me in this formula.

  11. Recommended: If UOM (I5) cell will be mlg then Total in KGS (K5) cell result Converted Milligram to KGS. If UOM (I5) cell will be grm then Total in KGS (K5) cell result Converted gram to KGS.

  12. I have excel report having 10 columns with multiple dates and blanks mentioned as NULL from report.
    Samples as
    A1 = 10-Mar-22, A2 = 30-Mar-22, A3 = 14-Apr-22, A4 = NULL, A5=NULL, A6 to A10 = NULL
    B1 = 10-Mar-22, B2 = 30-Mar-22, B3 = 14-Apr-22, B4 = 30-Apr, B5=10-May, B6 = NULL
    C1 = 10-Mar-22, C2 = 30-Mar-22, C3 = 14-Apr-22, C4 = 30-Apr, C5=10-May, C6 = 30-May, C7 = 30-Jun, C8 = 10-Jul

    Etc.,
    I need the formula to get me the latest date from this and skip the rows. Can you help me.

  13. Hello I hope someone can help with the formula for this particular condition.
    An if formula where if the cell contains Adequate and Moderate its appears on the next column as No. And yes if it contains Low and Critical. I tried using this formula
    =IF(AND(O18=“LOW”,O18=“CRITICAL”),"No", "Yes")
    but it does not work the closest I got is
    =IF(O18="CRITICAL", "YES", "NO")
    but it only recognizes critical and not low

    • Hi!
      I’m not sure I got you right since the description you provided is not entirely clear. However, it seems to me that the formula below will work for you:

      =IF(OR(O18="LOW",O18="CRITICAL"),"No", IF(OR(O18="Adequate",O18="Moderate"), "Yes",""))

      All the necessary information is in the article above.

  14. Hi, I like to add below logic if you can help me to convert in formula...

    Cell "A2" is Date

    If A2>=Today(),"Valid",IF A2<=6Months,"Near to Expire","Expire"

    If A2 is greater or equal to today's date enter "Valid", if A2 is less then 6months date from today enter "Near to Expire", if A2 is less then today's date enter "Expire".

    Pls help to solve this formula... Regards,

  15. I like to add If =IF(C34>=TODAY(),"Valid","Expire",if(C34<=6month,"Near to Expire"))
    pls correct this logic... regards,

  16. Can someone please help with providing a formula for the below problem:

    I would like to see 7:00 when its 7:00-7:04 and then 7:05 if the time is 7:05-7:09 and 7:10 if 7:10-7:15, and so on.

    this is my formula the hour is working fine but I'm having difficulties with the minutes.
    =IF(HOUR(NOW())=12, "12",IF(HOUR(NOW())>12,HOUR(NOW())-12,HOUR())))&":&"IF(MINUTE(NOW())<5,"00","05),IF(MINUTE(NOW())<10, "05","10"))))

  17. lets say i have 2 tables one of them is month table and the other is the number of every item in the store, i want a function that can solve what i will say, if i added number 2 to the october column(this means that i took 2 items from a specific row from the store table in at october) so how can i write a formula that makes the specific row subtract the number ive added to the other table?regarding the month for example ive added 2 to s2 how can i let excel make e2-the number that ive added to s2 and so on

  18. =IF($C39="M",$J$3-Data!B$8*5,IF($C39="T",$J$3-Data!C$8*5,IF($C39="W",$J$3-Data!D$8*5,IF($C39="TH",$J$3-Data!E$8*5,IF($C39="F",$J$3-Data!F$8*5)))))

    Okay, this is my formula it is calculating perfectly if you put in the M,T,W,TH,F individually but if I put two letters in the box like M,T it wont calculate. I need it to recognize more than one of the letters then take the calculation from each letter and subtract them from my J3 cell. help?

      • It is still not doing exactly what I need. I need it to do the follow say M=5, T=6, W=6, TH=6, F=5, if any of the letters are in the cell for example if I put W/T/F in the cell I need to add what each letter equals together then subtract that product from the value of another cell.

  19. Hi i want to know how can i create formula for
    {'B1' greater than '10' and 'D1' less than '5000', then 'C2' 1, if not 'C2' 0} and {B1' greater than '10' and 'D1' between 5001 and 10000, then 'C2' 1, if not 'C2' 0} and {B1' greater than '10' and 'D1' greater than '10000', then 'C2' 1, if not 'C2' 0}

  20. Hi there, I am producing a scorecard and have number of calculations to produce an overall score. Below this, I have put in a rank formula to give each individual and rank between 1 and 4. This is where I need assistance, below this I would like the cell to tell me which individual is ranked #1 - from their individual named cell (elsewhere in the worksheet) - how is this possible?

    • Hi!
      As it's currently written, it's hard to tell exactly what you're asking. Please describe your problem in more detail. Include an example of the source data and the result you want to get.
      To find the name of a person with rank 1, you can use the INDEX MATCH formula.

  21. Hello I have the following table that we use as our acceptance criteria for testing. The sample size determines how many outliers are allowed. For example if the sample size is 8, only 1 outlier is allowed for the sample to be accepted. There is one cell that captures the sample size selected, and 2 cells which capture how many outliers were identified. Below is the example formula I have created that works for one particular sample size.

    =IF(AND(H2=20,E46<4,F46<4),"Accept","Reject")

    I would like to capture each of the following sample sizes and testing criteria into one cell that would read "accept" or "reject". Applying the testing criteria based on the sample size captured in cell H2, then the allowable outliers.

    Total Sample Size Outliers
    Accept Reject
    2 0 1
    3 0 1
    5 1 2
    8 1 2
    13 2 3
    20 3 4
    32 5 6
    50 8 9
    80 12 13

  22. hi,
    please help me on this

    in my 1st column, 5 different item names on dropdown list,
    in my 2nd column, 5 different location names on dropdown list,
    3rd column quantities I'm going to enter number quantities i have.
    so i need a table with sum of the quantity i have entered respective to the conditions mentioned.

    note: if i'm selecting different conditions from the dropdown list, the quantity entered must go to respective cell under same condiiton

  23. Please help me, I have a condition that says "For every full 100, 10 has to be added."

    For example if I have $500 in a cell, then I must get/add $10 for every $100 in that $500.

  24. I need a formula that performs the following if cell in column a Sheet A contains word from Sheet1 column a then return sheet1 column B to cell in column B sheet A

  25. I am trying to have the cell (Status) auto change the data list drop down (drop down list: blank, Not Started, In Progress, Complete, Delayed) to "Delayed" (cell C6) if the cell (End Date) is past due (cell F6) is this a formula or conditional formatting or both. If so what should the formula be?

  26. How to do 2 conditions with count output?
    I tried this formula "=IF(AND(">=1000","<=2000"),"=COUNT(I2:I25)","0")" but I only get #VALUE! error.
    is it possible?

  27. I am trying to get the IF function for 2 variables in a cell. I want excel to give 1 if the cell has either of the variables and 0 if it doesn't have either likewise.

    This is the formula i came up with and it doesn't work - =IF(AND(U2="Strongly Confident", U2="Slightly Confident"), 1,0)

  28. Demurrage Conditions Criteria

    Upto 06 hrs. Rs.150
    07 hrs. to 12 hrs. Rs.165/
    13 hrs. to 24 hrs. Rs.187.5/
    25 hrs. to 48 hrs. Rs. 225
    49 hrs. to 72 hrs. RS. 300
    73 hrs. and above Rs. 450

    Data
    Demurrage Hours wagons
    72 58
    47 54
    13 51
    3 60
    8 45
    94 47

    eg 72*58*300=RS. 1252800
    eg 47*54*225=571050
    hours*wagons*rate=net amt
    How to calculate in excel with formula plz suggest i tried many time but failure

  29. Hello, I'm trying to follow the above guidance but I don't believe any of the examples quite match my scenario. Any assistance anyone could please provide would be greatly appreciated. I have two columns of data which I need to apply specific conditions to achieve one of three outcomes "Low", "Medium" or "High". Think of a matrix but my issue is the values in my data are too varied to match specific matrix headings. I've copied the below to help demonstrate what I am trying to achieve, apologies if it appears untidy:

    J2 Data
    H2 Data <70 <50 <40 <30 <20 0-20
    70,H2>0,"LOW"),IF(AND(J2>70,H2=0,"MEDIUM"),IF(AND(J2>50,H2>500,"LOW"),IF(AND(J2>50,H2>0,"MEDIUM"),IF(AND(J2>40,H2>1500,"LOW"),IF(AND(J2>40,H2>1,"MEDIUM"),IF(AND(J2>30,H2>4000,"LOW"),IF(AND(J2>30,H2>499,"MEDIUM"),"HIGH"))))))))

    So it's as if Excel likes the formula (due to no error messages) but it is producing the wrong false logic output ("false" instead of "high"), plus due to the values the cell should actually produce a true result of "medium".

    Can anyone please help?

    Thank you

    • As feared, the table did not post correctly and it appeared to be merged into my formula. hopefully you get the idea of the problem. Below if the formula I currently have:

      =IF(AND(J2>70,H2>0,"LOW"),IF(AND(J2>70,H2=0,"MEDIUM"),IF(AND(J2>50,H2>500,"LOW"),IF(AND(J2>50,H2>0,"MEDIUM"),IF(AND(J2>40,H2>1500,"LOW"),IF(AND(J2>40,H2>1,"MEDIUM"),IF(AND(J2>30,H2>4000,"LOW"),IF(AND(J2>30,H2>499,"MEDIUM"),"HIGH"))))))))

        • Thank you Alexander, that has worked perfectly :)

    • Hi!
      Unfortunately, your explanations are not enough to understand the problem. The formula is not fully written. Explain what result you want to get. Give an example of the source data and the expected result.

  30. Hi,
    I'm trying to create an "IF" formula with multiple conditions, so for example If( AB1=70%,AB1<100%),"(AB1-70%)*3.33,......). The 70%/100%/3.33 i have replace it with link to another tab (That way i can change there the values there instead of the formula, but if I want to add one extra layer how can i do it without modifying the formula?
    This is my current formula.
    =+IF(KC277='New Scales'!$A$17,KC277='New Scales'!$A$18,KC277='New Scales'!$A$19,KC277='New Scales'!$A$20,'New Scales'!$B$20,"check")))))

  31. hy,
    i need some help,
    i whant to set value to cell B1 to be max 250 and in a enter in B1 let say 300 the deference betwin them to by on C1

    thx

    • Thx for help
      But i whant cell B to stay at max 250 and the diference to go to cell C
      Cell B is dinamic number not all the time will be 250. , it will be 250, 255, 300,,,,500 and i whant the diference to go to cell C
      when i change whit =IF(B1>250,B1-250,"") and put 300 cell B stay at 300 and cell C is ramaining 50

      Thx

      • Hi!
        If the formula is written in cell C1, then it cannot change the value in B1. This can be done with a VBA macro. I have written about this on this blog many times.

  32. Hi sir,
    I am applying formula for different columns. For example
    =IF(B2>0,"good",IF(C2>0,"v.good",IF(B2>0,"excellent","check")))
    It is just assumed formula but columns are same... And data in columns are getting from different data sheets by using lookup. The issue which is face if the data is available in B column then i got results but it doesn't forward formula to C or D if value is not available in B.. so please help in this regard...

  33. Hi -- Just want to start with how much your site and tutorials have helped me on my Excel journey. They are so easy to understand and VERY helpful. Thank you for that !!!

    Following is my list:
    92
    Satisfactory
    86
    70

    I would like to score this list but my formula is not scoring the text correctly. Following is my formula:

    =IF(OR(A3>=90,A3="Superior"),5,IF(OR(A3>84.9,A3="Above Average"),4,IF(OR(A3>79.9,A3="Satisfactory"),3,IF(OR(A3>59.9,A3="Below Average"),2,IF(OR(A3<60,A3="Unsatisfactory"),1,3)))))

    The field showing Satisfactory is coming back with a score of 5, but I would expect a 3. Any assistance you can provide is GREATLY appreciated.
    Thank you !!!!

    • Hello!
      Excel can compare text and numbers. Therefore, add to the formula a test of cell A3 for a number. To do this, use the ISNUMBER function.

      =IF(OR(AND(ISNUMBER(A3),A3>=90),A3="Superior"),5, IF(OR(AND(ISNUMBER(A3),A3>84.9),A3="Above Average"),4, IF(OR(AND(ISNUMBER(A3),A3>79.9),A3="Satisfactory"),3, IF(OR(AND(ISNUMBER(A3),A3>59.9),A3="Below Average"),2, IF(OR(AND(ISNUMBER(A3),A3<60),A3="Unsatisfactory"),1,3)))))

      This should solve your task.

      • That worked !!! Thank you so much !!!!!!

  34. Please help, I'm a newby and not very advanced, so I beg your patience.

    If cell c2 = D, I want to return the value in D2 in a positive state
    if cell C2 = C, I want to return the value in D2 in a negative state

    ie. Debit Credit

  35. I was able to successfully code 2 of the 3 things I need my formula to do, however, the 3rd part keeps coming up false when added to the formula. I am looking for some help if possible. Here is what I need the formula to do:

    If the A19 cell has an entry of HOLIDAY OR VACATION, I want $25.00 to show in the C19 cell, OR if the A19 cell has an entry of SICK I want the entry listed in C20 to show in the C19 cell.

    This is the first part that works with HOLIDAY & VACATION, but the second part for SICK does not.

    Successful: =IF(OR(ISNUMBER(SEARCH("HOLIDAY:",A19)),ISNUMBER(SEARCH("VACATION:",A19))),"$25.00")

    Not Successful: =IF(OR(ISNUMBER(SEARCH("HOLIDAY:",A19)),ISNUMBER(SEARCH("VACATION:",A19)),"$25.00",ISNUMBER(SEARCH(“SICK:”,A19))),=C20)

  36. Hi can you Help here. My formula is not testing all condition. The #N/A values are not getting all tested.

    =IF((AND(ISNA(G18147),H18147<30)),"Text A",IF((AND(G1814729,ISNA(G18147))),"TEXT C",IF((AND(G18147>29,ISNA(H18147))),"Text D",IF((AND(G18147>29,H18147>29)),"Text E",IF((AND(G18147>29,H18147<30)),"Text F",IF((AND(G1814729)),"Text G",IF((AND(G18147<30,H18147<30)),"Text H"))))))))

    IN this, text B and Text D condition is returning a #n/A value and not testing for the conditions after it like e,f,g,h.

    Any help ?

    -Nishnt

    • Hi!
      Your formula contains syntax errors in a nested IF statement. The formula might look like this -

      =IF(AND(ISNA(G18147),H18147<30),"Text A",IF(AND(G18147>29,ISNA(G18147)),"TEXT C",IF(AND(G18147>29,ISNA(H18147)),"Text D",IF(AND(G18147>29,H18147>29),"Text E",IF(AND(G18147>29,H18147<30),"Text F",IF(AND(G18147>29),"Text G",IF(AND(G18147<30,H18147<30),"Text H","")))))))

      For more information, please visit: Nested IF in Excel – formula with multiple conditions.

  37. Hi Sir,
    Can we consolidate different excel sheets data into one sheet by using formula??
    (Example: sheet1 has x user production report
    Sheet2 has y user production report
    Sheet 3 has z user production report. I need all x, y and z report in sheet 4 with the same headings.

      • Hi sir,

        Merge and index will not be work on my task as it contains huge data.

        Each user having different reference #, and BU code and other details..

        Example;
        Reference|BU Code| User Name|Initiated Date| Status| Closed Date|Doc #| Vendor ID|Description Details |PIC|Entity|Exception code all these fields has to be appear in sheet 4
        And we will not be having any common factor in sheet 4.
        Basically whatever the data pasted in sheet 1,2,3 should be reflect in sheet 4 without doing manually (copy paste)
        Could you please assist on this.

        • I have got the answer! Thank you.

          Implemented VBA for consolidation.

          As below code:
          Public Sub CONSOLIDATE()

          Dim i As Integer

          For i = 1 To Worksheets.Count - 1

          Worksheets(i).Select
          Range("a2").Select
          Range(Selection, Selection.End(xlDown)).Select
          Range(Selection, Selection.End(xlToRight)).Select
          Selection.Copy

          Worksheets("report").Select
          Range("A1048576").Select
          Selection.End(xlUp).Select
          ActiveCell.Offset(1, 0).Select
          ActiveSheet.Paste

          Next i

          End Sub

  38. Hello,

    Can anyone help me. How do i formulate this:
    if value is >=3250 but not greater than 3749.99, type 157.50?

  39. In cell G3 use a function to determine the position of the employee, which is determined by:
    If the pay type is W and the Annual salary is greater than 20000 then the position should be Upper Senior
    If the pay type is W and the Annual salary is 20000 or less then the position should be Upper Junior
    If the pay type is S and the Annual salary is greater than 20000 then the position should be Lower Senior.
    If the pay type is S and the Annual salary is 20000 or less then the position should be Lower Junior.

  40. Hi Sir, I'm looking for a formula in the following condition:

    if B2 is Samsung then take 5
    if B2 is Nokia then take 10
    if B2 is LG then take 15
    if B2 is Mi then take 20

    please help me

  41. i am trying with formal but actually it working only till above 5K only as below:

    IF(E2<=500, "Paid", IF(E2=5000,"Above 5k", IF(E2>=10000,"Above 10k", IF(E2>=20000,"Above 20k", IF(E2>=40000,"Above 40k", IF(E2>=60000,"Above 60k", IF(E2>=80000,"Above 80k" ))))))))

    0 Paid
    0 Paid
    8,833.36 Above 5k
    12,965.89 Above 5k
    2,644.26 Less 5k
    88,654.84 Above 5k
    15,801.28 Above 5k
    4,320.72 Less 5k

  42. How to implement below in Excel formula

    Example

    If Mexico than Latin
    If India,china,bhutan,japan then asia
    Else europe

    Other are not included here.

  43. Please can you help me to calculate the number of interlocking stones to be produced?

    6,680kg - Stone dust
    25kg - Cement

    to produce 50 pieces ( 1m2)

    I want it in such a way that whenever I input the quantities of cement and stone dust, it will give me the number to be produced.

  44. I'm not sure if this is possible. I've been struggling with it for a couple of hours:

    I need a conditional formula that is conditional on the value in a single cell. For example
    If F2="Apple" and E3>F3 then G3=1 or 0 if second condition isn't met but,
    If F2="Orange" and E3>1 then G3=1 or 0 if second condition isn't met but,
    If F2="Grape" and E3>F3 then G3=1 or 0 if second condition isn't met but,
    If F2="Banana" and E3>1.5 then G3=1 or 0 if second condition isn't met and etc.

    Typing it out sounds sort of irrational but I feel like there should be a way that I can manipulate the formulas. Any ideas?

    • Hello!
      If I understand your task correctly, try the following formula:

      =IF(OR(AND(F2="Apple",E3>F3),AND(F2="Orange",E3>1),AND(F2="Gape",E3>F3),AND(F2="Banana",E3>1.5)),1,0)

      You can read more details here - IF AND OR formula.

      • I did not see your response as I was typing my own. My apologies. This formula works perfectly! Thank you!

    • I figured out how do do what I mentioned above. For anyone reading this that may find it helpful, in the above example the formula that goes in cell G3 would be:

      =IF(OR(AND(F2="Apple", E3>F3), AND(F2="Orange", E3>1), AND(F2="Grape", E3>F3), AND(F2="Banana", E3>1.5)), 1, 0)

  45. I'm not sure if this is possible. I've been struggling with it for a couple of hours:

    I need a conditional formula that is conditional on the value in a single cell. For example
    if F2=Apple

  46. I am trying to work a formula with the following:

    T1= Week 1 and U1 = 4 calculate D3/4
    T1= Week 2 and U1 = 4 calculate D3/2
    T1= Week 3 and U1 = 4 calculate (D3/4)*3
    T1= Week 4 and U1 = 4 enter D3
    T2= Week 1 and U1 = 5 calculate D3/5
    T2= Week 2 and U1 = 5 calculate (D3/5)*2
    T2= Week 3 and U1 = 5 calculate (D3/5)*3
    T2= Week 4 and U1 = 5 calculate (D3/5)*4
    T2= Week 5 and U1 = 5 enter D3

    Tried the following formula but it doesn't seem to work

    =IF(OR(AND($T$1="Week 1",$U$1="4",D3/4),AND($T$1="week 2",$U$1="4",D3/2),AND($T$1="Week 3",$U$1="4",(D3/4)*3),AND($T$1="Week 1",U1="5",D3/5),AND($T$1="Week 2",$U$1="5",(D3/5)*2),AND($T$1="Week 3",$U$1="5",(D3/5)*3),AND($T$1="Week 4",$U$1="5",(D3/5)*4)),D3)

    Can you help?

    • Hello!
      For the first four conditions, use a nested IF function. It is impossible to combine all conditions in one formula, as they contradict each other. For example, the first and fifth conditions can return TRUE at the same time.

      =IF(AND(T1="Week 1",U1=4),D3/4, IF(AND(T1="Week 2",U1=4),D3/2, IF(AND(T1="Week 3",U1=4),D3/4*3, IF(AND(T1="Week 4",U1=4),D3,""))))

      I hope it’ll be helpful.

      • Thank you - this is helpful!

  47. Hope someone can help me figure this out.
    I have a column "date rented" formatted mm/dd/yyyy.
    What I need to do is the following numeric values returned based on tenant's length of stay:
    If 5 years and 10 years and 5 years and 30 years then 5

    • Hope someone can help me figure this out. I have a column "Birth Date".
      What I need is return the following numeric values based on the Date column
      - If Birth Date 2 years and 5 years and 10 years then 4

  48. Can you please help me to get a suitable formulas for :

    Cell Number : B5

    (B5) Not Exceeding 53846 - (C7*10%)
    (B5) Exceeding 53846 but not exceeding 75000 - (C7*12.5%)
    (B5) Exceeding 75000 - (C7*15%)

    Please ignore my previous message. it was a mistake.

    Thanks

    Samad

  49. Can you please provide me with assistance for a multiple "IF" formula, using the following conditions;

    If the value in cell B27 is between 15 and 17, then the answer = 350
    If the value in cell B27 is between 18 and 19, then the answer = 800
    If the value in cell B27 is between 20 and 24, then the answer = 1350
    If the value in cell B27 is greater than 24, then the answer = 2350
    If the value in cell B27 is less than 15, then the answer = 0

    So far I have come up with the following formula for the first condition:

    =IF(AND(B27>15,B27<18),350,0

    This works, but when I try to add the other conditions I get an error. Can you please show me what I need to do to add the other criteria to this formula correctly.

    • Oops, I meant =IF(AND(B27>14,B27<18),350,0)

      • Hi Alexander,

        Thanks for your reply, it is very much appreciated.

        However, your formula didn't quite work properly. I have made the following adjustment to your formula and this now works fine.

        =IF(B27>24,2350,IF(B27>19,1350,IF(B27>17,800,IF(B27>14,350,0))))

        Thanks again for your assistance.

        Kind regards,
        Collis

  50. Thank you in advance for your help. I am having a problem coming up with a formula to:

    If cell 2 is blank do nothing, if cell 1 is greater than cell 2 do nothing, if cell 1 is less than cell 2 subtract cell 2 from cell 1.

    Any help you can offer would be appreciated.

    • Hi!
      I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
      I’m not sure I got you right since the description you provided is not entirely clear. However, it seems to me that the formula below will work for you:

      =IF(A1 < A2,A1-A2,"")

      • Thank you for responding but your formula got cut off. All I got was =IF(A1.

          • Thank you but my problem is still that if cell A2 is empty I want it to do nothing. As it is now if cell A2 is empty it is counting it as zero and deducting zero from cell A1 and showing the amount. I guess I forgot to point out this formula is being used in cell A3. That probably makes a difference. Sorry about that.

              • Sorry to keep bothering you but I am still getting a calculation if the cell is empty. To be more specific in G13 I am looking for a formula that will do nothing if E13 is empty or if D13 is more than E13. If E13 is less than D13 I want G13 to show D13-E13. The formula I am using is:

                =IF(E13=“”,””,IF(D13>E13,D13–E13,””))

                Everything works except that when E13 is empty G13 is showing D13-E13 which it is counting as zero. In the scenario I want G13 to do nothing at all.

                Again sorry to keep bothering you but I have been working on this for hours. Lol

              • Hi!
                The formula you wrote down doesn't match the formula I gave you. Look carefully.
                The conditions you wrote contradict each other.
                "if D13 is more than E13" - "do nothing"
                "If E13 is less than D13"- "show D13-E13"
                But "if D13 is more than E13" and "If E13 is less than D13" - this is the same.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)