by The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.
Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.
The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.
Excel COUNTIFS function - syntax and usage
The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 365, 2021, 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.
COUNTIFS syntax
The syntax of the COUNTIFS function is as follows:
- criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
- criteria1 (required) - sets the condition in the form of a number, cell reference, text string, expression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
- [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.
In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold.
Excel COUNTIFS - things to remember!
- You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
- Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
- Both contiguous and non-contiguous ranges are allowed.
- If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
- You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.
How to use COUNTIFS and COUNTIF with multiple criteria in Excel
Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.
How to count cells with multiple criteria (AND logic)
This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.
Formula 1. COUNTIFS formula with multiple criteria
Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).
The task can be accomplished by using this formula:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
And the count is 2 ("Cherries" and "Lemons"):
Formula 2. COUNTIFS formula with two criteria
When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.
For example, here's the right formula to count items that have 0 both in column B and column C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns.
Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).
How to count cells with multiple criteria (OR logic)
As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.
But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.
Formula 1. Add up two or more COUNTIF or COUNITFS formulas
In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:
=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")
In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")
Formula 2. SUM COUNTIFS with an array constant
In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:
In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:
=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))
In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:
=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))
You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
How to count numbers between 2 specified numbers
By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.
Formula 1. COUNTIFS to count cells between two numbers
To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:
=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")
Formula 2. COUNTIF formulas to count numbers between X and Y
The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.
How to use cell references in COUNTIFS formulas
When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.
In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")
Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells.
For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.
How to use COUNTIFS with wildcard characters
In Excel COUNTIFS formulas, you can use the following wildcard characters:
- Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
- Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.
Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.
Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.
Here is the formula that works a treat:
=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))
Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&""
COUNTIFS and COUNTIF with multiple criteria for dates
The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.
Example 1. Count dates in a specific date range
To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.
For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Example 2. Count dates with multiple conditions
In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Example 3. Count dates with multiple conditions based on the current date
You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.
For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.
=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY())
This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:
=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())
This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!
2006 comments
If column "A" has date values such as 1/1/2016 and column "C" has numeric values 1,2,3,4...how would i count the amount of times "1" appears in column "C" through the dates 1/1/2016 to 1/31/2016 in Column "A". Thanks!
I'm using the countifs function, trying to count non blanks from a previous column that used concatenate. Example:
Column D is a function =concatenate(A1:A3,B1:B3)
A B D
1 a a
2 b c bc
3
=countifs(D1:D3,"*") gives me 3. But this is wrong. Should be 2. Cell D3 is considered a non empty.
How do I solve it?
Best, Erez
Hello
I'm currently using multiple countif functions to extract records from a raw data table (in one worksheet) into a date and time summary table (in another worksheet) which is then conditionally formatted to identify trends in the form of a heat map. On the conditionally formatted worksheet users have the option of using drop down lists to model different options.
The problem I have is only "one" choice can be made from each drop down list at a time. How do I modify my current countif formulas to count "All" from the drop down list?
My data tables are too long and complex to include on this post. But below are the three current formulas I have been using within the date and time table:
1. =COUNTIFS(Speed20209,">="&'Time Chart 20209'!$B$2,Direction20209,'Time Chart 20209'!$B$3,Date20209,'Time Chart 20209'!$B8,Time20209,"="&'Time Chart 20209'!$B$2,Direction20209,'Time Chart 20209'!$B$3,Date20209,'Time Chart 20209'!$B8,Time20209,">="&'Time Chart 20209'!D$6,Time20209,"="&'Time Chart 20209'!$B$2,Direction20209,'Time Chart 20209'!$B$3,Date20209,'Time Chart 20209'!$B8,Time20209,">="&'Time Chart 20209'!Z$6)
Regards
Jade
I am trying to count total number of leaves taken by resources in month of working hours of 7.5 data with resources Ids in column A and attendance of each day in columns B, C & so on....
Sum of Total Time Column Labels
Row Labels 8/2/2016 8/3/2016 8/4/2016 8/5/2016 8/6/2016 8/8/2016 8/9/2016
BVNP6428 7:30:00 7:30:00 7:30:00
KNRG6427 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00
MAPR1554 7:30:00 7:30:00 7:00:00 7:30:00 7:00:00 7:30:00 3:30:00
MUNB6429 7:10:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00
NRYV6432 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00 7:30:00
SBSP6433 1:30:00
STVL6431 7:30:00 7:30:00 7:30:00 7:30:00
please can you provide me a help i how to count total number of leaves taken by a resources some time its half-day leave which is 3.75 and others full day leave... Thanks
Hi,
I'm trying to count the occurrence of special characters in a field.
the special characters i'm looking for include:
{"%","[","'","#","!","*","&","(",")","~","\","`","{","^","}","\","|","/","?",">","","<",",",";",":","+","]","=","ì","ü","û","ë","▒","│","├"}, 'Data Sheet'!A2:A29153))), "YES", "None")
However, cannot find a way to make it count the total sum of occurrence or return the the occurrence of each separated by a comma (which would be amazing.
Thanks
I want to check the active (using "1" active, "0" non-active) customers with 4
conditions,
Check date e.g. 9 Aug 2016
1 2 3
Start date e.g. 2 May 2016 29 Aug 2016 2 May 2016
End date e.g. 1 May 2017 27 Aug 2017 1 May 2017
Suspend date e.g. 29 Aug 2016 8 Aug 2016
Restart date e.g. 3 Sep 2016 29 Aug 2016
Answer should be "0" "1" "1"
Hello Kenneth,
To help you better, we need a sample table with your data in Excel and the result you want to get.
You can email it to support@ablebits.com. Please add the link to this article and your comment number.
In example #1 for Countifs for text values, what if you want to know how many students passed two or more of the classes?
Hello Adam,
It will be quicker and easier to do this using a helper column.
E.g. column G contains the number of exams passed by each student:
- Enter =COUNTIF($B2:E2,"P) into G2
- Copy the formula down to the other cells
- Then the formula =COUNTIF(G2:G20,">=2") will show the number of students that meets your criteria.
Thank you. One last question....If they passed two or more classes, what equation would list their name.
Hi Svetlana,
I have a table:
Product Store Date
P1 S1 1-Aug-2016
P1 S2 2-Aug-2016
P2 S1 1-Aug-2016
P1 S1 3-Aug-2016
I need the data for P1 is 2 and P2 is 1. Can you help what the formula is?
Thanks
Hi Svetlana,
I have a table:
Product Store Date
A S1 1 Jan 2016
A S2
B S1
C
OPEN Range From Range To Frequency
1855 1850 1950 4
1895 1951 2050 9
1924 2051 2150
1938 2151 2250
=COUNTIFS($A$2:$A$422,">=1850",$A$2:$A$422,"=1850",$A$2:$A$422,"=B2 (Cell) & <=C2 (Cell name) so that i can drag rather than manually entering 1951 - 2050, 2151 - 2250 and so on
Hi Team,
Can any one suggest how to write =COUNTIFS(B2:B7,"=P",C2:C7,"=P",D2:D7,"=P",E2:E7,"=P") this formula using VBA,any help can be appreciated,
Thanks ,
NAgaraju
Hi
Am wondering if you can help me.
I am trying to have excel calculate the number of times the value in cells D6:D583 contains a value ">=3" AND cells C6:C583 contains a value of "Blue"
I don't want it to calculate / include the values in D6:D583 if the value of C6:C583 doesn't contain "Blue"
I've unsuccessfully tried:
=COUNTIFS($D$6:$D$583,">=3",$C$6:$C$583,"Blue")
=COUNTIF(D6:D583,">=3")+COUNTIF(C6:C583,"=Blue")
Any help you could give would be much appreciated.
Thanks
Hello Svetlana, I've been trying unsuccessfully to find a formula to count numbers that start with certain digits.For example, in a range that includes: 4040345, 40503543, 4065678, 4067865, 4079876, I want Excel to count only those numbers that start with "406" (2 in this case). I tried a combination of Countif + Left but it did not work. Do yo have any idea of a formula that does this calculation? Thank you!!!!!
Hi Diana,
You can use an array formula similar to this:
=SUM(--(NUMBERVALUE(LEFT(A1:A100,3))=406))
Where A1:A100 is the data range with your numbers.
Please remember to press Ctrl+Shift+Enter to complete the array formula correctly.
How can i group the numbers in column A to show in coloumn B that they are between 1 to 1000, 1001 to 2000, 2001 to 3000?
21
83
921
1888
2702
2465
2571
20
1559
376
2087
2849
809
955
I have an excel sheet with 50 rows. In "Status" column I have 10 "Apples", 15 Mangoes", 3 "Oranges", 12 "Grapes", 6 "Banana", 4 "Cucumber". I want to count fruits (except Cucumber ie. 50-4 -46) by using COUNTIFS. Pls help me.....
HI MAM
PLEASE HELP ME, HOW CAN I SEPARATE OR BREAK BELLOW NUMBERS BASED ON DEPARTMENT & DIVISION BY USING FUNCTIONS
DIVISION Department Basic salary No pay Gross salary
MKT G 18,033.00 46,668.64
MKT F 13,892.00 31,921.94
MKT D 150,000.00 254,000.00
MKT D - 278,850.00
MKT D - 150,000.00
MKT D - 108,000.00
MKT M - 625,000.00
MKT G 20,800.00 27,700.00
AGR G 13,826.67 21,107.60
MKT G 14,000.00 1,400.00 16,100.00
MKT G 25,000.00 26,500.00
PRO F 20,000.00 23,500.00
MKT G 20,000.00 23,750.00
MKT M 15,000.00 600.00 22,787.50
how can count >= 8AM and <= 12PM below
08/02/2016 8:16:00 AM
05/03/2016 11:07:00 AM
17/02/2016 2:55:00 AM
19/02/2016 11:44:00 PM
Please give formula
If column a has" x" or" y" than column b has "5" or "100" or "10" so count "text" from column c
Sorry i rephrase my question:
Hi, how can I create a formula that references a date range in a first column and counts the number in the second column corresponding to that date range.
In the example below i'm trying to create a formula that selects the full date range but only calculates the number of 2 between 1/1/16 and 7/1/16.
In the example below the answer is "4"
Thanks so much
1/1/16 2
2/1/16 2
3/1/16 0
4/1/16 0
5/1/16 0
6/1/16 2
7/1/16 2
8/1/16 0
9/1/16 0
10/1/16 0
11/1/16 0
12/1/16 0
13/1/16 0
14/1/16 0
15/1/16 0
16/1/16 2
17/1/16 2
18/1/16 2
Hi, how can in the example below have the number of 2 between 1/1/16 and 7/1/16.
In the example below the answer is 4
Thanks so much
1/1/16 2
2/1/16 2
3/1/16 0
4/1/16 0
5/1/16 0
6/1/16 2
7/1/16 2
8/1/16 0
9/1/16 0
10/1/16 0
11/1/16 0
12/1/16 0
13/1/16 0
14/1/16 0
15/1/16 0
16/1/16 2
17/1/16 2
18/1/16 2
Hello - I am working with a COUNTIFS. I have the data pulling correctly, however, since I am pulling based on date ranges & my raw data has a time stamp in it, I have researched that I need to nest an INT formula. However, when I nest it, it does not work.
This is my formula, where 'YTD Opened Issues'C:C is the date of the help desk ticket. Dashboard A6 is the start date of the date range & Dashboard B6 is the end date of the date range.
=COUNTIFS('YTD Opened Issues'!$C:$C,">=" &Dashboard!$A6,'YTD Opened Issues'!$C:$C,"<=" &Dashboard!$B6)
Right now, this formula appears to not be pulling the count in for tickets that fall on the last day of the date range. I did a test on the YTD Opened Issues tab & used the INT function on the ticket created date, then kept my formula as is, this solved my issues.
However, I want to be able to not have to modify the raw data pulled out for metric reporting.
Any help on how to nest this INT in my current function would be greatly appreciated!!
hi everybody,
i want to count the selected cells with count if condition.
=COUNTIF(B4:B9,"<5) This is normal and work perfect.
and now i need this type the range will be different cells like
=COUNTIF((B4,C5,B18,B25,V14),"<5") this is not working but i need this way to count the cells.
I dont know this is logically correct.
anybody know this ????
please help me..
I need assistance with trying to average 3 arrays while one range has negative time stamps. The question is to find anyone in the ED, excluding mimics. Its returning 08:49 when the correct calculation should be 07:63
=TEXT(SUMIFS(AG19:AG98,J19:J98,"ED",L19:L98,"Mimic")/COUNTIF(AG19:AG98,">=0"),"hh:mm:ss")
1 56 5 8
2 89 6 5
3 6 12 6
3 9 36 11
3 7 8 12
Count the Cell in table which are properly divided by 3. Put the value of above table in A1:D5. and put the formula in cell F1.
i love every examples discuss in this section am just new to it an am studying for the first time if i encounter any problem i get back to the forum to say my challenges
Hi. what is the formula if i am counting the # of days present in a week and should have corresponding value. let say, 5 days in and a half-day and per day is $250. what is the formula for this?? thanks so much for the help.
In the beginning I thought this problem can be solved with Countifs but after many failed attempts to solve this I am not sure anymore! Hope anyone can help me.
Goal is to calculate number of rejects that occurred in a certain week. I have defined the start date and end date of a weeknumber.
Year Week StartDate EndDate #Rejects
2016 1 04-01-2016 10-01-2016
2016 2 11-01-2016 17-01-2016
2016 3 18-01-2016 24-01-2016
2016 4 25-01-2016 31-01-2016
2016 5 01-02-2016 07-02-2016
In column E (#Rejects) I want to calculate the number of rejects in that particular week.
On the same worksheet I have the registration of a reject. This lists the date a product is rejected and when the rejected product is repaired (=CompleteDate)
Reject# RejectDate CompleteDate
1 12-01-2016 15-01-2016
2 13-01-2016 16-01-2016
3 18-01-2016 25-01-2016
4 19-01-2016 13-02-2016
5 12-01-2016 21-02-2016
This means:
Reject#1 was in week 2 in repair
Reject#2 was in week 2 in repair
Reject#3 was in week 3 and 4 in repair
Reject#4 was in week 3,4,5 and 6 in repair
Reject#5 was in week 2,3,4,5,6 and 7 in repair
As such the answer should be:
In week 1 there was 0 product being repaired
In week 2 there were 3 products being repaired
In week 3 there were 3 products being repaired
In week 4 there were 3 products being repaired
In week 5 there were 2 products being repaird
In other words column E should give me
0
3
3
3
2
Any suggestions?
I wanteed to know how I can use the countif using the criteria that is in another cell: Example.
Here is the formula that won't work:
=COUNTIF(B18:B700,">=D2")/B4
D2 is a cell that I want to be able to change the value, every month.
Example: I want to be able to change the criteria, just by changing a number in a single cell.
Thank you for your help !
I am trying to figure out how many school buses we have on the road at a given time (every 15 minutes, 5:45 to 5:59, 6:00 to 6:14, 6:15 to 6:29, all the way to 9:00 PM etc).
Column A is the route #,Column B is the Start Time, and Column is the End Time and Column D is the duration of the entire route.
RRoute # End Time Start Time Duration
762 AM1 7:25 AM 5:46 AM 1:39
792 AM1 7:24 AM 5:58 AM 1:26
764 AM1 7:25 AM 5:59 AM 1:26
716 AM1 7:25 AM 6:07 AM 1:18
794 AM1 7:20 AM 6:10 AM 1:10
715 AM1 7:25 AM 6:12 AM 1:13
754 AM1 7:20 AM 6:17 AM 1:03
706 AM1 7:25 AM 6:17 AM 1:08
766 AM1 7:18 AM 6:21 AM 0:57
767 AM1 7:23 AM 6:23 AM 1:00
770 AM1 8:20 AM 6:23 AM 1:57
798 AM1 7:15 AM 6:24 AM 0:51
763 AM1 7:25 AM 6:28 AM 0:57
I have been able to get a formula to work using the Start Time, but I can't get it right to keep counting that bus all the way to the end time.
Thank you.
I need some help, I'm tying to use a countifs function. Let's say that I want to add "Matt" and "Bella"(column A), then continue the formula "Biology" (column D). I can't seemed to make it work.
I am trying to work with the countifs formula to come up with the following.
Between date range 1/3/2016 and 1/10/2016 how many of this list are Class A along with how many are for this particular area (GA).
My current formula is:
=COUNTIFS(DATE,">="&$B$2,DATE,"<="&$B$28,Class,"A")
WE WANT TO APPLY 70 IF CONDITIONS LIKE
BUT NORMALLY AAPLY ONLY 9 CONDITIONS, PLEASE HELP FOR APPLY 70-80 IF CONDITION, IN THIS FILE WE HAVE 2 SHEET INVENTRYDTA LINK AND OTHER SHEET1 SO APPLY IF ON SHEET 1 AND THAT WILL FETCH DATA FROM INVENTRYDTA LINK.
BUT WE WANT APPLY 70 IF ON SHEET 1
=IF(C18=INVENTRYDATA LINK'!B2,INVENTRYDATA LINK'!D2,IF(C18=INVENTRYDATA LINK'!B3,INVENTRYDATA LINK'!D3,IF(C18=INVENTRYDATA LINK'!B4,INVENTRYDATA LINK'!D4,IF(C18=INVENTRYDATA LINK'!B5,INVENTRYDATA LINK'!D5,IF(C18=INVENTRYDATA LINK'!B6,INVENTRYDATA LINK'!D6,IF(C18=INVENTRYDATA LINK'!B7,INVENTRYDATA LINK'!D7,IF(C18=INVENTRYDATA LINK'!B8,INVENTRYDATA LINK'!D8,IF(C18=INVENTRYDATA LINK'!B9,INVENTRYDATA LINK'!D9,))))))))
can i count different date value in summery next sheet
this is what I would like to accomplish. I have a list of words. This list of words could be long but for simplicity, let's say I am looking for any occurrence of orange apple or banana. Any time any of those words show up, I would like to get a count for each occurrence.
I would like you to get me some bananas, strawberries, oranges, grapes and kiwis.
I would like for the logic to recongnize that there were 3 occurrences and bring back the number 3. The logic may be in one field or it may be in multiple fields.
Any thoughts.
try COUNTIF(Range,"*banana*") to count all occurrence of banana from the Range
Hello Chuck!
You can calculate apples, bananas and oranges separately, and then sum the results. For example =COUNTIF(D1:D13,"apple")+COUNTIF(D1:D13,"orange")+COUNTIF(D1:D13,"banana")
HI,
I have send you an email with the excel sheet attached to it. Please do consider it and help me on that.
Country China Sweden India Japan Korea *Can be inc or dec
Fruits Apple Banana Grapes Pineapple Cherry *Can be inc or dec
Month January March June July *Can be inc or dec
I need to verify the total number of consumption by each country in each month
Data can be increased or decreased wrt to the requirements. Status must be accepted only
Status>> accepted
Total count Country wise>>
Total count Fruits wise
Hi,
Within Cells A33:A151, I have options of saying either "LISTING" or "DBL END".
In cell N152, my current formula is as follows:
=AVERAGEIF(A33:A151,"LISTING",N33:N151)
This formula works, however, I am having trouble writing the formula so that when a cell within A33:A151 says "DBL END" (as opposed to "LISTING"), Cell N152 still calculates accordingly.
Thanks.
Hi,
please how can I write a formula with a series of range and each range has a number that should be added.E.g Range 1-500,50 should be added,range 501-1000, 100 should be added and so on.
Thanks.
Hi
Is there a way I can count cells with the same conditional formatting? For example, I have cells that will turn green if they meet certain criteria and the others will not be green and I would like to count the cells in a column that are green. Is there a way to do that?
Thanks in advance.
hello there,
A1 CONTAIN PACKAGE NUMBER 123456
B1 CONTAIN AMOUNT 100$
C1 CONTAIN STATUS DELIVERED OR NOT DELIVERED
HOW CAN I COUNT THE AMOUNT FOR ONLY WORD DELIVERED OR NOT DELIVERED
THANKS
Hi,
can you plz provide me solution for this.
Required Output - Raw Data in Yellow, I need the total count of CRC in Column H7 after selecting the date from drop down in Column F6. The data shuld be changed according to the date from drop down in Column F6.
1-Apr-15 (SVC)
1-Apr-15 (CRC)
1-Apr-15 (CRC)
1-Apr-15 (CRC)
1-Apr-15 (CRC)
Hi,
I am having problem to make formula:
Subject wise Percentage
I want to generate formula for boys and girls who passed and failed.
Subject wise Percentage
Subjects Pass Fail
B G T B G T
Dzongkha 4 26 30
English 4 8
Mathematics 4 4 8
EVS 4 8
Hi, i have the first column which is a list of different people, but the names repeat going down for every new client shown in the 2nd column.
In a 3rd column there is a list of comments for each different client.
This column has rows of cells that either have a comment or they are blank.
What i need help with is counting the # of blank cells in the 3rd column and breaking that total into subtotals based on each unique person from the 1st column.
So if you have Ashley Gomez(example) occupying 10 rows (1st column) and only 3 of her comment fields have any text in them. It will return the number of blank rows as 7.
And then the same for Bibi Martinez who occupies 15 rows but has 6 actual comments this value would return as 9 blank
And so on down through Zoe...
Hashing this out in my head seems easy enough but the translation to excel logic just escapes me...
Any help would be very much appreciated.
-chris
Hi Ablebits Team, I've found myself in trouble trying to work out a way to avoid using Countifs in the following way:
=COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018109402",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018109396",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106869",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106852",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106876",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106845",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106685",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106937",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106753",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018106920",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018112129",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018112112",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018112136",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018118763",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018118749",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018118725",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018118756",s!$Q:$Q,">=0")
+COUNTIFS(s!$A:$A,D$1&"*",s!$G:$G,"9318018118787",s!$Q:$Q,">=0")
Huge etcetera…
Basically I get those barcodes from column G in a tab called “S” and each week I need to add new barcodes to the formula but adding a new line is not ideal as I will potentially reach the limit of characters that can be used per formula per cell. My question is, could I possibly combine Countifs with vlookup or get Countifs to get those barcodes from a specified range of cells where I could easily dump more barcodes?
Thanks heaps in advance!
I want count Number of Male which is 3 Age from X Unit like below table
Name of Unit Age Gender
X 3 Male
Y 4 Female
Z 5 Female
Help me
Hi
I am looking at trying to differentiate between cases and enquiries and count what stage they are at:
eg
Case Withdrawn
Case Withdrawn
Case Withdrawn
Case Withdrawn
Case Withdrawn
Enquiry Withdrawn
Enquiry Withdrawn
Case Closed
Case Closed
Case Closed
Case Closed
Case Closed
Case Closed
I am looking to count how many cases are withdrawn, how many enquiries are withdrawn etc
Thanks
Thanks that worked. I had a named range of the entire data set and that did not work. Breaking the specific ranges looks to be required.
I have a data set that lists a persons age in years along with their sex. I want to be able to count the number of people who are say Male and ages from 4-19.
Any suggestions to a formula? I have been able to use COUNTIF to get all persons in that age but unable to now further filter by sex. Trying COUNTIFS but not able to get the desired result.
suggestions?
@Merlyn, Please check this result.
A B
Age Sex
3 Male
4 Female
2 Male
6 Female
9 Male
22 Female
11 Male
21 Female
10 Male
7 Female
COUNTIFS(A2:A11,">=4",A2:A11,"<=19",B2:B11,"Male")
This should give you result for age between 4 and 19, and,
all Males.
How to use ~ in criteria using COUNTIFS?
I am having values in column E like CIVIL, MECHANICAL, ELECTRICAL, INSTRUMENT..... In column O I am having values like 0:30, 0:25,0:45,0:51,0:48,1:21 (all are time format)like that. I need a formula to count number of CIVIL is more than 0:30 minutes.
Please help
=SUMIF($J$8:$J$40,$AK7,S8:T40)this is posible
Hi geyanthan,
According to your formula, only column S will be summed.