Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4506 comments

  1. Hello, sir. What if I want the if condition to look value in multiple cells.

    Eg.

    =IF(A1=any value from the (B1,B2,B3), TRUE, FALSE)

    How can I achieve this?

  2. Hello, I'm really struggling with this. I think the function that I need to use is IF but I'can make it to work properly.

    I have 4 different categories [A] [B] [C] [D] and those categories can be scored as 1, 2 ,3. But one particular [D] category if the score is 1 I need to have more impact in the end. I was thinking in if score is 3 : 40%,40%,10%,10%, if score is 2 : 35%,35%,10%,20% and if score is 1 : 30%,30%,10%,30%.

    I came to
    =IF(E10="3","((E7-40%)+(E8-40%)+(E9-10%)+(e10-10%)/4)",IF(E10="2","((e7-35%)+(e8-35%)+(e9-10%)+(e10-20%)/4)",IF(E10="1","((e7-30%)+(e8-30%)+(e9-10%)+(e10-30%)/4)")))

    But is not working and this is driving me crazy,
    If you maybe help me I would be very grateful

    Thank you in advance,
    David Lopes

    • Hi! The information you provided is not enough to understand your case and give you any advice, sorry. Explain your source data and the result you want to get.
      I can assume that your formula does not need quotation marks.

      =IF(E10=3,((E7-40%)+(E8-40%)+(E9-10%)+(E10-10%)/4),IF(E10=2,((E7-35%)+(E8-35%)+(E9-10%)+(E10-20%)/4),IF(E10=1,((E7-30%)+(E8-30%)+(E9-10%)+(E10-30%)/4))))

      • Thank you so much that really help me, I don't know why I was using quotation marks... I was just looking at some tutorials and gave me the wrong idea. For my formula to work and give back a result between 1 and 3 I just add one more () and it worked just fine!

        like this:
        =IF(E10=3,(((E7-40%)+(E8-40%)+(E9-10%)+(E10-10%))/4),IF(E10=2,(((E7-35%)+(E8-35%)+(E9-10%)+(E10-20%))/4),IF(E10=1,(((E7-30%)+(E8-30%)+(E9-10%)+(E10-30%))/4))))

        Thank you so much!!!! You really solved my problem!!!

  3. Hell Alexander, I continue receiving error messages when attempting to write “IF” formula with multiple conditions

    =IF(AND(‘D7=”Kick-Off Training”, ‘M7>=DATEVALUE(“4/30/2023”), "0", "1")))

    Cell D7 value = required training title
    Cell M7 value = later than date hired (those hired Q2 or later)
    “0”, “1” = determines if counted in subtotal formula

    • Read the manual above carefully and do not use unnecessary brackets and quotation marks.
      Check the formula below, it should work for you:

      =IF(AND(D7="Kick-Off Training", M7>=DATEVALUE("4/30/2023")), "0", "1")

      • Alexander, thank you so much. That correction worked perfectly!

  4. Little Help in the following formula

    =IF(OR(A6="Equity",A6="MFs",F5>365*1),"LT","ST"),IF(OR(A6="Debt",A6="Sec-UL",F6>365*3),"LT","ST"), the result of which shows as "#value" instead of LT or ST as case may be, Plese help

      • Thank you so much Sir. That correction worked perfectly

      • =IF(OR(OR(A6="Debt",A6="Sec-UL",F6>365*3),OR(A6="Equity",A6="MFs",F5>365*1)),"LT","ST"),

        PLEASE check once again, the result from the above formula always as "LT" instead of "ST", even if the days in some case less than 365 days.

        My original formula as later which had been modified by you as former one above

        =IF(OR(A6="Equity",A6="MFs",F5>365*1),"LT","ST"),IF(OR(A6="Debt",A6="Sec-UL",F6>365*3),"LT","ST"), the result of which shows as "#value" instead of LT or ST as case may be,

        • The formula I suggested to you uses the conditions you described in your formula. If you have described them incorrectly, the formula will not work properly. Note that the OR function returns TRUE if at least one condition out of three is true. For example, if A6="Equity", it doesn't matter what number is written in F5 and F6.

  5. Hi
    Trying to create a formula for 0.33 "Present" and blank cell (so no result) "Not evaluable".
    Any help appreciated!

  6. Worked on multiple IF functions with AND and OR and THEN but nothing is working.

    My issue:

    B14=9 then 100
    B14=6 then 350
    B14=1 then 500

    no matter what I've put in I keep getting errors.

    IF(OR(B14=9 THEN true_value 100 ELSE IF B14=6 THEN true_value 350 ELSE IF B14=1 THEN true_value 500)

    Please help.

  7. I hope you may help me with this situation.. i have 3 sheets with Cust name in column A and warehouse name in rows B to F. 1st sheet is called SUMMARY. now in SUMMARY sheet, i need to show the total value of all the warehouses (from sheet 1 & 2) according the customer name.

    SHEET 1 LOOKS LIKE THIS:
    WAREHOUSE
    CUST NAME F G H I J
    A 1 2 3 4 5
    B 2 2 3 4 5
    CD 3 2 3 4 5
    DE 4 2 3 4 5
    E 5 2 3 4 5

    SHEET 2 LOOKS LIKE THIS:
    WAREHOUSE
    CUST NAME F G H I J
    A 6 7 8 9 10
    AB 7 7 8 9 10
    B 8 7 8 9 10
    CD 9 7 8 9 10
    DE 10 7 8 9 10

    SUMMARY MUST ADD THE WAREHOUSE VALUES OF SHEET 1 & 2 ACCORDING TO THE CUSTOMER NAME

    WAREHOUSE
    CUST NAME F G
    A SHEET 1+2 SHEET 1+2
    AA SHEET 1+2 SHEET 1+2
    DE SHEET 1+2 SHEET 1+2
    B SHEET 1+2 SHEET 1+2
    CD SHEET 1+2 SHEET 1+2

    thank you so much

    • sorry that content rumbles and i cant paste screen shots

  8. Hello
    the content was really helpful and useful
    thanks a bunch

  9. Hi, am trying to create an expense sheet, so if a cell has a drop down with three values Needs, Wants and Savings and if I add Rs 200 to a cell and select option "need" from the drop down, Automatically value from my cell where percentage of total earnings which is allocated to needs must be subtracted.

    For example, My total earnings is 30K and from that I have allocated 30% to my needs which will be 10K , if I enter house rent = 5K and select "Needs" from drop down automatically the cell which has 10K should be 10k - 5K. This formula must be applied to atleast 10 rows so I can track my needs, wants and savings.

    I have derived with this formula =IF(J3="Needs",D33-H3,D33) where J3 is the drop down cell, D33 holds the 10K , H3 holds the 5K, but this formula works only for 1 cell , I want this formula to work on a range of cells say from H3 to H13.

    Kindly help on this formula

  10. Hello! I was hoping you could help.
    If A2 = Male and B2 = RTK then C2*15% If A2 = Female and B2 = RTK then C2*20% If A2 = Male and B2 = MDK then C2*25% If A2 = Female and B2 = MDK then C2*30% Else C2=0

  11. Hi,

    Hope you could help me this.

    If K721 is equals to "VAT" then (amount) divided into 1.12

  12. Hi,

    I have a below data, where column E is the result column.
    Trying to come up with a formula, that gives me the expected result in column E.
    Any help on this is greatly appreciated.
    Thanks in Advance.

    ID Helper 1 Helper 2 Customer Expected Result
    A-01-A1 A-01-A 1 Sliver 1
    A-01-A1 A-01-A 1 Sliver 0
    A-01-A1 A-01-A 1 Sea Blue 1
    A-01-A3 A-01-A 3 Sea Blue 0
    A-01-A4 A-01-A 4 Sliver 0
    A-01-A5 A-01-A 5 Sea Blue 1
    A-01-A7 A-01-A 7 Sliver 1
    A-01-A9 A-01-A 9 Sliver 0
    A-01-B1 A-01-B 1 Sliver 1
    A-01-B1 A-01-B 1 Sliver 0
    A-01-B3 A-01-B 3 Sliver 0
    A-01-B6 A-01-B 6 Sliver 1
    A-01-B6 A-01-B 6 Sliver 0
    A-01-B8 A-01-B 8 Sliver 0
    A-01-C1 A-01-C 1 Sliver 1
    A-01-C2 A-01-C 2 Sliver 0
    A-01-C3 A-01-C 3 Sea Blue 1
    A-01-C6 A-01-C 6 Sea Blue 1
    A-01-C9 A-01-C 9 Sea Blue 0
    A-01-D1 A-01-D 1 Sea Blue 1
    A-01-D4 A-01-D 4 Sliver 1
    A-01-D5 A-01-D 5 Sliver 1
    A-01-D6 A-01-D 6 Sliver 0
    A-01-D7 A-01-D 7 Sliver 0

  13. Hello. I'm trying to create this:
    IF E2=1 then the value is 400. But I want this for more numbers. But somehow I am unable to combine them.
    Endgoal:
    E2=1, then value 400...... =IF(E2=1;400;0)
    E2=2, then value 200...... =IF(E2=2;200;0)
    E2=3, then value 150...... =IF(E2=3;150;0)
    E2=4, then value 75........ =IF(E2=4;75;0)
    E2=5, then value 50........ =IF(E2=5;50;0)

    How should my formula look like?

    Kind regards,
    Tommy

      • Thank you for your reply. Unfortunately your formule doesn't work.
        "There's a problem with the formula''

        Not trying to type a formula?
        When the first character is an equal ("=") or minus ("-") sign, Excel thinks it's a formula:

        • you type: =1+1, cell shows: 2

        To get around this, type an apostrophe ( ' ) first:

        • you type: '=1+1, cell shows: =1+1

        • Hi! The formula I sent to you was created based on the description you provided in your first request.This formula has been tested and works with your data. Why are you telling me how to enter the formula correctly? You need it, not me. What delimiters do you use in your formulas - commas or semicolons? What is the value in cell E2?

          • I've just copy pasted your formule, hoping it could work. Once copy pasting it, the text below have been directly copy pasted from Excel. Wasn't trying to be rude. I am really thankful for your help.
            I'm using semicolons. Currently is the value of E2 3.

            • Hi! Replace the commas in the formula with semicolons. Use your regional settings in the formulas.

              =IFS(E2=1;400;E2=2;200;E2=3;150;E2=4;75;E2=5;50)

      • Hi Sir,
        I am trying to use below excell function but it doesnt works. Please help

        =IFS(D4=1,1.1,D4=2,1.1,D4=3,1.2,D4=4,1.3)

  14. If there are 32 days in any cell, zero will be added after 33 days at the rate of 10 rupees per day.

    excel formula making

  15. Hello,

    I'm trying to create a formula that says "If cell D8 equals In Progress or Not Started AND cell G8 is earlier than today, then mark the field with either OVERDUE or NOT DUE". I have tried several different things and can't get it to work properly. Any suggestions?

    Thank you!

    • Hi! All the necessary information is in the article above. The formula might look like this:

      =IF(AND(OR(D8="In progress",D8="Not started"),G8<TODAY()),"overdue","")

  16. please help with the formula
    i want to Calculate the Tax for Whisky at 8% of the TOTAL
    and GIN at 6% of the TOTAL For the drinks not requiring tax to
    paid insert "NO TAX"
    col a col b col c col d col e col f
    Drink Tax Band Price Sales Total Tax
    Whisky B 12.90 8,000.00 103,200.00 8,256.00
    Brandy C 14.50 6,890.00 99,905.00 FALSE
    Gin A 8.65 12,896.00 111,550.40 6,693.02
    Vodka D 9.95 12,356.00 122,942.20 6,147.11
    Rum B 11.30 7,896.00 89,224.80 0
    Port D 13.90 2,300.00 31,970.00 0

    • Hi! Please re-check the article above since it covers your task.
      If I understand correctly, here is an example formula:

      =IF(A2="Whisky",F2*8%,IF(F2="Gin",F2*6%,"No tax"))

  17. Hi! I need to add the results of a nested if together to give me a number to source for a further if query - I'm really struggling to get it work and I'm getting very frustrated!

    • To ensure clear understanding of your task, can you provide an example of the source data and the desired result you are aiming for?

  18. I am asked to do this:
    "In column H find Discount. Where discount is 10% of the total Sales for Item Type “Clothes”
    and “Total Sales” greater than 500000. Otherwise, the discount is 0."
    what is the correct way to write the function?

  19. Im looking for a formula that will provide me with a result only if two conditions are met and are on the same line of the table

    From one spreadsheet i need to search another table made up of follows Column A - PO Number / Column B - Item No. & Column C - Value

    How can i make sure that the PO and Item No are the same in both tables before i can call in the value (Column C).

    In the data table, PO number and Item Numbers can be duplicated but only one line will contain the correct PO and Item number together.

  20. Hi!
    I have a question about the following formula:
    =IF(F2="MONTH";DATE(YEAR(C2);MONTH(C2)+D2;DAY(C2));IF(F2="";DATE(YEAR(C2)+D2;MONTH(C2);DAY(C2));IF(F2="YEAR";DATE(YEAR(C2)+D2;MONTH(C2);DAY(C2)))))

    What I am doing here is creating a date calculation from Starting date, so if the cell F2 contains MONTH as the unit, then add the number present in D2 to the MONTH (in the formula). If the F2 cell contains YEAR unit, then add number in D2 to the YEAR (in the formula). If the F2 cell does not contain any unit, assume it is YEAR and add the number from D2.

    Now I want to add an additional condition into the formula - if the Starting date (column C) is empty, how do I show the result as "0" instead of it just being #VALUE! error?

    Here is a quick example of the table I have:

    1 C D F
    2 empty 20 empty
    3 empty 20 YEAR
    4 2025-02-28 15 YEAR
    5 2022-03-24 1 MONTH

    Thank you for the help!

  21. I am attempting to enter a formula =countif(f2:f99,P2) but I need an extra parameter (sorry if that’s the wrong term).

    I am doing a spreadsheet for people who are “housed and unhoused”. The formula above works perfectly but when the case is closed, I do not want to numbers counted in the calculation anymore. What can I add to no count those. It’s in column M as “yes or no”. Hopefully that’s enough information.

  22. Using if function find the prices of a product according to
    1. Country (Turkey, Cyprus)
    2. Currency (USD, TL)
    3. Availability (available, Not available)

    Country Product USD TL
    Turkey Steel bars 25 400 TL
    Fine aggregate 5 75 TL
    Cement 3 70 TL

  23. Hello,

    I have a tracker which is tracking and occasions when employee is added there. So if there is an issue and clerk insert his name into a tracker, occasion comes as 1. If he is added there next time, occasion comes as 2... but I need this occasion to be lowered when NFA- no further action is needed. We have a columns for - NFA - First Warning - Final Warning.

    How I can add another rule for occasions to be lowered if NFA is ticked?

    Thank you

    • Hi! Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula in cell B2:

      =IFERROR(MAXIFS($B$1:B1,$A$1:A1,A2),0)+(C2=FALSE)

  24. I have a column typed with three types of data. i want to use IF function as for any type then put the result. i know if i put my result in another table and use of VLOOKUP i can get the result but i want to know can i use the IF function is this situation or to better say can we use IF function for triple conditions in one cell?

    • Hi! Please describe your problem in more detail. To understand what you want to do, give an example of the source data and the desired result.

  25. MATERIAL CODES MATERIAL DISCRIPTION UOM JAN FEB MAR APR MAY JUN JUL AUG SEP OCT NOV DEC

    300551151 RAIL BRACKET,DRG NO:ESL/SI/031/RBPFR/01 NO 30 70 0 0 0 0 0 0 0 0 0 0

    from this i want to get fast & slow function .

  26. hi,

    I have data monthly wise with filled numbers , I want to get fast & slow function from monthly cells value if monthly value is 0 in any cell atleast then it is fast , if all the monthly values are 0 then it is slow

    • Hi! I’m sorry but your description doesn’t give me a complete understanding of your task. Correct me if I’m wrong, but I believe the formula below will help:

      =IF(PRODUCT(--(A1:A10=0))=1,"slow","fast")

      The condition in the IF function returns TRUE if all cells in the range are zero.

  27. Hello, here is my formula and I'd like to know when to use * with if formula below. Thank you in advance!!!

    IFERROR(INDEX('Raw Data'!$A$1:$A$839, SMALL(IF(($FO$39='Raw Data'!$F$1:$F$839)*($C$2='Raw Data'!$J$1:$J$839)*($C$3='Raw Data'!$C$1:$C$839),MATCH(ROW('Raw Data'!$A$1:$J$839), ROW('Raw Data'!$A$1:$J$839)), ""), ROWS($A$1:$A1)), COLUMNS($A$1)),"")), 1, 1)

  28. Thank you for this article, it was very informative.

    I did have a pertinent question about using IF and COUNTIF together with various outcomes and would appreciate your assistance.

    There are two columns of data being used in the formula.

    Time Origination RESULTS DESIRED
    7:40 am Las Vegas, NV 9:40 am
    11:15 am Chicago, IL 11:15 am
    1:00 pm Buffalo Grove, MI 12:00 pm
    3:00 pm Hayward, IN 2:00 pm

    I need a formula to return a modified "Time" for records where the Origination state is MI, IN or NV.
    The formula I have so far subtracts 1 hour from the MI or IN records, which is what I want. I need to expand on that formula to add 2 hours to the NV records. The formula criteria have to be wildcards.

    Formula so far:
    IF(OR(COUNTIF(H2,"*, IN*"),COUNTIF(H2,"*, MI*")),B2-TIME(1,0,0),B2)
    This works perfectly for the MI and IN records.

    I need to add this to the above formula:
    IF(COUNTIF(H2,"*, NV*"),B2+TIME(2,0,0),B2)

    Thank you for your help.

  29. I am trying to create a formula that can be used across the board. I want it to give me the value if it is a positive number but give me a "$0" if it is a negative number.

    For example:
    (1,689,265-1,550,000)*.0035= $684.14
    FOR this answer I want the amount $684.14 to be entered as the result.
    but other cells have these as values:
    (1,441,243-1,500,000)*.0035= $-205.65
    FOR this answer I want the formula to enter a $0 in the result.

    Isn't there a single formula that will satisfy BOTH answers?

    • Hi! To return 0 instead of a negative number, use the IF function. Use cell references.

      =IF((1,689,265-1,550,000)*.0035>0,(1,689,265-1,550,000)*.0035,0)

  30. I'm trying to create a formula where if the range of Unit Numbers is not found on another sheet in the workbook then No, if it is found then Yes. This is what I have so far

    =IF(A2:A106)*(Depository!L2:L87)*"Yes","No")

    I cannot figure out what is wrong, also this is my first time using a formula in a long time.

    • Hi! Please clarify your problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.

  31. HI,

    im trying to get a formula to search through cell AB2 find a specific word then return data from that word that is in a table on another sheet.

    the table in sheet 2 that has the info i want to return is below

    Unit PC type of unit time price
    Loft SF-EVL-HR new isntall 1.5 300
    Wall SF-EVF-H new isntall 3 500
    Broom SF-INF-SELV new isntall 2 400
    Kitchen SF-INF-230V new isntall 2 200

    ive tried using Vlook up as per the below however it only ever brings back the 2nd unit never any others!

    =VLOOKUP(AB3, Sheet2!$A$2:$E$5,2,TRUE)

    Any ideas before i loose my head?

    • Hi! Your question is not quite clear. Explain exactly what you want to find in these text strings and what data you want to return. Specify exactly what result you want.

  32. I'm wanting to use text and numbers for the IF. So IF B1 =Firefighter C1 = 4 but with mulitple potentials so also IF B1=Captain C1 =3. How do I have 6 different IFs

  33. How can you expand this - if(AE3="Yes",2,1) - into a 3 point Likert Scale where the function automatically assigns a value (0) for a maybe response entry or for a 5 point Likert Scale for example - if(AE3="Strongly Agree",5,0) and in the function values for (Agree=4, Neutral=3, Disagree=2 and Strongly Disagree=1) in an IF Function.

      • Thanks, but i mean rather than return numeric value it should be a text instead, like the response choices are closed end to just very satisfied, satisfied, neutral, dissatisfied and very dissatisfied and as soon as any of the aforementioned options are selected the next cell automatically returns a numeric value (i.e when the respondent selects very satisfied from the dropdown box the next cell automatic gets filled with the numeric value of 5)

          • Thanks, but you still haven't gotten what i mean, from the dropdown menu, you could even skip using the developer tab...can just head to data tab, click on data validation and select list, then input your text separating them with commas...i mean for instance you have the response cell gets a neutral from a choice of (Excellent, good, neutral, poor and very poor) how do you format a conditional (IF logical) statement to automatically assign a numerical value to the next cell on the right for...something like (=if(b2="Neutral",1,0) but extended to cover the 5 likert scale options...

              • This is the IF function i have been trying to get from you...got it from a CHATGPT supported AI (Android version) =IF(A2="Strongly Agree",5,IF(A2="Agree",4,IF(A2="Neutral",3,IF(A2="Strongly Disagree",2,IF(A2="Disagree",1,""))))) it works but for the disagree it returns a blank entry instead could it be the last two inverted commas? Or just look through and show me what am doing wrong why the disagree value shows a blank return entry

  34. Hi, I can't seem to find the right formula for this situation. We have column A with the item name, then column B for the price, on Column C there's a drop-down menu to choose whether the item is Vatable or Non-Vatable. If it's Vatable, auto calculation on column D should appear with this formula: (Item price*12)/112. If it's Non-Vatable then we leave it blank. Could you help me please?

  35. I have a sheet that is adding scores.
    But if DQ (Disqualified) appears in column P or O ...
    then I want DQ to appear in the box for the TOTAL SCORE

    IF DQ does NOT appear in column P or O... I want it to total the sum of points

    Here is what I used... however it is not correct. Please help

    =IF(AND(O5="DQ", P5="DQ"), "DQ", (=sum(C4+E4+G4+I4+Q4+R4+S4+T4)))

    • Hi!
      If I understand your task correctly, try the following formula:

      =IF(AND(O5="DQ", P5="DQ"), "DQ", sum(C4+E4+G4+I4+Q4+R4+S4+T4))

  36. I had a little error in formula

    =(IF(A8="MFs",IF(A8="Sec-L",M26,M27),M28))

    I hade entered "Sec-L",'MFs", in data validation list in cell A8 and entered value as 2822, 2820 and 1250 in cell M26, M27 and M28 respectively

    The formula in Later one "IF(A8="Sec-L",M26,M27),M28)" gives the result 2822 or 2820 respectively which is proper, But the formula gives the same result as above, if both the if formula are joined, instead of desired result of 1250 for MFs or 2822/2820 for Sec-L,

    I/m nearly fumble nearly at the last point. Please help.

  37. Hi, I am trying to create a nested IF for scenario: if vlookup into method sheet is 21 days and days from date created col in data sheet is 21 days, populate 3wks created. (So forth with 2wks, 1wk). If false, blank " ". Then those " ", populate if days to due date col in data sheet is less than 0, populate "[#] days has late" and if days to due date is greater than or equal to 0 & less than and equal to 5 (supposedly 1wk), populate "[#] days has left", otherwise if false: "good standing".

    This is my formula but I think I am missing the nested IF formulation and getting something incorrectly and can't seem to find it
    =IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=21,N4=21),"3WK CREATED",IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=14,N4=14),"2WK CREATED",IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=7,N4=7),"1WK CREATED"," "))),IF(AND(" ",O4=0,O4<=5),O4&" DAYS HAS LEFT","GOOD STANDING"))

    • This is the formula actually, missed one part (days has late less than 0):

      =IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=21,N2=21),"3WK CREATED",IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=14,N2=14),"2WK CREATED",IF(AND(VLOOKUP(OfficialOpenBills__3[@Vendor],Method!$A$2:$H$1235,5,FALSE)=7,N2=7),"1WK CREATED"," "))),IF(AND(" ",O2=0,O2<=5),O2&" DAYS HAS LEFT","GOOD STANDING"))

    • Hi!
      It is very difficult to understand a formula that contains unique references to your workbook worksheets. Hence, I cannot check its work, sorry. To understand what you want to do, give an example of the source data and the desired result.

  38. Hi,
    I have a list of 2 variables - people names and account names. I am trying to create a formula that gives the following:
    if a certain account name falls under the 10% of all # account names for a certain people name -> assign to scenario 1, otherwise scenario 2.
    would anyone be able to help with the formula?

      • Thanks for the reply. The example is: assign 10% of Paul's accounts to scenario 1, rest goes to scenario 2. The case below is limited so, it's about assign 25% of the accounts, but this should be applicable to any %. It seems to me countif formula should be merged with % calculation, but not sure how.
        Formula needed:
        Paul account 1 scenario 1
        Sam account 1 scenario 1
        Lia account 1 scenario 1
        Paul account 2 scenario 2
        Sam account 2 scenario 2
        Lia account 2 scenario 2
        Paul account 3 scenario 2
        Sam account 3 scenario 2
        Lia account 3 scenario 2
        Paul account 4 scenario 2
        Sam account 4 scenario 2
        Lia account 4 scenario 2

        • Hi!
          Use the COUNTIF function to count the quantity of account names.
          If I understand your task correctly, try the following formula:

          =IF(OR(COUNTIF($A$1:A1,A1)/COUNTIF($A$1:$A$20,A1)<0.1,COUNTIF($A$1:A1,A1)=1),1,2)

          • OMG! it works! It's exactly what I was after. Thanks a lot Alexander!
            Best regards, Kremena

  39. Hello, trying to use the an IF statement to add one of five different gradings.
    5=outstanding
    4=Exceeds
    3=Solid
    2=Marginal
    1=Needs
    This is the formula I used. Can you tell me what I'm doing wrong.
    =IF(J2>=5,"Exceeds", IF(J2>=4, "Exceeds", IF(J2>=3, "Solid", IF(J2>=2, Marginal", IF(J2>=1, "Needs")))))

  40. Hi,
    I am trying to create locked template sheet for automatic calculation. I can import data in excel format from other program. I want the average from the values from the column G to be calculated to the bottom of column. Column G has numerical values, but the value from the column G can only be calculated to the average if the columns C, D, F, J, N, S, W and AA from the same row all have the text POS at the same time to rule out false positive values. If any of columns on the row has another text the value from the column G must be excluded from the average. I cannot change the layout of the data and the number of rows may vary.

  41. Hi Alex,

    Need your assistance with the formula for the below situation.

    Instance: We have 2 products both are dependent on each for their availability.

    If both the products are available then the Text should return as "A"
    If either of them or both products not available then the text should return as "X"

  42. i'm trying to make a formula to assign weight in grams based on a column that has named formats for record albums..
    examples as follows
    LP / 600
    2LP / 1000
    3LP / 1660
    4LP / 2000
    10" / 500
    7" / 300
    2x7" / 400
    3x7" / 500
    2x10" / 660

  43. Ooops forgot the last formula

    =IF(AND(E7<0,F7="n"),-100/E7*10)

  44. Hello, I have a problem I am trying to solve that has 4 separate calculations to produce an answer based on 4 different criteria which are as follows:
    Team wins and ML+
    Team wins and ML-
    Team loses and ML+
    Team loses and ML-

    The calculations I have for each of these conditions are working independently and are producing the correct answer in the cell, what I can not figure out is how to string all of these calculations together in one cell to produce the one correct answer.

    Here are the independent formulas I have:
    =IF(AND(E4>0,F4="y"),10*E4/100)
    =IF(AND(E40,F4="n"),-10)
    =IF(AND(E4<0,F4="n"),-100/E4*10)

    Thank you for your help!

      • I used the following and get an Excel message, "There's a problem with this formula"

        =IF(AND(E16>0,F16="y"),10*E16/100), IF(AND(E160,F16="n"),-10), IF(AND(E16<0,F16="n"),-100/E16*10))))

        I also tried the IFS example as well with the same error.
        Do you see what could be the problem with it? Thanks

        • Hi! Look at the formula I gave you and read the recommended instructions carefully. Do not use unnecessary brackets.

          =IF(AND(E16>0,F16="y"),10*E16/100,IF(AND(E160,F16="n"),-10,IF(AND(E16<0,F16="n"),-100/E16*10)))

          • Thank you so much! I had some syntax errors that it took a while to figure out, but I now have my cell calculating all 4 scenarios as I wish.

  45. Hi,
    I have a table that contains the following columns, quantity, unit price, cost and type of transaction (Buy and Sell). I want to create a formula to calculate the cost =(Qty*Unit price) provided that if the type of transaction is (Buy), the calculation should be with a minus sign and if it is sold calculation would be positive.
    Thanks in advance for helping..

  46. Hello! I am trying to come up with a nested IF formula with BOTH if and If(AND, but I cannot get it to work and am not sure if it is possible. Let's say I am trying to assign a score to the below combinations of grades:

    IF ONE OR MORE "A", THEN "01"
    IF ONE OR MORE "B", THEN "02"
    IF ONE OR MORE "C", THEN "03"
    IF ONE OR MORE "B" AND ONE OR MORE "C", THEN "04"
    IF ONE OR MORE "D", THEN "05"
    IF ONE OR MORE "D" AND ONE OR MORE "B" THEN "06"
    IF ONE OR MORE "E" THEN "07"
    ELSE "00"

    Can this be done? Thank you!

    • I am sorry I forgot to mention, the grades will be in a single table column, so will be searching for the grades in "Sheet1!E:E" for example. I can things to work with the help of your article for most cases but not in this way. Any help is much appreciated. Thank you!

  47. Hi there! I hope you can help me. I know that an IF statement needs to be used for this but i am having a hard time how to do it. Here is the example:

    IF BMI IS GREATER THAN OR EQUAL TO 1.0% THE RESULT IS 35 pts, IF BMI IS IN BETWEEN 0.4% AND 0.99% THE RESULTS IS 30 pts, IF BMI IS IN BETWEEN 0.1% AND 0.39% THE RESULT IS 25 pts, IF BMI IS EQUAL TO 0% THE RESULT IS 20 pts AND I F BMI IS LOWER THAN 0 THE RESULT IS 0 pts.

    I hope its not that complicated and I hope you can share your knowledge with excel to us, Soon.

    Best,
    James

  48. Hi, I was hoping you could help. I need a formula which looks at whether monies have been receipted promptly. Cell (F13) prescribes if monies received by EFT or Cash. If received by cash then then should have been banked by 2 days (Cell I13 is the date variance between bank and receipt date). If received by EFT then should have been receipted by 5 days (based on cell I13). This is what I was trying but came up with a 'value' return.

    =IF(F13="CASH",IF(I13<2,"Yes","No")), IF(F13="EFT",IF(I13<-5,"Yes","No"""))

    • Hi!
      If I understand your task correctly, try the following formula:

      =IF(F13="CASH",IF(I13<2,"Yes","No"),IF(F13="EFT",IF(I13<5,"Yes","No")))

      • Thank you so much Alexander ! You have been so helpful. I feel I was close :)

  49. Hi,

    Hoping you can help, I've tried a few ways but struggling.
    I have a column C consisting of a drop down of pass/fail with the percentage of passes at the bottom using COUNTIF( C2:C21, "Pass")÷COUNTA( C2:C21).
    Column D identifies from a drop down, on which attempt the pass happened (first, second, third etc).
    I would like the bottom of Column D to provide the percentage of first time passes so if a "Pass" from Column C has been achieved, what percentage of those were a 'First" from Column D.

    I tried inserting a third column (E) and using =IF(AND(C2="pass", D2="first"), "Yes", "No") then calculating the percentage of Yes to No's but it isn't actuate For example, based on the below information, it identifies the one "yes" so gives me 25% first time pass when it's actually 50% because there's only two people attempted it.

    B C D E
    Bob Pass First Yes
    Fred Fail First No
    Fred Fail Second No
    Fred Fail Third No
    25%

    Hopefully that makes sense and what I'm after is achievable!
    Thank you!

  50. Hello. Will an IF scenario work with a dropdown box? For example: B3 has options to select from in a dropdown box and I need to put a mileage rate based on which option is chosen in B3 into cell H3.

    So if one of 3 options in B3 are selected, the mileage rate would be 0.40 but if one of another set of 3 options are selected, the mileage rate would be 0.45.

    I hope this makes sense. Any help would be greatly appreciated!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)